  
100  PRINT "***************************************"
110  PRINT "   5327A-H48 RTE B DEVICE SUBROUTINE" 
120  PRINT "         VERIFICATION TEST" 
125  REM
126  REM *     SOURCE TAPE:  09601-18016
127  REM *     ERS:  09601-18016-1
130  PRINT "***************************************"
140  PRINT  
150  PRINT  
500  PRINT "          FREQUENCY 'A' TEST" 
510  PRINT "          ------------------" 
515  PRINT  
520  LET H=0
540  PRINT " 1-CONNECT SIGNAL GENERATOR TO 'CHANNEL A'" 
542  PRINT "   INPUT OF COUNTER"
544  PRINT  
546  PRINT " 2-SET SIG. GEN. TO 100 KHZ"
548  PRINT  
550  PRINT " 3-TYPE 'GO'" 
555  PAUSE  
556  GOSUB 5000 
560  LET F=100000 
565  FOR T=4 TO 8 
570  CTRSF(1,T,0,0,0,0,1) 
575  GOSUB 6000 
580  NEXT T 
600  PRINT  
610  PRINT "          PERIOD 'A' TEST"
612  PRINT "          ---------------"
614  PRINT  
620  PRINT "SET SIG. GEN. TO 10 HZ & TYPE 'GO'" 
630  PAUSE  
640  LET H=1
645  GOSUB 5000 
650  LET F=10 
660  FOR T=0 TO 3 
670  CTRSF(2,T,0,0,0,0,1) 
675  GOSUB 6000 
680  NEXT T 
699  PRINT  
700  PRINT "          PERIOD AVG. 'A' TEST" 
702  PRINT "          --------------------" 
704  PRINT  
710  PRINT "SET SIG. GEN. TO 1 KHZ & TYPE 'GO'" 
711  PAUSE  
720  GOSUB 5000 
725  LET T=2
730  CTRSF(6,T,0,0,0,0,1) 
735  LET F=1000 
740  GOSUB 6000 
799  PRINT  
800  PRINT "          TIME INTERVAL 'A' TO 'B' TEST"
802  PRINT "          -----------------------------"
804  PRINT  
820  GOSUB 5000 
830  REM * DOUBLE 'F' SINCE ONLY HALF A PERIOD IS MEASURED
831  LET F=2000 
840  LET T=0
845  CTRSF(7,T,0,3,0,0,1) 
850  GOSUB 6000 
899  PRINT  
900  PRINT "          TIME INTERVAL AVG. 'A' TO 'B' TEST" 
902  PRINT "          ----------------------------------" 
904  PRINT  
910  PRINT "TYPE 'GO' WHEN READY" 
915  PAUSE  
920  GOSUB 5000 
925  LET T=2
930  CTRSF(8,T,0,3,0,0,1) 
940  GOSUB 6000 
999  PRINT  
1000  PRINT "          'CHECK' FUNCTION TEST" 
1002  PRINT "          ---------------------" 
1004  PRINT 
1020  LET H=0 
1025  LET F=1E+07 
1030  GOSUB 5000
1040  CTRSF(10,T,0,0,0,0,1) 
1050  GOSUB 6000
1099  PRINT 
1100  PRINT "          START/STOP TEST" 
1102  PRINT "          ---------------" 
1104  PRINT 
1120  PRINT "SET SIG. GEN. TO 10 KHZ & TYPE 'GO'" 
1125  PAUSE 
1126  LET H=2 
1128  GOSUB 5000
1130  LET T=1 
1135  CTRSF(4,T,0,0,0,0,1)
1140  WAIT 900
1150  CTRSF(5,T,0,0,0,0,1)
1155  LET F=10000 
1160  GOSUB 6000
1199  PRINT 
1200  PRINT "          FREQUENCY 'C' TEST"
1202  PRINT "          ------------------"
1204  PRINT 
1220  LET H=0 
1230  PRINT "1-CONNECT SIG. GEN. TO FREQ.'C' INPUT OF COUNTER"
1232  PRINT "2-SET SIG. GEN. TO 100 KHZ." 
1234  PRINT "3-TYPE 'GO'" 
1240  PAUSE 
1245  GOSUB 5000
1250  LET F=100000
1255  LET T=5 
1260  CTRSF(3,T,0,0,0,0,1)
1270  GOSUB 6000
1299  PRINT 
1300  PRINT "          FREQUENCY 'C/10' TEST" 
1302  PRINT "          ---------------------" 
1304  PRINT 
1310  GOSUB 5000
1320  CTRSF(9,T,0,0,0,0,1)
1330  GOSUB 6000
2000  STOP  
4999  REM 
5000  REM * SUBROUTINE TO PRINT HEADING * 
5010  REM 
5020  PRINT 
5030  PRINT "RANGE","PROGRAMMED","MEASURED","DEVIATION","TOLERANCE" 
5035  PRINT "(TIMEBASE)", 
5040  IF H=0 PRINT "  HZ","  HZ", 
5050  IF H=1 PRINT "  SECS","  SECS", 
5060  IF H=2 PRINT "  VALUE","  VALUE", 
5070  PRINT "   %","   %" 
5080  PRINT 
5090  RETURN  
5999  REM 
6000  REM * SUBROUTINE TO MEASURE & PRINT DATA *
6010  REM 
6020  CTRMF(V,D)
6030  IF H#1 LET X=F
6040  IF H=1 LET X=1/F
6050  LET T0=100*(V-X)/X
6052  IF T<3 PRINT 10^(T-1);TAB(4);"US",
6054  IF T>2 AND T<6 PRINT 10^(T-4);TAB(4);"MS",
6056  IF T>5 PRINT 10^(T-7);TAB(4);"S", 
6060  PRINT X,V,T0,10;TAB(0); 
6070  IF ABS(T0)>10 PRINT "  FAIL *"
6080  IF ABS(T0) <= 10 PRINT  
6090  RETURN  
            