/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 3   9-25-70
       .TITLE .BE    RAISE REAL BASE (A) TO REAL POWER (B)  A**B
       .GLOBL .BE,.CB,.EE,.AK,.EF,.ER,.AB
/             CALLING SEQUENCE   (A//B = EXP(B * LOGE(A)))
/      JMS*   (.BE)           SUBR CALL (A IN FLOAT ACC)
/      CAL/XCT ADDR           ADDR OF B (XCT IF INDIRECT)
/      NEXT   INSTRUCTION     SUBR RETURN (RESULT IN FLOAT ACC)
/
.BE    CAL    0              /ENTRY-EXIT
       JMS*   .CB            /SHORT GET ARG (.CB)
BE02   CAL    0              /ARG ADDR (B)
	LAC* .AB		/GET BASE
	SZA
	JMP BE07
	ISZ BE02		/BUMP PAST EXP.
	LAC* BE02		/GET EXP. MANTISSA
	SPA!SNA!CLA		/GIVE 0 ANS. FOR EXP>-0
	JMS* .ER		/OTS 15
	AND 15			/DUMMY INSRUCT.
	JMP* .BE		/(50015). ANS=BASE
BE07       JMS*   .EE            /COMPUTE LOG2(A) (.EE)
       JMS*   .AK            /MULTIPLY REAL (.AK)
       .DSA   BE05           / (LOG2(A) * LOGE(2) = LOGE(A))
       JMS*   .AK            /MULTIPLY REAL (.AK)
       .DSA   BE02+400000    / (B X LOGE(A))
	JMS*   .EF            /COMPUTE EXP (.EF) (EXP(B * LOGE(A)))
       JMP*   .BE            /EXIT
BE05          140000         /LOGE(2) (1)  (0.6931471806)
              261344         /        (2)
       .END