CLF INTP      TURN INTPS OFF
SMIO1 CLC SSMI      INPUT SELECTTOR TO SELS 
SMIO2 LIA SSMI      GET INTERFACE STATUS
      AND NRNG      MASK OFF RING 
      STA XSSMI     SAVE
      AND SMMI      GENERATE NEW ARM
      IOR SMIA
SMIO3 OTA SSMI      OUTPUT COMMAND
SMIO4 STC SSMI      SET CONTROL 
      JSB PTG       PLACE TO GO IF ANOTHER INT
      DEF DMIX
      DEF CMCCA-1   DONE
      STF INTP      ENABLE INTERRUPTS 
      JMP IRTN,I    RETURN
XSSMI BSS 1 
SMMI  ABS CLS+DSR+RLS 
SMIA  ABS 100000B+ARMC
NRNG  ABS -RNG-SRLS-1 
      SPC 2 
CMNDI NOP           RETURN ADDRESS
      LDA CMNDI,I   GET COMMAND 
      STA CMPI1 
      ISZ CMNDI 
      LDA CMNDI,I   GET EXPECTED STATUS 
      STA CMPI2 
      ISZ CMNDI 
      LDA CMNDI,I   GET ERROR POINTER 
      STA CMPI3 
      ISZ CMNDI     UPDATE RETURN 
      JSB PTG       PLACE TO GO 
      DEF SMI1      INTERRUPT 
      DEF CMNIC     DONE
      JSB CLF       CLEAR FLAG
      JSB STC       SET CONTROL 
      STF INTP      TURN ON INTERRUPTS
      JSB CMND
      ABS MASKC+CLSM+DSRM+RLSM
      JSB CNTRL 
CMPI1 BSS 1         COMMAND 
      CLF INTP      TURN INTERRUPT SYSTEM OFF 
      JSB ERMS,I    REPORT TIMEOUT
      DEF EM153 
      JSB RSTUS     READ STATUS 
      AND NRNG      MASK OFF RING 
      RSS           SKIP
CMNIC LDA XSSMI     GET STATUS
      LDB CMCCA 
      STB CSTUS 
      CLF INTP      TURN INTERRUPT SYSTEM OFF 
      JMP CSC01     CHECK STATUS
CMPI2 BSS 1         EXPECTED STATUS 
CMPI3 DEF *-* 
      STF INTP      TURN INTERRUPT SYSTEM ON
      JMP CMNDI,I   RETURN
CMCCA DEF CMPI2 
      SPC 2 
CBUFS NOP           RETURN ADDRESS
      CLA 
      STA NOERS     CLEAR ERROR FLAG
      LDA CBUFS,I   GET ERROR POINTER 
      STA CBERR 
      LDA MD32      INITIALIZE COUNT
      STA CBCNT 
      LDA TDATA     INITIALIZE POINTERS 
      ALS 
      STA BUFFA 
      LDA ABUFB 
      ALS 
      INA 
      STA BUFFB 
CBC02 LDA CBC1A 
      STA CDATA 
      LDB BUFFA 
      JSB GUPLO     GET EXPECTED DATA 
      ISZ BUFFA 
      STA CEXPD     SAVE
      LDB BUFFB 
      ISZ BUFFB 
      JSB GUPLO     GET ACTUAL DATA 
      LDB A 
      JMP CDAC1     CHECK DATA
CEXPD BSS 1         EXPECTED DATA 
CBERR DEF *-*       ERROR MESSAGE POINTER 
      ISZ NOERS     CHECK FOR EXTENDED ERROR REPORT 
      RSS 
      JMP CBC03     EXIT NO MORE ERRORS ALLOWED 
      ISZ CBCNT     DONE? 
      JMP CBC02     CONTINUE
CBC03 ISZ CBUFS     UPDATE RETURN 
      JMP CBUFS,I   RETURN
CBCNT BSS 1 
CBC1A DEF CEXPD 
      SPC 2 
DMS1  NOP           RETURN ADDRESS
      JSB CNTRL     CONTROL COMMAND 
      ABS CNTLC+DTR+RQS+DMAEN 
      JSB CMND      START COMMAND 
      ABS STRTC 
      JSB MCLK      SET ACTV
      JSB MCLK      SET BYMD AND DRQ
      JMP DMS1,I    RETURN
      SPC 2 
