(NUMBER)
"PER BRINCH HANSEN

 INFORMATION SCIENCE
 CALIFORNIA INSTITUTE OF TECHNOLOGY

 UTILITY PROGRAMS FOR
 THE SOLO SYSTEM

 18 MAY 1975"

"###########
#  PREFIX  #
###########"


CONST NL = '(:10:)';   FF = '(:12:)';   CR = '(:13:)';   EM = '(:25:)';

CONST PAGELENGTH = 512;
TYPE PAGE = ARRAY (.1..PAGELENGTH.) OF CHAR;

CONST LINELENGTH = 132;
TYPE LINE = ARRAY (.1..LINELENGTH.) OF CHAR;

CONST IDLENGTH = 12;
TYPE IDENTIFIER = ARRAY (.1..IDLENGTH.) OF CHAR;

TYPE FILE = 1..2;

TYPE FILEKIND = (EMPTY, SCRATCH, ASCII, SEQCODE, CONCODE);

TYPE FILEATTR = RECORD
                  KIND: FILEKIND;
                  ADDR: INTEGER;
                  PROTECTED: BOOLEAN;
                  NOTUSED: ARRAY (.1..5.) OF INTEGER
                END;

TYPE IODEVICE =
  (TYPEDEVICE, DISKDEVICE, TAPEDEVICE, PRINTDEVICE, CARDDEVICE);

TYPE IOOPERATION = (INPUT, OUTPUT, MOVE, CONTROL);

TYPE IOARG = (WRITEEOF, REWIND, UPSPACE, BACKSPACE);

TYPE IORESULT =
  (COMPLETE, INTERVENTION, TRANSMISSION, FAILURE,
   ENDFILE, ENDMEDIUM, STARTMEDIUM);

TYPE IOPARAM = RECORD
                 OPERATION: IOOPERATION;
                 STATUS: IORESULT;
                 ARG: IOARG
               END;

TYPE TASKKIND = (INPUTTASK, JOBTASK, OUTPUTTASK);

TYPE ARGTAG =
  (NILTYPE, BOOLTYPE, INTTYPE, IDTYPE, PTRTYPE);

TYPE POINTER = @BOOLEAN;

TYPE ARGTYPE = RECORD
                 CASE TAG: ARGTAG OF
                   NILTYPE, BOOLTYPE: (BOOL: BOOLEAN);
                   INTTYPE: (INT: INTEGER);
                   IDTYPE: (ID: IDENTIFIER);
                   PTRTYPE: (PTR: POINTER)
               END;

CONST MAXARG = 10;
TYPE ARGLIST = ARRAY (.1..MAXARG.) OF ARGTYPE;

TYPE ARGSEQ = (INP, OUT);

TYPE PROGRESULT =
  (TERMINATED, OVERFLOW, POINTERERROR, RANGEERROR, VARIANTERROR,
   HEAPLIMIT, STACKLIMIT, CODELIMIT, TIMELIMIT, CALLERROR);

PROCEDURE READ(VAR C: CHAR);
PROCEDURE WRITE(C: CHAR);

PROCEDURE OPEN(F: FILE; ID: IDENTIFIER; VAR FOUND: BOOLEAN);
PROCEDURE CLOSE(F: FILE);
PROCEDURE GET(F: FILE; P: INTEGER; VAR BLOCK: UNIV PAGE);
PROCEDURE PUT(F: FILE; P: INTEGER; VAR BLOCK: UNIV PAGE);
FUNCTION LENGTH(F: FILE): INTEGER;

PROCEDURE MARK(VAR TOP: INTEGER);
PROCEDURE RELEASE(TOP: INTEGER);

PROCEDURE IDENTIFY(HEADER: LINE);
PROCEDURE ACCEPT(VAR C: CHAR);
PROCEDURE DISPLAY(C: CHAR);

PROCEDURE READPAGE(VAR BLOCK: UNIV PAGE; VAR EOF: BOOLEAN);
PROCEDURE WRITEPAGE(BLOCK: UNIV PAGE; EOF: BOOLEAN);
PROCEDURE READLINE(VAR TEXT: UNIV LINE);
PROCEDURE WRITELINE(TEXT: UNIV LINE);
PROCEDURE READARG(S: ARGSEQ; VAR ARG: ARGTYPE);
PROCEDURE WRITEARG(S: ARGSEQ; ARG: ARGTYPE);

