ASMB,R,L,C
      HED DOPEN 91700-16116 REV A 751222 * (C) HEWLETT PACKARD CO. 1976 
      NAM DOPEN,7 91700-16116 REV A 751222
      SPC 1 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
      SPC 2 
      ENT DOPEN 
      EXT .ENTR 
      EXT OPEN
      SPC 5 
* 
* DOPEN 
* SOURCE:91700-18116
* BINARY:91700-16116
* SHANE DICKEY
* JULY 31,1974
* 
PRAMS REP 6 
      NOP 
DOPEN NOP 
      JSB .ENTR 
      DEF PRAMS 
* 
      LDA PRAMS+5   IS THE DESTINATION SPECIFIED? 
      SZA,RSS 
      JMP MORE         DEFAULT TO CENTRAL CALL
* 
      INA           STEP PAST CART.LABEL
      LDA A,I       PICK UP DESTINATION CODE
      SZA           CENTRAL CALL? 
      JMP ERROR     NO-ABORT USER 
MORE  LDA D3        SET UP DEFAULT # OF PARAMETERS
      STA #PRMS 
* 
      DLD PRAMS     MOVE DEFS FOR 1ST TWO 
      DST PRAM1 
* 
      DLD PRAMS+2   MOVE 2ND TWO
      DST PRAM1+2 
* 
* 
      SZB,RSS       WAS THE 4TH ONE THERE?
      JMP DONE      NO DONE 
* 
      ISZ #PRMS     YES INCREMENT COUNT 
      DLD PRAMS+4   PICK UP POSSIBLE 5TH & 6TH
      DST PRAM1+4 
* 
      SZA,RSS       THERE?
      JMP DONE      NO FINISHED 
      ISZ #PRMS     YES BUMP COUNT & STORE AWAY 
* 
      SZB,RSS        6TH PARAMETER THERE? 
      JMP DONE      NO
      ISZ #PRMS     YES 
DONE  LDA #PRMS     CALCULATE RETURN
      ADA ADDS
      STA DRTN      & PUT IN CONSTRUCTED CALL 
* 
      JSB RFASR 
      JSB CLEAR     CLEAR PARAMETER ARRAY 
      LDA PRAMS+1,I GET IERR
      JMP DOPEN,I   FINISHED RETURN TO USER 
      SPC 5 
* CLEAR ARRAY & CALL CONSOLE OUTPUT 
ERROR JSB CLEAR 
      LDA MD18      PICK UP & RETURN ERROR CODE 
      STA PRAMS+1,I TO USER 
      JMP DOPEN,I   THEN RETURN 
      SPC 5 
RFASR NOP 
      JSB OPEN
DRTN  NOP 
PRAM1 REP 6 
      NOP 
      JMP RFASR,I 
      SPC 5 
CLEAR NOP 
      CLA           CLEAR DEFS TO OPTIONAL
      CLB           PARAMETERS
      DST PRAMS+3 
      DST PRAM1+3 
      STA PRAMS+5 
      STA PRAM1+5 
* 
      JMP CLEAR,I 
      SPC 5 
* CONSTANTS 
A     EQU 0 
D3    DEC 3 
ADDS  DEF DRTN+1
#PRMS NOP 
MD18  DEC -18 
      END 
* AN ERROR EXISTS 
    