DMS2  NOP           RETURN ADDRESS
      JSB MRST      MASTER RESET
      LDA CPTO      GET COMPUTER OPTIONS
      RAR,RAR 
      SLA,RSS 
      JMP DMC05     CONTINUE - NO DMA 
      JSB STSUB 
      OCT 151 
      JSB CLBFR     CLEAR BUFFER
      JSB CMNDI     INITIALIZE INTERFACE
      ABS CNTLC+DTR 
      ABS CHECK+CHECK+MRQ+DSRI+DSR
      DEF EM151 
      JSB CMNDI 
      ABS CNTLC+DTR+RQS 
      ABS CHECK+CHECK+MRQ+CLSI+CLS+DSR
      DEF EM151 
      JSB SUBUP     UPDATE SUB. TEST NO.
      JSB UNPCK 
      JSB DMAON     TURN ON DMA 
      DEF DMABF 
      JSB STSUB 
      OCT 146 
      LDA ABUFB     BUFFER POINER 
      ALS 
      STA BUFFB 
      LDA MD33
      STA DMCNT     COUNT 
      JSB PTG       PLACE TO GO 
      DEF DMIX      SMI INTERRUPT 
      DEF DMC06     INTERRUPT RETURN
      JSB CMND      START COMMAND 
      ABS STRTC 
      JSB CMND      ENABLE DMA
      ABS CNTLC+DTR+RQS+DMAEN 
      JSB MCLK      SUPPLY CLOCK
      JSB MCLK      SUPPLY CLOCK
DMC07 JSB SDOU      SUPPLY COOCKS 
      LDB BUFFB 
      JSB STC       SET CONTROL 
      JSB PUPLO     PUT CHARACTER IN BUFFER 
      ISZ BUFFB 
      ISZ DMCNT     UPDATE COUNTER
      JMP DMC07     CONTINUE
      JSB CMND      STOP COMMAND
      ABS STOPC 
      JSB DMAOF     TURN DMA OFF
      CLF INTP      TURN INTERRUPT SYSTEM OFF 
      JSB CBUFS     CHECK DATA
      DEF EM146 
      STF INTP      TURN INTERRUPT SYSTEM ON
      JSB SHUTA 
      JSB STSUB 
      OCT 151 
      JSB CMNDI     PREPARE INTERFACE FOR INPUT 
      ABS CNTLC+DTR 
      ABS CHECK+CHECK+MRQ+CLSI+DSR
      DEF EM151 
      JSB CMNDI 
      ABS CNTLC+DTR+SRQS
      ABS CHECK+CHECK+MRQ+RLSI+RLS+DSR
      DEF EM151 
      JSB STSUB 
      OCT 147 
      JSB CLBFR     CLEAR BUFFER
      JSB DMAON     START DMA 
      DEF DMABF,I   DMA BUFFER
      JSB RCVI      START RECIIVE 
      JSB CMND
      ABS CNTLC+SRQS+DTR+DMAEN
      LDA TDATA     BUFFER ADDRESS
      ALS 
      STA BUFFA 
      LDA MD33
      STA DMCNT 
      JSB GSYNC     GET SYNC CHARACTER
      STA DMSY1 
      STA DMSY2 
      JSB SDIN      PROVIDE SYNC
DMSY1 BSS 1         SYNC
      JSB SDIN      PROVIDE SYNC
DMSY2 BSS 1         SYNC
      JSB LIA       INPUT SELECTOR TO SELD
DMC08 LDB BUFFA 
      JSB GUPLO     GET TEST DATA 
      STA DMPD1 
      JSB SDIN      PROVIDE DATA
DMPD1 BSS 1         TEST DATA 
      ISZ BUFFA     UPDATE BUFFER POINTER 
      ISZ DMCNT     UPDATE COUNT
      JMP DMC08     CONTINUE
      JSB DMAOF     TURN DMA OFF
      JSB PACK
      JSB CBUFS 
      DEF EM147 
      JSB STSUB 
      OCT 151 
      JSB CMNDI 
      ABS CNTLC+DTR 
      ABS CHECK+CHECK+MRQ+RLSI+DSR
      DEF EM151 
      JSB CMNDI 
      ABS CNTLC 
      ABS CHECK+CHECK+MRQ+DSRI
      DEF EM151 
      JSB SUBTT 
DMC06 EQU * 
      JMP DMS2,I
      SPC 1 
