(NUMBER)
"PER BRINCH HANSEN

 INFORMATION SCIENCE
 CALIFORNIA INSTITUTE OF TECHNOLOGY

 UTILITY PROGRAMS FOR
 THE SOLO SYSTEM

 18 MAY 1975"

"###########
#  PREFIX  #
###########"


CONST NL = '(:10:)';   FF = '(:12:)';   CR = '(:13:)';   EM = '(:25:)';

CONST PAGELENGTH = 512;
TYPE PAGE = ARRAY (.1..PAGELENGTH.) OF CHAR;

CONST LINELENGTH = 132;
TYPE LINE = ARRAY (.1..LINELENGTH.) OF CHAR;

CONST IDLENGTH = 12;
TYPE IDENTIFIER = ARRAY (.1..IDLENGTH.) OF CHAR;

TYPE FILE = 1..2;

TYPE FILEKIND = (EMPTY, SCRATCH, ASCII, SEQCODE, CONCODE);

TYPE FILEATTR = RECORD
                  KIND: FILEKIND;
                  ADDR: INTEGER;
                  PROTECTED: BOOLEAN;
                  NOTUSED: ARRAY (.1..5.) OF INTEGER
                END;

TYPE IODEVICE =
  (TYPEDEVICE, DISKDEVICE, TAPEDEVICE, PRINTDEVICE, CARDDEVICE);

TYPE IOOPERATION = (INPUT, OUTPUT, MOVE, CONTROL);

TYPE IOARG = (WRITEEOF, REWIND, UPSPACE, BACKSPACE);

TYPE IORESULT =
  (COMPLETE, INTERVENTION, TRANSMISSION, FAILURE,
   ENDFILE, ENDMEDIUM, STARTMEDIUM);

TYPE IOPARAM = RECORD
                 OPERATION: IOOPERATION;
                 STATUS: IORESULT;
                 ARG: IOARG
               END;

TYPE TASKKIND = (INPUTTASK, JOBTASK, OUTPUTTASK);

TYPE ARGTAG =
  (NILTYPE, BOOLTYPE, INTTYPE, IDTYPE, PTRTYPE);

TYPE POINTER = @BOOLEAN;

TYPE ARGTYPE = RECORD
                 CASE TAG: ARGTAG OF
                   NILTYPE, BOOLTYPE: (BOOL: BOOLEAN);
                   INTTYPE: (INT: INTEGER);
                   IDTYPE: (ID: IDENTIFIER);
                   PTRTYPE: (PTR: POINTER)
               END;

CONST MAXARG = 10;
TYPE ARGLIST = ARRAY (.1..MAXARG.) OF ARGTYPE;

TYPE ARGSEQ = (INP, OUT);

TYPE PROGRESULT =
  (TERMINATED, OVERFLOW, POINTERERROR, RANGEERROR, VARIANTERROR,
   HEAPLIMIT, STACKLIMIT, CODELIMIT, TIMELIMIT, CALLERROR);

PROCEDURE READ(VAR C: CHAR);
PROCEDURE WRITE(C: CHAR);

PROCEDURE OPEN(F: FILE; ID: IDENTIFIER; VAR FOUND: BOOLEAN);
PROCEDURE CLOSE(F: FILE);
PROCEDURE GET(F: FILE; P: INTEGER; VAR BLOCK: UNIV PAGE);
PROCEDURE PUT(F: FILE; P: INTEGER; VAR BLOCK: UNIV PAGE);
FUNCTION LENGTH(F: FILE): INTEGER;

PROCEDURE MARK(VAR TOP: INTEGER);
PROCEDURE RELEASE(TOP: INTEGER);

PROCEDURE IDENTIFY(HEADER: LINE);
PROCEDURE ACCEPT(VAR C: CHAR);
PROCEDURE DISPLAY(C: CHAR);

PROCEDURE READPAGE(VAR BLOCK: UNIV PAGE; VAR EOF: BOOLEAN);
PROCEDURE WRITEPAGE(BLOCK: UNIV PAGE; EOF: BOOLEAN);
PROCEDURE READLINE(VAR TEXT: UNIV LINE);
PROCEDURE WRITELINE(TEXT: UNIV LINE);
PROCEDURE READARG(S: ARGSEQ; VAR ARG: ARGTYPE);
PROCEDURE WRITEARG(S: ARGSEQ; ARG: ARGTYPE);

PROCEDURE LOOKUP(ID: IDENTIFIER; VAR ATTR: FILEATTR; VAR FOUND: BOOLEAN);

PROCEDURE IOTRANSFER
  (DEVICE: IODEVICE; VAR PARAM: IOPARAM; VAR BLOCK: UNIV PAGE);

PROCEDURE IOMOVE(DEVICE: IODEVICE; VAR PARAM: IOPARAM);

