ASMB,R,L,C
      HED DLK65 - DVR65 FTN4 LINK SUBR * (C) HEWLETT-PACKARD CO. 1976 * 
      NAM DLK65,7 91700-16134 REV A 760113
      ENT DLK65 
      EXT D65CL,.ENTR,D65AB 
* 
* NAME:   DLK65 
* SOURCE: 91700-18134 
* RELOC:  91700-16134 
* PGMR:   D.J.G. (01-13-76) 
* 
******************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
******************************************************************
* 
.IRW  NOP 
.ILU  NOP 
.DBUF NOP 
.DLNT NOP 
.RQBF NOP 
.RQLN NOP 
.MODE NOP 
DLK65 NOP 
      JSB .ENTR 
      DEF .IRW
* 
      LDA .ILU,I    GET LU
      STA NABRT     SAVE AS NO-ABORT FLAG 
      RAL,CLE,ERA   STRIP SIGN BIT
      STA .ILU      SAVE STRIPPED LU
      LDB DLK65     SET UP ERROR REPORT ADDRESS 
      ADB DM6 
      LDA .MODE     IF FEWER THAN 7 PRAMS, IT'S GOTTA 
      SZA,RSS       BE A MODE 2 CALL. ELSE MODE 0 
      JMP MODE2 
* 
      ADB DM2       (ERROR REPORT ADDRESS)
      STB ERRAD 
* 
      LDA .MODE,I 
      SZA           MODE MUST BE 0!!! 
      JMP ERR 
* 
      CLA,INA       SET UP CONWD FOR D65CL CALL 
      LDB .IRW,I
      SLB,RSS       SEND DATA?
      INA           YES, SET MODE IN CONWD = 2
      ALF,RAL       POSITION MODE BITS TO 6-8 
      RAL 
      IOR .ILU      INCLUDE LU #
      IOR ZBIT      SET Z-BIT 
      STA CONWD 
* 
      JSB D65CL     CALL D65CL
      DEF *+7 
      DEF .IRW,I
      DEF CONWD 
      DEF .RQBF,I 
      DEF .RQLN,I 
      DEF .DBUF,I 
      DEF .DLNT,I 
      JMP ERRTN     ERROR RETURN
* 
EXIT  CLA           RE-SET ADDRESSES FOR NEXT CALL
      STA .MODE 
      JMP DLK65,I   RETURN
* 
* 
      SKP 
* 
* 
*  MODE-2 REQUESTS
* 
MODE2 STB ERRAD     (ERROR REPORT ADDRESS)
      LDA .RQBF,I   GET MODE VALUE. MUST = 2!!! 
      CPA TWO 
      RSS 
      JMP ERR 
      LDA .ILU      SET UP CONWD FOR D65CL CALL 
      STA CONWD 
* 
      JSB D65CL     CALL D65CL
      DEF *+7 
      DEF .IRW,I
      DEF CONWD 
      DEF .DBUF,I 
      DEF .DLNT,I 
      DEF *         DUMMY PARAM 
      DEF *         DUMMY PARAM 
      JMP ERRTN     ERROR RETURN POINT
      JMP EXIT
* 
* 
TWO   DEC 2 
CONWD NOP 
NABRT NOP           NO-ABORT FLAG 
ZBIT  OCT 10000 
ERRAD NOP 
DM6   DEC -6
DM2   DEC -2
* 
* 
ERRTN STA EMSG      HERE FOR ERROR RETURN 
      STB EMSG+1
      LDA NABRT     GET NO-ABORT FLAG 
      SSA           NO-ABORT FLAG SET?
      JMP EXIT      YES, RETURN TO CALLER 
ERR   LDA ERRAD     SET UP ERROR CALL 
      LDB EMSGA     TO 'D65AB'
      JSB D65AB 
      JMP DLK65,I   (JUST IN CASE)
* 
EMSGA DEF EMSG
EMSG  ASC 2,
* 
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                            