DMC05 JSB MSGC,I
      DEF HM152 
      JMP DMC06 
DMCNT BSS 1 
      SPC 2 
DMAON NOP           RETURN ADDRESS
      LDA DMACF     PLACE 
      STA SDMAH     CLF IN TRAP CELL
      LDA CW1       GET COMMAND WORD 1
      OTA SDMAH     OUTPUT TO DMA 
      CLC SDMAL     PREPARE FOR CW2 
      LDA DMAON,I   INPUT OR OUTPUT + 
      OTA SDMAL     ADDRESS TO DMA
      STC SDMAL     PREPARE FOR CW3 
      LDA CW3       GET CONTROL WORD 3
      OTA SDMAL     OUTPUT TO DAM 
FNIO5 STC SSMI,C    START SMI 
      STC SDMAH,C   START DMA 
      ISZ DMAON     UPDATE RETURN 
      JMP DMAON,I   RETURN
      SPC 1 
CW1   ABS SSMI      CONTROL WORD 1
MD32  DEC -32 
DMACF CLF SDMAH     CLEAR DMA FLAG
CW3   EQU * 
MD33  DEC -33 
      SPC 2 
DMAOF NOP           RETURN ADDRESS
      CLF SDMAH     TRUN OFF DMA
      LIA SDMAL     GET COUNT 
      SZA,RSS       CHECK COUNT = 0 
      JMP DMAOF,I   RETURN
      CLF INTP      TURN OFF INTERRUPTS 
      JSB ERMS,I    REPORT ERROR
      DEF EM150 
      JMP DMAOF,I   RETURN
      SPC 2 
DMIX  NOP           RETURN ADDRESS
      CLF INTP      TURN OFF INTERRUPTS 
      CLF SDMAH     STOP DMA
      JSB RDDTA     GET ACTUAL DATA AND STATUS
      JSB ERMS,I    REPORT ERROR
      DEF EM154 
      JMP IRTN,I    CONTINUE
      SPC 2 
GSYNC NOP           RETURN ADDRESS
      LDA USSC      GET CONFIGURATION DATA
      ALF,ALF       ISOLATE SYNC CHARACTER
      ALF,RAR 
      RAR 
      AND LOHWD     MASK
      JMP GSYNC,I   RETURN
      SPC 2 
CLBFR NOP           RETURN ADDRESS
      LDB MD38      INITIALIZE COUNTER
      CLA           CLEAR 
      STB CLCNT 
      LDB ABUFB     BUFFER POINTER
      BLS 
CLC01 JSB PUPLO     CLEAR BUFFER
      INB           UPDATE POINTER
      ISZ CLCNT     UPDATE COUNT
      JMP CLC01     CONTINUE
      JMP CLBFR,I   RETURN
CLCNT BSS 1         COUNTER 
      SPC 2 
PACK  NOP           RETURN ADDRESS
      LDA ABUFD 
      STA BUFFA 
      LDB ABUFB 
      BLS 
      INB 
      LDA MD32
      STA MYCNT 
MYC01 LDA BUFFA,I 
      JSB PUPLO 
      INB 
      ISZ BUFFA 
      ISZ MYCNT 
      JMP MYC01     CONTINUE
      JMP PACK,I    RETURN
      SPC 1 
MYCNT BSS 1 
      SPC 1 
UNPCK NOP           RETURN ADDRESS
      LDB TDATA 
      BLS 
      LDA ABUFD 
      STA BUFFB 
      LDA MD32
      STA MYCNT 
MYC02 JSB GUPLO 
      STA BUFFB,I 
      INB 
      ISZ BUFFB 
      ISZ MYCNT 
      JMP MYC02     CONTINUE
      JMP UNPCK,I   RETURN
      SKP 
CSTUS NOP           RETURN ADDRESS
      JSB RSTUS     GET INTERFACE STATUS
CSC01 STA STAT      SAVE ACTUAL STATUS
      LDA CSTUS,I   GET EXPECTED STATUS 
      ISZ CSTUS     UPDATE RETURN 
      CPA STAT      CHECK STATUS
      JMP CSXIT     CONTINUE
      STA EXSTS     SAVE EXPECTED STSTUS
      LDA CSTUS,I   GET ERROR MESSAGE 
      STA CSFRM     SAVE
      LDA EMCS3 
      STA CSTO
      JSB MOVE
