ASMB,L
      HED SENSE -- EVENT SENSE INTERRUPT HANDLER  09611-18007 
*    * * *  S E N S E -- EVENT SENSE INTERRUPT HANDLER  * * * 
* 
* 
*   BIN. RELOC. TAPE:    09611-16007  REV A 
*   SOURCE TAPE:         09611-18007  REV A 
*   MANUAL:              09611-90010  JUNE, 1975
* 
*   AUTHOR:  JULIA A. CATES 
* 
*   VERSION:  MAY, 1975 
* 
*      SENSE, EVENT SENSE INTERRUPT HANDLER, RETRIEVES THE
*  SLOT, DATA AND SELECT CODE INFORMATION OF INTERRUPTING 
*  6940 MULTIPROGRAMMER I/O CARDS.  SENSE PRINTS THIS INFOR-
*  MATION ON THE SYSTEM CONSOLE, SO THAT THE USER MAY VERIFY
*  PROPER FUNCTIONING OF THE MULTIPROGRAMMER. 
* 
* 
      NAM SENSE,2,89    09611-16007  REV A   20MAY75
* 
      ENT SENSE 
      EXT EXEC
      SUP 
* 
* 
SENSE LDA B,I 
      STA SLOT# 
      INB 
      LDA B,I 
      STA DATA
      ADB .3
      LDA B,I 
      AND MSK77 
      STA CHAN# 
PSLOT LDA SLOT#    PREPARE INTERRUPT DATA FOR OUTPUT. 
      ADA MIN18 
      SSA,RSS      CHECK FOR VALID SLOT NUMBER. 
      JMP PDATA 
      LDA .14 
      STA TXT1L 
      LDA SLOT#    \
      CLB           \ 
      DIV .10        \
      ADB B60         \  CONVERT THE SLOT NUMBER TO 
      ADA B60         /  THE ASCII REPRESENTATION 
      ALF,ALF        /   OF A DECIMAL NUMBER. 
      IOR B         / 
      STA BUFR1    /
PDATA LDA TXPT2 
      LDB DATA
      JSB OCTAS 
      LDA TXPT3 
      LDB CHAN# 
      JSB OCTAS 
START LDA TXT1D    START OUTPUT.
      LDB TX1LD     PRINT THE SLOT NUMBER 
      JSB OUTPT      ON THE TELETYPE. 
      LDA TXT2D 
      LDB TX2LD     PRINT THE DATA OF THE 
      JSB OUTPT       INTERRUPTING CARD.
      LDA TXT3D 
      LDB TX3LD     PRINT THE SELECT CODE OF
      JSB OUTPT    THE 6940 THAT INTERRUPTED. 
CONT  JSB EXEC
      DEF *+2 
      DEF RCOD6     COMPLETION CALL.
      SKP 
* 
*    VARIABLES, CONSTANTS 
* 
SLOT# NOP 
TXPT2 DEF BUFR2 
DATA  NOP 
TXPT3 DEF BUFR3 
CHAN# NOP 
ICNWD OCT 1 
.3    OCT 3 
RCOD6 OCT 6 
.10   DEC 10
.14   DEC 14
MIN18 DEC -18 
B60   OCT 60
MSK77 OCT 77
* 
A     EQU 0 
B     EQU 1 
* 
TEXT1 ASC 13, THE INTERRUPTING SLOT IS
BUFR1 ASC 4,INVALID 
TXT1L DEC 17
TXT1D DEF TEXT1 
TX1LD DEF TXT1L 
TEXT2 ASC 7, THE DATA IS
      NOP 
      NOP 
BUFR2 NOP 
TXT2L DEC 10
TXT2D DEF TEXT2 
TX2LD DEF TXT2L 
TEXT3 ASC 13, THE 6940 SELECT CODE IS 
      NOP 
      NOP 
BUFR3 NOP 
TXT3L DEC 16
TXT3D DEF TEXT3 
TX3LD DEF TXT3L 
      SKP 
* 
*    SUBROUTINE OCTAS -- OCTAL TO ASCII CONVERSION
* 
*  "OCTAS" USES THE B REGISTER AS THE INTEGER TO BE 
*  CONVERTED.  THE A REGISTER CONTAINS A POINTER TO 
*  THE STORAGE LOCATION OF THE 3 ASCII WORDS. 
* 
OCTAS NOP 
      STA BFRPT 
      LDA MIN3
      STA CNTR
GOON  LDA B 
      AND MK7 
      STA TEMP2 
      LDA B 
      AND M7770 
      STA TEMP1 
      ALF,ALS 
      AND M3400 
      IOR TEMP2 
      ADA ASCII 
      STA BFRPT,I 
      ISZ CNTR
      RSS 
      JMP DONE
      LDB BFRPT 
      ADB MIN1
      STB BFRPT 
      LDB TEMP1 
      BRS,BRS 
      BRS,BRS 
      BRS,BRS 
      JMP GOON
DONE  JMP OCTAS,I 
* 
BFRPT NOP 
TEMP1 NOP 
TEMP2 NOP 
ASCII OCT 30060 
MIN1  OCT -1
MIN3  OCT -3
CNTR  OCT 3 
MK7   OCT 7 
M3400 OCT 3400
M7770 OCT 177770
      SKP 
* 
* 
*     SUBROUTINE OUTPT -- OUTPUT DATA 
* 
*  OUTPT OUTPUTS THE SLOT NUMBER, DATA AND SELECT CODE
*  OF THE INTERRUPTING 6940 CARD TO THE SYSTEM CONSOLE. 
* 
OUTPT NOP 
      STA TEXT
      STB TEXTL 
      JSB EXEC
      DEF *+5 
      DEF RCOD2      WRITE CALL.
      DEF ICNWD 
TEXT  NOP 
TEXTL NOP 
      JMP OUTPT,I 
* 
RCOD2 OCT 2 
* 
* 
      END SENSE 
      END$
                                                                                                                  