FUNCTION TASK: TASKKIND;

PROCEDURE RUN(ID: IDENTIFIER; VAR PARAM: ARGLIST;
              VAR LINE: INTEGER; VAR RESULT: PROGRESULT);


PROGRAM P(VAR PARAM: ARGLIST);


"#################################################################
#  START(VAR OK: BOOLEAN; SOURCE: IDENTIFIER; INITIAL: BOOLEAN)  #
#################################################################"

"INSERT PREFIX HERE"


CONST

INITIAL_BASE = 24; OTHER_BASE = 88;
MAXLENGTH = 64;

VAR

OK: BOOLEAN; SOURCE, INITIAL: ARGTYPE;
BASE: INTEGER;

PROCEDURE WRITETEXT(TEXT: LINE);
VAR I: INTEGER; C: CHAR;
BEGIN
  I:= 0;
  REPEAT
    I:= I + 1;
    C:= TEXT(.I.);
    DISPLAY(C);
  UNTIL C = NL;
END;

PROCEDURE ERROR(TEXT: LINE);
BEGIN
  WRITETEXT(TEXT);
  OK:= FALSE;
END;

PROCEDURE HELP;
BEGIN
  IF OK THEN
  BEGIN
    WRITETEXT('TRY AGAIN(:10:)');
    WRITETEXT('     START(SYSTEM: IDENTIFIER) (:10:)');
    WRITETEXT('OR (:10:)');
    WRITETEXT
      ('     START(SYSTEM: IDENTIFIER; INITIAL: BOOLEAN) (:10:)');
    OK:= FALSE;
  END;
END;

PROCEDURE WRITEDISK(PAGENO: UNIV IOARG;
  VAR BLOCK: PAGE);
CONST MAXTIMES = 3;
VAR PARAM: IOPARAM; TIMES: INTEGER;
BEGIN
  WITH PARAM DO
  BEGIN
    OPERATION:= OUTPUT;
    ARG:= PAGENO;
    TIMES:= 0;
    REPEAT
      TIMES:= TIMES + 1;
      IOTRANSFER(DISKDEVICE, PARAM, BLOCK);
    UNTIL (STATUS = COMPLETE) OR
          (TIMES = MAXTIMES);
    IF STATUS <> COMPLETE THEN
      ERROR('DISK ERROR (:10:)');
  END;
END;

PROCEDURE COPY(BASE: INTEGER);
VAR PAGENO: INTEGER; BLOCK: PAGE;
BEGIN
  FOR PAGENO:= 1 TO LENGTH(1) DO
  BEGIN
    GET(1, PAGENO, BLOCK);
    WRITEDISK(BASE + PAGENO - 1, BLOCK);
  END;
END;

PROCEDURE CALL(BASE: UNIV IOARG);
VAR PARAM: IOPARAM;
BEGIN
  WITH PARAM DO
  BEGIN
    OPERATION:= CONTROL;
    ARG:= BASE;
  END;
  IOMOVE(DISKDEVICE, PARAM);
END;

PROCEDURE INITIALIZE(VAR BASE: INTEGER);
VAR ATTR: FILEATTR; FOUND: BOOLEAN;
BEGIN
  IDENTIFY('START: (:10:)');
  OK:= TRUE;
  SOURCE:= PARAM(.2.);
  WITH SOURCE DO
  IF TAG <> IDTYPE THEN HELP ELSE
  BEGIN
    LOOKUP(ID, ATTR, FOUND);
    IF NOT FOUND THEN
      ERROR('SOURCE FILE UNKNOWN(:10:)') ELSE
    IF ATTR.KIND <> CONCODE THEN
      ERROR('SOURCE KIND MUST BE CONCODE(:10:)');
    IF OK THEN
    BEGIN
      OPEN(1, ID, FOUND);
      IF LENGTH(1) > MAXLENGTH THEN
        ERROR('SOURCE FILE TOO LONG (:10:)');
    END;
  END;
  INITIAL:= PARAM(.3.);
  WITH INITIAL DO
  IF TAG = NILTYPE THEN
    BASE:= OTHER_BASE ELSE
  IF TAG <> BOOLTYPE THEN HELP ELSE
  IF BOOL THEN BASE:= INITIAL_BASE
          ELSE BASE:= OTHER_BASE;
END;

PROCEDURE TERMINATE;
BEGIN
  CLOSE(1);
  WITH PARAM(.1.) DO
  BEGIN TAG:= BOOLTYPE; BOOL:= OK END;
END;

BEGIN
  IF TASK = JOBTASK THEN
  BEGIN
    INITIALIZE(BASE);
    IF OK THEN COPY(BASE);
    IF OK THEN CALL(BASE);
    TERMINATE;
  END;
END.
                                                   