CSTO  DEF *-* 
CSFRM DEF *-* 
      LDA EXSTS     GET EXPECTED STATUS 
      CLE 
      LDB EMCS2 
      JSB O2AS,I
      LDA STAT      GET ACTUAL STATUS 
      CLE 
      LDB EMCS1 
      JSB O2AS,I
      JSB ERNO      GET SUB-TEST NO.
      DEF EMCS
      LDA STAT      GET ACTUAL STATUS 
      LDB EXSTS     GET EXPECTED STATUS 
      JSB ERMS,I    OUTPUT ERROR
      DEF EMCS
CSXIT ISZ CSTUS 
      JMP CSTUS,I    RETURN 
EMCS  ASC 8,EXXX STATUS IS
EMS1  ASC 6,XXXXXX EXP
EMS2  ASC 4,YYYYYY (
EMS3  ASC 10, 
EMCS1 DEF EMS1
EMCS2 DEF EMS2
EMCS3 DEF EMS3
STAT  BSS 1         ACTUAL STATUS 
EXSTS BSS 1 
      SKP 
MOVE  NOP           RETURN ADDRESS
      LDB MOVE,I    GET TO
      ISZ MOVE
      LDA .M10
      STA MVCNT 
      LDA MOVE,I GET FROM 
      STA MVFRM 
MVC01 LDA MVFRM,I    GET DATA 
      STA B,I        PUT DATA 
      INB 
      ISZ MVFRM 
      ISZ MVCNT 
      JMP MVC01 
      ISZ MOVE
      JMP MOVE,I    RETURN
MVCNT BSS 1 
.M10  DEC -10 
MVFRM DEF *-* 
      SKP 2 
RDDTA NOP           RETURN ADDRESS
FNIO6 CLC SSMI      INITIALIZE INPUT SELECTOR TO
*                              STATUS 
INIO1 LIA SSMI      GET STATUS
INIO2 LIB SSMI      GET DATA
      JMP RDDTA,I   RETURN
      SPC 2 
CDATA NOP           RETURN ADDRESS
      JSB RDDTA     GET DATA FROM INTERFACE 
CDAC1 STB DATA
      LDA CDATA,I   GET EXPECTED DATA 
      ISZ CDATA     UPDATE RETURN 
      CPA DATA      CHECK DATA
      JMP CDXIT     CONTINUE
      STA EXDAT     SAVE EXPECTED DATA
      LDA CDATA,I   GET MESSAGE POINTER 
      STA CDFRM 
      LDA EMCD3 
      STA CDTO
      JSB MOVE
CDTO  DEF *-* 
CDFRM DEF *-* 
      LDA EXDAT     GET EXPECTED DATA 
      CLE 
      LDB EMCD2 
      JSB O2AS,I    CONVERT TO ASCII
      LDA DATA      GET ACTUAL DATA 
      CLE 
      LDB EMCD1 
      JSB O2AS,I    CONVERT TO ASCII
      JSB ERNO      PLACE E NO. 
      DEF EMCD
      LDA DATA      GET ACTUAL DATA 
      LDB EXDAT     GET EXPECTED DATA 
      JSB ERMS,I    REPORT ERROR
      DEF EMCD
      LDB SW2       GET MASK FOR SW 2 
SWJSB JSB SWRT,I    CHECK SWITCH REGISTER 
      CLA,RSS       CLEAR FLAG
      CCA           SET FLAG
      STA NOERS     SAVE ERROR FLAG 
CDXIT ISZ CDATA     UPDATE RETURN 
      JMP CDATA,I   RETURN
      SPC 2 
EMCD  ASC 7,EXXX DATA IS
EMD1  ASC 6,XXXXXX EXP
EMD2  ASC 4,YYYYYY (
EMD3  ASC 10, 
EMCD1 DEF EMD1
EMCD2 DEF EMD2
EMCD3 DEF EMD3
DATA  BSS 1         ACTUAL DATA 
EXDAT BSS 1         EXPECTED DATA 
NOERS BSS 1 
D4    EQU * 
SW2   OCT 4 
      SKP 
HM152 ASC 19,H152 DMA DATA TRANSFER OMITTED-NO DMA/ 
EM153 ASC 16,E153 MISSING INT. DURING STATUS/ 
EM154 ASC 14,E154 INT. WHEN NOT EXPECTED/ 
EM155 ASC 17,E155 MISSING INT. DURING TRANSMIT/ 
BSPGO EQU * 
      SKP 
      ORG ZCEND 
IOID  EQU * 
      DEF FNIO0 
      DEF FNIO1 
      DEF CNIO1 
      DEF CNIO2 
      DEF CNIO3 
      DEF CNIO4 
      DEF CNIO5 
      DEF CNIO6 
      DEF CNIO7 
      DEF CNIO8 
      DEF OTIO1 
      DEF FNIO2 
      DEF FNIO5 
      DEF FNIO6 
      DEF STIO1 
      DEF INIO1 
      DEF INIO2 
      DEF SMIO1 
      DEF SMIO2 
      DEF SMIO3 
      DEF SMIO4 
      DEF SMIO6 
      DEF CW1 
      DEC -1
TSTD  EQU * 
      DEF TST00 
      DEF TST01 
      DEF TST02 
      DEF TST03 
      DEF TST04 
      DEF TST05 
      DEF TST06 
      DEF TST07 
      DEF TST10 
      DEF TST11 
      DEC -1
      SKP 
SMPDA OCT 015433      SYNC,SYNC 
EM030 ASC 14,E030 FLAG NOT SET BY CLC 0/
EM031 ASC 16,E031 CONTROL NOT RESET BY CLC 0/ 
EM032 ASC 13,E032 FLAG NOT SET BY MRST/ 
EM033 ASC 16,E033 CONTROL NOT RESET BY MRST/
EM034 ASC 5,RQS, CLS)/
EM035 ASC 8,DTR, DSR, RNG)/ 
EM036 ASC 9,SRQS, RLS, SRLS)/ 
EM037 ASC 24,E037 STATUS NOT RECVD ON 1ST INPUT AFTER CLC CH/ 
EM040 ASC 22,E040 STATUS RECVD ON 2ND INPUT AFTER CLC CH/ 
EM041 ASC 24,E041 STATUS NOT DECVD ON 1ST INPUT AFTER STC CH/ 
EM042 ASC 3,MRST)/
EM043 ASC 12,E043 STATUS REVD AFTER 
      ASC 11,MASTER RESET COMMAND/
