ASMB,R,L,C
      HED TYPE 5 MANAGER INTERFACE
*     NAM IDGT#,7 PRE-REL 7-22-76 (MOS) 
*     NAM IDGT#,7 09570-16499 REV. A 761013 
*     NAM IDGT#,7 PRE-REL 770213 (DLB)
      NAM IDGT#,7 PRE-REL 780402 (DLB) (RTE-IV) 
* 
*-------------------------------------------------------- 
* 
*     RELOC.       09570-16499
*     SOURCE       09570-18499
* 
*     M. SPANN           13 OCT 76 REV. 
* 
*---------------------------------------------------------
* 
      ENT IDGT#,IDMG# 
      EXT EXEC,.XLB 
* 
A     EQU 0 
B     EQU 1 
XEQT  EQU 1717B 
TAT   EQU 1656B 
TATSD EQU 1756B 
* 
IDMG# NOP 
      LDB IDMG# 
      STB IDGT# 
      CLB,INB,RSS 
IDGT# NOP 
      STB IDMG#     SAVE NUMBER OF MODULES TO :RP,
      STA TEMP
      INA 
      STA TEMP+1
      INA 
      STA TEMP+2
      LDA XEQT      GET IDSEGMENT ADDRESS OF THIS PROGRAM 
      ADA D26       BUMP TO THE DISC ADDRESS WORD 
      JSB .XLB      GET THE DISC ADDRESS WORD 
      DEF A,I       * LDB A,I 
      CLE,ELB       GET THE DISC LU IN E-REG
      LSR 8         POSITION DISC TRACK TO LO 8 BITS
      CLA,SEZ       CHECK IF ON LU = 3
      ADB TATSD     YES, LU = 3, ADD IN TRACKS IN LU = 2
      ADB TAT       INDEX INTO THE TAT TABLE
      JSB .XLB      GET THE VALUE IN THE TAT TABLE
      DEF B,I       * LDB B,I 
      CPB FMPTK     CHECK IF IS ON A FMGR TRACK?
      CLA,INA,RSS   YES, CONTINUE 
      JMP EXIT      NO, SKIP CALL TO T5IDM
      ELA           NOW CALCULATE IF ON LU = 2 OR 3 
      CMA,INA       MAKE NEGATIVE 
      STA CRN       AND SET TO CRN = -2 OR -3 
      JSB EXEC
      DEF RTN 
DEFER DEF SCHD
      DEF T5IDM 
TEMP  NOP           PARAMETERS TO PASS
      NOP 
      NOP 
      DEF IDMG#     NUMBER OF SEGMENTS
      DEF CRN       THE CARTRAGE OF THIS PROGRAM
RTN   NOP           T5IDM NOT FOUND 
EXIT  JMP IDGT#,I 
* 
SCHD  OCT 100027
D26   DEC 26
FMPTK OCT 77776 
T5IDM ASC 3,T5IDM 
CRN   NOP 
      END 
                                                                    