ASMB,L
      HED TXPM2 - MEMORY VERIFICATION PROGRAM 
      NAM TXPM2,4,89 91711-16005  REV 1926  790421
      EXT EXEC,PRTN 
* 
* 
* 
*  DESCRIPTION: 
*  ------------ 
* 
* 
*    THE PURPOSE OF THIS PROGRAM IS TO TEST THE AVAILABLE MEMORY
*    (DYNAMIC BUFFER AREA) FOR QUICK VERIFICATION OF OPERATING
*    CONDITION BY ATTEMPTING TO FORCE A MEMORY PARITY ERROR.
*    PARITY ERRORS ARE HANDLED BY THE RTE-IV MODULE PERR4.
* 
* 
*  NOTE:
*  -----
* 
*    THIS TEST IS LIMITED TO THE PARTITION IN WHICH 
*    THE VERIFICATION PROGRAM "TXPM2" IS EXECUTING. 
* 
* 
* 
*  OPERATING PROCEDURE: 
*  -------------------- 
* 
* 
*    1. LOAD THE PROGRAM "TXPM2" USING THE OPCODE LBNC. 
* 
*    2. ASSIGN THE PROGRAM "TXPM2" TO THE PARTITION TO BE TESTED. 
* 
*    3. ADJUST THE PAGE REQUIREMENT FOR "TXPM2" TO INCLUDE ALL
*       AVAILABLE PAGES IN THE SELECTED PARTITION.
* 
*    4. SCHEDULE "TXPM2" USING THE RUN COMMAND. 
* 
*                *AS,TXPM2,PTN# 
*                *SZ,TXPM2,SIZE 
*                *RU,TXPM2
* 
*    PTN# - PARTITION NUMBER TO BE TESTED  (EXCL. MOTHER PART'N)
*    SIZE - NUMBER OF PAGES ASSINGED TO PARTITION PTN#. 
*           (*RU,WHZAT,,1 TO DETERMINE PTN# AND SIZE).
* 
* 
*    SUCCESSFUL OPERATION OF THE PROGRAM IS INDICATED BY
*    NO ERROR MESSAGES DISPLAYED ON THE SYSTEM CONSOLE. 
* 
* 
* 
* 
* 
      SKP 
TXPM2 NOP           ENTRY POINT 
      JSB EXEC
      DEF RTN 
      DEF RQ26      PARTITION SIZE REQUEST
      DEF FWMEM     FIRST WORD AFTER PROGRAM
      DEF NWMEM     # OF WORDS AVAILABLE
      DEF PSIZE     # OF PAGES IN PARTITION 
* 
RTN   LDA FWMEM     STORE FIRST AVAILABLE 
      STA LOC         MEMORY LOCATION TO BE TESTED
* 
      LDA NWMEM     STORE THE NEGATIVE
      CMA,INA         NUMBER OF LOCATIONS TO BE 
      STA COUNT         TESTED IN DYNAMIC BUFFER SPACE
* 
      LDB DATA      DATA PATTERN - 1010101010101010 
* 
LOOP  LDA LOC,I     CHECK FOR PARITY ERORRS 
      STB LOC,I     STORE DATA PATTERN
* 
      LDA LOC,I     LOAD DATA PATTERN 
      CMA,SSA       COMPLEMENT DATA PATTERN 
      ISZ PRAM1     SET NONEXISTENT MEMORY FLAG 
      STA LOC,I     STORE COMPLEMENT
      LDA LOC,I     CHECK FOR PARITY ERRORS 
* 
      CLA 
      STA LOC,I     CLEAR CONTENTS, SET PARITY BIT
      LDA LOC,I     CHECK FOR PARITY ERRORS 
* 
      ISZ LOC       NEXT MEMORY LOCATION
      ISZ COUNT     ALL DONE? 
      JMP LOOP      NO - CONTINUE 
* 
      JSB PRTN      PASS BACK PARAMETERS
      DEF *+2 
      DEF PRAM1 
* 
      JSB EXEC      TERMINATE "TXPM2" 
      DEF *+2 
      DEF RQ6 
* 
PRAM1 OCT 0 
LOC   OCT 0 
FWMEM OCT 0 
NWMEM OCT 0 
PSIZE OCT 0 
COUNT OCT 0 
RQ6   DEC 6 
RQ26  DEC 26
DATA  OCT 125252
* 
      END TXPM2 
                