EM044 ASC 6,RNGI, DSRI)/
EM045 ASC 7,RLSI, SRLSI)/ 
EM046 ASC 3,CLSI)/
EM047 ASC 3,DSRA)/
EM050 ASC 3,CLSA)/
EM051 ASC 3,RLSA)/
EM052 ASC 4,SRLSA)/ 
EM053 ASC 6,MASK, MRST)/
EM054 ASC 6,ARM, MRST)/ 
EM055 ASC 17,E055 FLAG SET - LOCK INOPERATIVE/
EM056 ASC 13,E056 FLAG NOT SET - DEVRQ/ 
EM057 ASC 8,TSDTA)/ 
EM060 ASC 3,RQS)/ 
EM061 ASC 4,RECVT)/ 
EM062 ASC 4,TRDTA)/ 
EM063 ASC 3,RUN)/ 
EM064 ASC 6,RUN, STOP)/ 
EM065 ASC 6,RUN, MRST)/ 
EM066 ASC 3,ACTV)/
EM067 ASC 6,ACTV, STOP)/
EM100 ASC 3,HUNT)/
EM101 ASC 6,HUNT, STOP)/
EM102 ASC 3,BYMD)/
EM103 ASC 6,BYMD, STOP)/
EM104 ASC 3,BCOV)/
EM105 ASC 4,BCOV+1)/
EM106 ASC 4,BCOV+8)/
EM107 ASC 6,BCOV, STOP)/
EM110 ASC 3,DRQ)/ 
EM111 ASC 6,DRQ, STOP)/ 
EM112 ASC 13,E112 FLAG NOT SET BY DRQ/
EM113 ASC 6,DRQ, DATA)/ 
EM114 ASC 6,DRQ, BCOV)/ 
EM115 ASC 6,DRQ, INPUT)/
EM116 ASC 3,DERR)/
EM117 ASC 7,DERR, SRSTC)/ 
EM120 ASC 3,MRST)/
EM121 ASC 6,SHIFT ONES)/
EM122 ASC 4,SDOUT)/ 
EM123 ASC 7,SDOUT, MRST)/ 
EM124 ASC 6,DATA PATH)/ 
EM125 ASC 6,PARITY ODD)/
EM126 ASC 7,PARITY EVEN)/ 
EM127 ASC 5,E127 SYND=
E127A ASC 1,
      ASC 3,DATA= 
