.TITLE	.SPSER
/
/INTERNAL GLOBALS
	.GLOBL	.SPSER
/
/ EXTERNAL GLOBALS
	.GLOBL	.SPADD,.SPRML,.SPRLD,.SPRST,.LODBS
	.GLOBL	.ADDR1,.ADDR2
/
/
/
/ SINGLE PRECISION POWER SERIES EVALUATION
/ CALCULATES C1*X+C3*X**3+ . . . . +C13*X**13
/ ENTER WITH X IN ACC A,ADDRESS OF C13 IN AC
/ CONSTANTS MUST BE ARRANGED SEQUENTIALLY IN REVERSE ORDER
/ EXIT WITH SUM IN ACC A
/
.SPSER  XX
        DAC     PNTR    /ADDRESS OF C13 TO PNTR
        LAW     -6
        DAC     CNTR    /SET UP COUNTER
        LAC     .ADDR1
	JMS*	.SPRST
	JMS*	.LODBS
        JMS*    .SPRML  /X**2 IN ACC A
        LAC     .ADDR2
        JMS*    .SPRST  /STORE IN ADDR2
        LAC     PNTR
AGAIN   JMS*    .SPRLD  /LOAD X**2 EXCEPT FOR FIRST TIME IN LOOP
        JMS*    .SPRML  /MULTIPLY BY X**2
        LAC     PNTR
        TAD     (3
        DAC     PNTR    /BUMP POINTER
        JMS*    .SPRLD  /GET NEXT CONSTANT
        JMS*    .SPADD	/ADD
        LAC     .ADDR2
        ISZ     CNTR
        JMP     AGAIN   /LOOP UNTIL SUM COMPLETE
        LAC     .ADDR1
        JMS*    .SPRLD
        JMS*    .SPRML  /MULTIPLY BY X
        JMP*    .SPSER
/
CNTR
PNTR
	.END