/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 3   9-25-70
       .TITLE .BG    RAISE DOUBLE BASE (A) TO REAL POWER (B)  A**B
       .GLOBL .BG,.CB,.DE,.AS,.AK,.DF,.ER,.AB
/             CALLING SEQUENCE    (A**B = EXP (B * LOGE(A)))
/      JMS*   (.BG)           SUBR CALL  (A IN FLOAT ACC)
/      CAL/XCT ADDR           ADDR OF B  (XCT IF INDIRECT
/      NEXT   INSTRUCTION     SUBR RETURN (RESULT IN FLOAT ACC)
/
.BG    CAL    0              /ENTRY-EXIT
       JMS*   .CB            /SHORT GET ARG (.CB)
BG02   CAL    0              /ADDR OF B
	LAC* .AB		/CHECK BASE
	SZA
	JMP BG06
	ISZ BG02		/BY PASS EXP WORD
	LAC* BG02		/CHECK EXP MANTISSA
	SPA!SNA!CLA
	JMS* .ER		/OTS 15
	AND 15			/DUMMY INSTR. (500015)
	JMP* .BG		/ANS=BASE
BG06	JMS*   .DE            /COMPUTE LOG2(A) (.DE)
       JMS*   .AS            /MULTIPLY DOUBLE (.AS)
       .DSA   BG05           / (LOG2(A) * LOGE(2) = LOGE(A))
       JMS*   .AK            /MULTIPLY REAL (.AK)
       .DSA   BG02+400000    / (B X LOGE(A))
       JMS*   .DF            /COMPUTE EXP (.DF) (EXP (B * LOGE(A)))
       JMP*   .BG            /EXIT
BG05          0              /LOGE(2) (1)  (0.6931471806)
              261344         /        (2)
              137700         /        (3)
       .END