E127B ASC 4,XXXXXX/ 
EM130 ASC 6,BYMD, SYND)/
EM131 ASC 8,BYMD, NOT SYND)/
EM132 ASC 6,HUNT, SYND)/
EM133 ASC 6,NO PARITY)/ 
EM134 ASC 3,PERR)/
EM135 ASC 4,RPERR)/ 
EM136 EQU * 
EM137 ASC 5,TRANSMIT)/
EM140 EQU * 
EM141 ASC 5,RECEIVE)/ 
EM142 ASC 19,E142 FLAG SET WITH DMA ENABLED (DRQ)/
EM143 ASC 17,E143 FLAG SET BY CHECK WITH (SRQ)/ 
EM144 ASC 19,E144 FLAG NOT SET AFTER CLF CH (SRQ)/
EM145 ASC 13,E145 SRQ SET WHILE LOCK=1/ 
EM146 ASC 7,DMA TRANSMIT)/
EM147 ASC 7,DMA RECEIVE)/ 
EM150 ASC 15,E150 DMA ABNORMAL COMPLETION/
EM151 ASC 5,DMA TEST)/
      SKP 
TST01 EQU * 
MRTST NOP           RETURN ADDRESS
      JSB STSUB     SAVE SUB-TEST NO. 
      OCT 30        SUB-TEST NO.
      JSB CLF       CLEAR INTERFACE FLAG
      CLC IOCLR     I/O MASTER RESET
      JSB SFS       CHECK INTERFACE FLAG FF 
      RSS 
      JMP MRC01     CONTINUE
      JSB ERMS,I    REPORT ERROR
      DEF EM030     ERROR MESSAGE POINTER 
MRC01 JSB SHUTA     CHECK SUB-TEST HALT,LOOP
      JSB CLF       CLEAR INTERFACE FLAG
      JSB STC       SET INTERFACE CONTROL FF
      JSB TRJSB,I   FILL INTERRUPT TRAP CELL
      DEF MRIR1     WHERE TO GO IF INTERRUPT
      STF INTP      ENABLE INTERRUPT SYTTEM 
      CLC IOCLR     I/O MASTER RESET
      NOP           ALLOW TIME FOR INTERRUPT
      NOP           INTERRUPT SHOULD NOT OCCUR
      CLF INTP      TURN OFF THE INTERRUPT SYSEM
      JMP MRC02     CONTINUE
MRIR1 NOP           RETURN ADDRESS
      CLF INTP      TURN OFF INTERRUPT SYSTEM 
      JSB ERMS,I    REPORT ERROR
      DEF EM031     POINTER TO MESSAGE
MRC02 JSB SHUTA     CHECK SUB-TEST HALT,LOOP
      JSB CLF       CLEAR INTERFACE FLAG FF 
      JSB MRST      GIVE INTERFACE A MASTER RESET COMMAND 
      JSB SFS       CHECK INTERFACE FLAG FF 
      RSS 
      JMP MRC03     CONTINUE
      JSB ERMS,I    REPORT ERROR
      DEF EM032     POINTER TO MESSAGE
MRC03 JSB SHUTA     CHECK SUB-TEST HALT,LOOP
      JSB CLF       CLEAR INTERFACE FLAG FF 
      JSB STC       SET INTERFACE CONTROL FF
      JSB TRJSB,I   FILL INTERRUPT TRAP CELL
      DEF MRIR2     WHERE TO GO IF INTERRUPT
      STF INTP      TURN ON INTERRUPT SYSTEM
      JSB MRST      GIVE INTERFACE A MASTER RESET COMMAND 
      NOP           GIVE THE INTERFACE TIME TO INTERRUPT
      NOP           THERE SHOULD BE NO INTERRUPT
      CLF INTP      TURN OFF THE INTERRUPT SYSTEM 
MRC04 JSB SUBTT     CHECK SUB-TEST HALT,LOOP
      JMP MRTST,I   RETURN
MRIR2 NOP           RETURN ADDRESS
      CLF INTP      TURN OFF THE INTERRUPT SYSTEM 
      JSB ERMS,I    REPORT ERROR
      DEF EM033     POINTER TO MESSAGE
      JMP MRC04     CONTINUE
      SKP 
