ASMB,R,L,C
      HED DCRET 91700-16113 REV A 751222 * (C) HEWLETT PACKARD CO. 1976 
      NAM DCRET,7 91700-16113 REV A 751222
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT DCRET 
      EXT CREAT 
      EXT .ENTR 
      SPC 5 
* 
* DCRET 
* SOURCE:91700-18113
* BINARY:91700-16113
* SHANE DICKEY
* JULY 31,1974
* 
PRAMS REP 7 
      NOP 
DCRET NOP 
      JSB .ENTR 
      DEF PRAMS 
* 
      LDA PRAMS+6   IS THE DESTINATION SPECIFIED
      SZA,RSS 
      JMP MORE      NO DEFAULT TO CENTRAL 
      INA           STEP TP DESTINATION WORD
      LDA A,I       PICK IT UP
      SZA           IS IT LOCAL 
      JMP ERROR     NO EXIT WITH ERROR
* 
* 
MORE  LDA D5        SET UP DEFAULT # OF PARAMETERS
      STA #PRMS 
* 
      DLD PRAMS     MOVE DEFS FOR 1ST TWO 
      DST PRAM1 
* 
      DLD PRAMS+2   MOVE 2ND TWO
      DST PRAM1+2 
* 
      DLD PRAMS+4   MOVE 5TH & POSSIBLE 6TH 
      DST PRAM1+4 
* 
      SZB,RSS       WAS THE 6TH ONE THERE?
      JMP DONE      NO DONE 
* 
      ISZ #PRMS     YES INCREMENT COUNT 
      LDA PRAMS+6   MOVE POSSIBLE 7TH 
* 
      SZA,RSS       THERE?
      JMP DONE      NO FINISHED 
      ISZ #PRMS     YES BUMP COUNT & STORE AWAY 
      STA PRAM1+6 
DONE  LDA #PRMS     CALCULATE RETURN
      ADA ADDS
      STA DRTN      & PUT IN CONSTRUCTED CALL 
* 
      JSB RFASR 
      JSB CLEAR     CLEAR PARAMETER ARRAY 
      LDA PRAMS+1,I 
      JMP DCRET,I   FINISHED RETURN TO USER 
      SPC 5 
* CLEAR ARRAY & CALL CONSOLE OUTPUT 
ERROR JSB CLEAR 
      LDA MD18      RETURN DESTINATION ERROR PARAMETER
      STA PRAMS+1,I TO USER 
      JMP DCRET,I   & RETURN
      SPC 5 
RFASR NOP 
      JSB CREAT 
DRTN  NOP 
PRAM1 REP 7 
      NOP 
      JMP RFASR,I 
      SPC 5 
CLEAR NOP 
      CLA           CLEAR DEF TO OPTIONAL PARAM 
      CLB 
      DST PRAMS+5 
      DST PRAM1+5 
      JMP CLEAR,I 
      SPC 5 
* CONSTANTS 
A     EQU 0 
D5    DEC 5 
ADDS  DEF DRTN+1
MD18  DEC -18 
#PRMS NOP 
      END 
* AN ERROR EXISTS 
                                                                                                                  