/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 01P   10-14-70
       .TITLE .DA    GET ARGUMENTS FOR INTRINSIC AND EXTERNAL FUNCTIONS
       .GLOBL .DA
/             CALLING SEQUENCE
/FNTN  CAL    0               FWA-1 OF LIST OF ARGUMENT ADDRESSES
/      JMS*   (.DA)           SUBR CALL
/      JMP    .+(N+1)         SUBR RETURN
/      CAL    0               STORAGE FOR ADDR OF ARG(1)
/      CAL    0                        .          ARG(2)
/       .     .                        .            .
/       .     .                        .            .
/      CAL    0                        .          ARG(N)
/
.DA    CAL    0              /ENTRY-EXIT
       LAC    .DA            /MASK OFF POSSIBLE
       AND    GARG10         /SIGN BIT SET FROM
       DAC    .DA            /LINK DURING JMS
       TAD    GARG09             /GET RETURN ADDR +1 FOR FWA OF LIST
       DAC    GARG04
       LAC    GARG01         /(ADD 1)
       TAD*   GARG04
       DAC    GARG05         /STORE AD -FROM-
       LAC    GARG01         /SET UP ADDR TO STORE INTO
       TAD    .DA
       DAC    GARG06         /STORE AS -TO-
       LAC      .DA
       AND     GARG07          /SAVE BANK BIT
       XOR*     .DA          /PICK UP JUMP AROUND LIST
       AND     GARG10          /KEEP N+1
       TAD    GARG09         /(ADD 2)  PRODUCE -N
       CMA                    /PRODUCE -(N+1)
       TAD    .DA
       DAC    GARG08         /STORE AS -N-
GARG02 LAC*   GARG05         /PICK UP ARG ADDR (FROM)
       SMA                   /INDIRECT IF MINUS
       JMP    GARG03
       DAC    GARG04
       LAC*   GARG04
GARG03 DAC*   GARG06         /STORE ARE ADDR (TO)
       ISZ    GARG05         /BUMP -FROM-
       ISZ    GARG06         /BUMP -TO-
       ISZ    GARG08         /N=N+1
       JMP    GARG02         /MORE ARGS-GET NEXT
       JMP*   .DA            /DONE-EXIT
GARG01        1
GARG04 CAL    0              /TEMP
GARG05 CAL    0              /FROM
GARG06 CAL    0              /TO
GARG07	70000		/MASK FOR PDP15 BK AND PG BITS
GARG08 CAL    0              /N
GARG09        777776
GARG10        77777          /ADDRESS MASK
       .END