TST02 EQU * 
MSTST NOP           RETURN ADDRESS
      JSB STSUB     SAVE SUB-TEST NO
      OCT 34
      JSB MRST      MASTER RESET
      JSB MSS1      TEST RQS AND CLS
      ABS CNTLC+RQS 
      ABS CLS 
      DEF EM034 
      JSB SHUTA     CHECK SUB-TEST HALT AND LOOP
      JSB MSS1      TEST DTR,DSR,RNG
      ABS CNTLC+DTR 
      ABS DSR+RNG 
      DEF EM035 
      JSB SHUTA     CHECK SUB-TEST HALT AND LOOP
      JSB MSS1      TEST SRQS,RLS,SRLS
      ABS CNTLC+SRQS
      ABS RLS+SRLS
      DEF EM036 
      JSB SHUTA     CHECK SUB-TEST HALT AND LOOP
      JSB CNTRL     GIVE CONTROL COMMAND
      ABS CNTLC+DTR+RQS+SRQS
      JSB RSTUS     GET INTERFACE STATS 
      CPA MSTT1     CHECK STATUS
      JMP MSC01     CONTINUE
      JSB ERMS,I    REPORT ERROR
      DEF EM037 
MSC01 JSB SUBTH     CHECK SUB-TEST HALT 
      JSB LIA       INPUT 2ND CHARACTER 
      CPA MSTT1 
      RSS 
      JMP MSC02     CONTINUE
      JSB ERMS,I    REPORT ERROR
      DEF EM040 
MSC02 JSB SHUTA     CHECK SUB-TEST HALT, LOOP 
MSC03 JSB SUBUP     UPDATE SUB-TEST NO. 
      JSB CNTRL     GIVE CONTROL COMMAND
      ABS CNTLC+DTR+RQS+SRQS
      JSB MRST      GIVE INTERFACE MASTER RESET COMMAND 
      JSB CSTUS     CHECK STATUS
      ABS NULL      ALL MODEM STATUS RESET
      DEF EM042 
      JSB SHUTA     CHECK SUB-TEST HALT, LOOP 
      JSB MRST      MASTER RESET COMMAND
      JSB CNTRL     GIVE CONTROL COMMAND
      ABS CNTLC+DTR+RQS+SRQS
      JSB LIA       INPUT FROM INTERFACE
      CPA MSTT1      CHECK INPUT FOR DATA 
      RSS 
      JMP MSC04     CONTINUE
      JSB ERMS,I    REPORT ERROR
      DEF EM043 
MSC04 JSB SUBTT     CHECK SUB-TEST HALT, LOOP 
      JMP MSTST,I   RETURN
      SPC 2 
MSTT1 ABS CLS+RNG+DSR+SRLS+RLS
      SPC 2 
MSS1  NOP           RETURN ADDRESS
      LDA MSS1,I    GET PARAMETERS
      STA MSP1
      ISZ MSS1
      LDA MSS1,I
      STA MSP2
      ISZ MSS1
      LDA MSS1,I
      STA MSP3
      STA MSP4
      ISZ MSS1      UPDATE RETURN ADDRESS 
      JSB CNTRL     GIVE CONTROL COMMAND
MSP1  BSS 1 
      JSB CSTUS     CHECK STATUS
MSP2  BSS 1 
MSP3  DEF *-*       ERROR MESSAGE POINTER 
      JSB CNTRL     GIVE CONTROL COMMAND
      ABS CNTLC+NULL
      JSB CSTUS     CHECK STATUS
      ABS NULL
MSP4  DEF *-*       ERROR MESSAGE POINTER 
      JMP MSS1,I    RETURN
      SKP 
TST03 EQU * 
AMTST NOP           RETURN ADDRESS
      JSB STSUB     SAVE SUB-TEST NO. 
      OCT 44
      JSB MRST      MASTER RESET
      JSB CNTRL     GIVE CONTROL COMMAND
      ABS CNTLC+DTR+RQS+SRQS
      JSB CMND      GIVE INTERFACE MASK COMMAND 
      ABS MASKC+RNGM
      JSB CSTUS     CHECK STATUS
      ABS CHECK+CHECK+MRQ+RNGI+SRLS+RLS+CLS+DSR+RNG