ASMB,R,L,C
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
*   NAME: PART OF MATH LIBRARY
*   SOURCE:  24998-18XXX  SEE NAM FOR LAST THREE DIGITS 
*   RELOC: PART OF 24998-12001
*   PGMR: BG & JTS
* 
      HED PAUSE AND STOP FOR RTE,DOS,AND IOMEC/DOS
      NAM PAUSE,7 24998-1X253 REV.2001 771122 
      ENT .PAUS,.STOP 
      EXT EXEC,PAU.E,REIO 
      EXT PNAME 
* 
      SUP 
*ENTER WITH A= 4-DIGIT OCTAL NUMBER 
.PAUS NOP 
      LDB PSASC 
      STB TEXT+5    SET 
      LDB PSASC+1 
      STB TEXT+6      -PAUSE- 
      LDB PSASC+2         IN
      JSB PRINT     PRNAM :PAUSE NNNN 
      JSB EXEC      SUSPEND EXECUTION 
      DEF *+2 
      DEF *+2 
      JMP .PAUS,I   EXIT AFTER: GO,FTN
      DEC 7         RCODE FOR SUSPEND EXECUTION 
PSASC ASC 3,PAUSE 
* 
* 
* 
TEXT  ASC 5,  PRNAM : 
      ASC 3,PAUSE 
TEXTN NOP 
      NOP 
* 
* 
* 
STASC ASC 2,STOP
* 
.STOP NOP 
      LDB STASC 
      STB TEXT+5    SET 
      LDB STASC+1 
      STB TEXT+6      -STOP-
      LDB TEXT            IN
      JSB PRINT     PRNAM :STOP  NNNN 
      JSB EXEC      END RUN 
      DEF *+2 
      DEF *+1 
      DEC 6         RCODE FOR COMPLETION REQUEST
* 
*ENTER WITH A= 4-DIGIT OCTAL NUMBER 
PRINT NOP 
      STB TEXT+7
      CLB 
      LSL 7 
      BLS,BLF       SHIFT IN POSITION FOR NEXT LSL 3
      LSL 3         2ND DIGIT TO B
      ADB .ASCN     CONVERT TO ASCII
      STB TEXTN     FIRST 2 DIGITS TO TEXT
      CLB 
      LSL 3         3RD DIGIT TO B
      BLS,BLF       SHIFT IN POSITION FOR NEXT LSL 3
      LSL 3         4TH DIGIT TO B
      ADB .ASCN     CONVERT TO ASCII
      STB TEXTN+1   LAST 2 DIGITS TO TEXT 
      JSB PNAME     ADD PROGRAM NAME TO MESSAGE 
      DEF *+2 
      DEF TEXT+1
      JSB REIO      PRINT TEXT LINE 
      DEF *+5 
      DEF .2        RCODE=2 FOR WRITE 
      DEF PAU.E     SYSTEM TTY= 1 
      DEF TEXT      FWA OF TEXT 
      DEF .M20      20 CHARACTERS 
      JMP PRINT,I   RETURN
.ASCN ASC 1,00
.2    DEC 2 
.M20  DEC -20 
      END 
* 
* 
                                                                                                                        