PROCEDURE LOOKUP(ID: IDENTIFIER; VAR ATTR: FILEATTR; VAR FOUND: BOOLEAN);

PROCEDURE IOTRANSFER
  (DEVICE: IODEVICE; VAR PARAM: IOPARAM; VAR BLOCK: UNIV PAGE);

PROCEDURE IOMOVE(DEVICE: IODEVICE; VAR PARAM: IOPARAM);

FUNCTION TASK: TASKKIND;

PROCEDURE RUN(ID: IDENTIFIER; VAR PARAM: ARGLIST;
              VAR LINE: INTEGER; VAR RESULT: PROGRESULT);


PROGRAM P(VAR PARAM: ARGLIST);


"###########################################
#  MOVE(VAR OK: BOOLEAN; FILENO: INTEGER)  #
###########################################"


"INSERT PREFIX HERE"

VAR OK: BOOLEAN; FILENO: INTEGER;

PROCEDURE WRITETEXT(TEXT: LINE);
VAR I: INTEGER; C: CHAR;
BEGIN
  I:= 0;
  REPEAT
    I:= I + 1;
    C:= TEXT(.I.);
    DISPLAY(C);
  UNTIL C = NL;
END;

PROCEDURE HELP;
BEGIN
  IF OK THEN
  BEGIN
    WRITETEXT('TRY AGAIN(:10:)');
    WRITETEXT('     MOVE(FILENO: INTEGER) (:10:)');
    OK:= FALSE;
  END;
END;

PROCEDURE TAPEERROR(RESULT: IORESULT);
BEGIN
  CASE RESULT OF
    INTERVENTION:
      WRITETEXT('INSPECT(:10:)');

    TRANSMISSION:
      WRITETEXT('ERROR(:10:)');

    FAILURE:
      WRITETEXT('FAILURE(:10:)');

    ENDMEDIUM:
      WRITETEXT('ENDMEDIUM(:10:)')
  END;
  OK:= FALSE;
END;

PROCEDURE MOVETAPE(WHERE: IOARG; VAR RESULT: IORESULT);
VAR PARAM: IOPARAM;
BEGIN
  WITH PARAM DO
  BEGIN
    OPERATION:= MOVE;
    ARG:= WHERE;
    IOMOVE(TAPEDEVICE, PARAM);
    RESULT:= STATUS;
  END;
END;

PROCEDURE REWINDTAPE;
VAR RESULT: IORESULT;
BEGIN
  MOVETAPE(REWIND, RESULT);
  IF (RESULT <> COMPLETE) &
     (RESULT <> STARTMEDIUM)
     THEN TAPEERROR(RESULT);
END;

PROCEDURE NEXTFILE;
VAR RESULT: IORESULT; DONE: BOOLEAN;
BEGIN
  DONE:= FALSE;
  REPEAT
    MOVETAPE(UPSPACE, RESULT);
    IF RESULT = ENDFILE THEN
      DONE:= TRUE ELSE
    IF RESULT <> COMPLETE THEN
      TAPEERROR(RESULT);
  UNTIL DONE;
END;

PROCEDURE FINDFILE;
VAR POSITION: INTEGER;
BEGIN
  REWINDTAPE; POSITION:= 1;
  WHILE OK & (POSITION < FILENO) DO
  BEGIN
    NEXTFILE;
    POSITION:= POSITION + 1;
  END;
END;

PROCEDURE INITIALIZE;
BEGIN
  IDENTIFY('MOVE:(:10:)');
  OK:= TRUE;
  WITH PARAM(.2.) DO
  IF TAG = INTTYPE
    THEN FILENO:= INT
    ELSE HELP;
END;

PROCEDURE TERMINATE;
BEGIN
  WITH PARAM(.1.) DO
  BEGIN TAG:= BOOLTYPE; BOOL:= OK END;
END;

BEGIN
  IF TASK = JOBTASK THEN
  BEGIN
    INITIALIZE;
    IF OK THEN FINDFILE;
    TERMINATE;
  END;
END.
                                                                                                                                                                                                          