ASMB,R,L
      NAM CLASS,7    09580-16023 770120 
*-------------------------------------------------------------------
* 
*      RELOC.       09580-16023 
*      SOURCE       09580-18023 
*      ERS        A-09580-16023-1 
* 
*      C. LEATH     01/20/77    REV. A
* 
*      HP 92425A TEST SYSTEM SOFTWARE IS THE PROPRIETARY
*      MATERIAL OF THE HEWLETT-PACKARD COMPANY.  USE AND
*      DISCLOSURE THEREOF ARE RESTRICTED BY WRITTEN AGREEMENT.
* 
*      (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.
*      ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM
*      MAY BE PHOTOCOPIED, REPRODUCED OR TRANSLATED 
*      TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR
*      WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY.
* 
*-------------------------------------------------------------------
      EXT SVCLN 
      EXT DRTXX 
      EXT IPUT
      EXT .ENTR 
      ENT STCLN,RTCLN 
B     EQU 1 
* 
*     THIS SUBROUTINE IS USED TO STORE AND RETRIEVE 
*  CLASS NUMBERS FROM/TO THE 8 WORD CORE RESIDENT 
*  BUFFER SVCLN.
*     THE PARAMETERS IN THE CALLING SEQUENCE HAVE 
*  THE FOLLOWING MEANINGS:
* 
*     INDX = STATION NUMBER USED TO INDEX INTO SVCLN
*     ICLASS = CLASS NUMBER TO BE STORED
* 
INDX  NOP 
ICLAS NOP 
STCLN NOP 
      JSB .ENTR     RETRIEVE ADDRESSES
      DEF INDX
      LDB INDX,I
      JSB DRTX      COMPUTE INDEX INTO DRTXX TABLE TO GET REAL LU#
      ADB SV,I      FORM ADDR[SVCLN] + INDX ->[B] 
      INB           ACCOUNT FOR # OF STATIONS 
      STB ADDR
      JSB IPUT
      DEF RTN 
      DEF ADDR
      DEF ICLAS,I 
RTN   JMP STCLN,I 
* 
*RETRIEVE CLASS NUMBER
* 
INDEX NOP 
ICLS  NOP 
RTCLN NOP 
      JSB .ENTR 
      DEF INDEX 
      LDB INDEX,I 
      JSB DRTX
      ADB SV,I
      INB 
      LDA B,I 
      STA ICLS,I
      JMP RTCLN,I 
* 
DRTX  NOP 
      ADB DRT,I     ADDRESS OF DRTXX TABLE
      LDA B,I 
      AND .7        LU #
      STA B 
      JMP DRTX,I
SV    DEF SVCLN 
DRT   DEF DRTXX 
.7    DEC 7 
ADDR  NOP 
      END 
          