ASMB,R,L,C
      NAM SWTCH,7 
      EXT EXEC,.ENTR
      ENT SWTCH 
* 
* 
ERR   NOP 
LU    NOP 
EQTX  NOP 
* 
* 
SWTCH NOP 
      JSB .ENTR       GET PARAMETERS
      DEF ERR         FROM CALLING PROGRAM
      LDA LU,I        GET LOGICAL UNIT
      STA B           AND SAVE IT 
      ADA DM1         FIRST, CHECK
      SSA             IF THE
      JMP ILLG        LOGICAL UNIT
      CMB,INB         IS GOOD 
      ADB 122B        AND THEN
      SSB             COMPUTE THE 
      JMP ILLG        EQT17 
      ADA 121B        ADDRESS 
      LDA A,I         CALL EXEC 
      ADA DM1         TO STORE
      MPY D17         THE SUPPLIED
      ADA 117B        EQT EXTENSION 
      ADA D3          ADDRESS 
      LDB A,I         GET AVABLITY FIELD
      SSB             AND CHECK IF BUSY 
      JMP BUSY        YES - RETURN
      ADA D13         NO - OK 
      STA TEMP        STORE TEMPORARY 
      LDA A,I         GET EQT EXTENSION 
      ADA D18         AND EQT 36 ADDRESS
      LDA A,I         AND EQT 36
      LDB EQTX        NEW EQT EXTENSION 
      ADB D18         NEW EQT 36
      STA B,I         STORE BOARD STATUS
      LDB TEMP        RESTORE B REGISTER
      LDA EQTX        EQT AND 
      JSB EXEC        RETURN WITH 
      DEF *+2         A-REGISTER TO 
      DEF DM19        ZERO
      CLA,RSS     
ILLG  CCA             ILLEGAL CODE
      STA ERR,I       INTO FIRST PAR. 
      JMP SWTCH,I     AND RETURN
BUSY  LDA DM2         BUSY RETURN 
      STA ERR,I       INTO FIRST PAR. 
      JMP SWTCH,I     WITH A=2
* 
* 
A     EQU 0 
B     EQU 1 
D18   DEC 18
TEMP  NOP 
DM2   DEC -2
DM1   DEC -1
DM19  DEC -19 
D3    DEC 3 
D17   DEC 17
D13   DEC 13
      END 
      END$
                                                