ASMB,R,L,C
      HED EXECW 91740-16008 REV 1740 * (C) HEWLETT-PACKARD CO. 1977
      NAM EXECW,19,30 91740-16008 REV 1740 770728 
      SPC 1 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977. ALL RIGHTS      *
*  * RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY.   *
*  ***************************************************************
* 
*    NAME:   EXECW
*    SOURCE: 91740-18008
*    RELOC:  91740-16008
*    PGMR:   C. HAMILTON  [07/28/77]
* 
*  <EXECW> IS THE DS/1000 MONITOR, WHOSE FUNCTION IS TO PROCESS ALL 
*   REQUESTS, WHICH ARE FORWARDED TO THIS NODE VIA SLAVE STREAM #3. ALL OF
*   THESE REQUESTS WILL HAVE BEEN ORIGINATED THROUGH A USER'S REQUEST TO THE
*   <DEXEC> USER-INTERFACE MODULE. REQUESTS PROCESSED BY <EXECW> ARE
*   HANDLED ON A 'FIRST COME, FIRST SERVED' BASIS! THUS, IF <EXECW> IS
*   'WAITING' FOR COMPLETION OF A PREVIOUSLY-SCHEDULED PROGRAM, A NEW 
*   REQUEST CANNOT BE HONORED, UNTIL THE PREVIOUS REQUEST HAS COMPLETED.
* 
*  THE CURRENT USER'S NODE NUMBER WILL BE STORED IN #CNOD, IN <RES>.
*    ( WHEN <EXECW> IS INACTIVE, #CNOD WILL CONTAIN -1 )
* 
*   NOTE: SPECIAL PROCESSING IS PROVIDED FOR THE RTE-M ABSOLUTE LOADER
*         <APLDR> (SEE INFORMATION FOR SUBROUTINE 'APLCK'). 
* 
*   THOSE REQUESTS WHICH ARE ACCEPTABLE FOR PROCESSING VIA <EXECW>
*    MAY BE CLASSIFIED UNDER THE FOLLOWING 'EXEC' REQUEST CODES:
* 
*     6 - TERMINATE A PROGRAM (PREVIOUSLY SCHEDULED VIA <EXECW>)
* 
*     9 - SCHEDULE A PROGRAM WITH 'WAIT' (REPLY RETURNED UPON COMPLETION) 
* 
*    23 - QUEUE-SCHEDULE A PROGRAM WITH 'WAIT' (SCHEDULE WHEN AVAILABLE)
*         (REPLY RETURNED UPON COMPLETION OF SCHEDULED PROGRAM) 
* 
*   NOTE: FOR RC=9,23 PARAMETERS RETURNED FROM THE SCHEDULEE-VIA 'PRTN' OR
*         'PRTM'-WILL BE PASSED TO THE CALLER. [<EXECW> SETS <B>=-1,
*          TO INFORM <DEXEC> THAT PARAMETERS HAVE BEEN RETURNED.] 
* 
*    24 - QUEUE-SCHEDULE A PROGRAM IMMEDIATELY (SCHEDULE WHEN AVAILABLE)
*         (REPLY RETURNED AS SOON AS PROGRAM IS SCHEDULED)
* 
*  ERRORS, ORIGINATING IN <EXECW>:
* 
*  "DS06" - ILLEGAL REQUEST CODE (NOT 6,9,23,24)
* 
*  "DS08" - INSUFFICIENT MEMORY FOR 'STRING BUFFER', OR <APLDR> NOT DORMANT.
* 
*  "SC01" - MISSING SCHEDULING PARAMETER. 
*  "SC02" - ILLEGAL SCHEDULING PARAMETER. 
*  "SC05" - ATTEMPT TO CONTROL <EXECW>, OR UNDEFINED PROGRAM. 
*  "XXNN" - [ RTE SYSTEM-ORIGINATED ERRORS ]
      SKP 
* 
      EXT D65GT,D65SV,PGMAD,#CNOD,#LNOD,#NODE 
      EXT $LIBR,$LIBX,$OPSY,EXEC
A     EQU 0 
B     EQU 1 
KEYWD EQU 1657B 
XEQT  EQU 1717B 
      SUP 
      SPC 2 
EXECW LDA B,I       GET THE PASSED PARAMETER. 
      IFZ 
      EXT DBUG
      SZA 
      JMP SETCL 
      JSB DBUG
      DEF *+1 
      JSB EXEC
      DEF *+4 
      DEF D6
      DEF D0
      DEF D1
      JMP EXECM+1 
      XIF 
* 
SETCL STA SAVCL     SAVE <EXECW> CLASS NUMBER.
* 
      CLB 
      LDA $OPSY     GET THE SYSTEM SPECIFICATION. 
      AND D4        ISOLATE THE RTE-M BIT(#2).
      SZA           IF NOT RTE-M, SKIP; 
      STB SCHD0      ELSE, PREVENT <APLDR> PROCESSING.
* 
*  CALL <D65GT> TO 'GET' A NEW REQUEST. 
* 
GET   JSB D65GT     WE WAIT FOR A REQUEST TO ARRIVE 
      DEF *+6 
      DEF SAVCL     MONITOR'S CLASS 
      DEF RQBUF     REQUEST BUFFER ADDRESS. 
      DEF D16       MAXIMUM REQUEST LENGTH. 
DABFA DEF DABUF     DATA BUFFER ADDRESS.
      DEF D512      MAXIMUM DATA BUFFER SIZE. 
      JMP GET       IGNORE INITIAL ERRORS!
* 
      DST SAVA      <A> = REQUEST LENGTH; <B> = DATA LENGTH.
      LDA D7        INITIALIZE FOR A
      STA RPLYL      MINIMUM-LENGTH REPLY.
* 
      SKP 
* 
*  EXAMINE AND VERIFY THE REQUEST CODE (VALID CODES: 6,9,23,24) 
* 
      LDA RQBUF+4   GET THE REQUEST CODE. 
      CPA D6        TERMINATION REQUEST?
      JMP PKILL     YES, GO TO KILL THE PROGRAM.
      CPA D9        SCHEDULE WITH WAIT? 
      JMP SCHED      YES. GO TO SCHEDULE & WAIT.
      CPA D23       QUEUE-SCHEDULE WITH WAIT? 
      JMP SCHED      YES--THAT'S ACCEPTABLE.
      CPA D24       QUEUE-SCHEDULE WITHOUT WAIT?
      JMP SCHED      YES--ACCEPT THAT REQUEST, ALSO.
* 
      DLD DS06      ERROR "DS06": BAD REQUEST CODE. 
      JMP ERRTN     RETURN ERROR-CODE TO CALLER.
ERSC1 DLD SC01      ERROR "SC01": MISSING PARAMETER.
      JMP ERRTN 
ERSC2 DLD SC02      ERROR "SC02": INVALID PARAMETER.
      JMP ERRTN     RETURN ERROR-CODES TO CALLER. 
ERSC5 DLD SC05      ERROR "SC05": IMPROPER PROGRAM REFERENCE. 
      JMP ERRTN 
ERDS8 DLD DS08      ERROR "DS08": INSUFFICIENT RESOURCES. 
* 
ERRTN CCE,RSS       ERROR RETURN. 
SCDON CLB,CLE       SCHEDULE-RETURN (NO PARAMETERS).
* 
DONE  DST RQBUF+4   STORE REGISTERS IN WORDS 5&6 OF REPLY.
      LDA #NODE     GET THE LOCAL NODE NUMBER, AND
      ELA,CLE,RAR    INCLUDE ASCII-ERROR FLAG (BIT#15). 
      STA RQBUF+6   STORE THE ERROR INDICATOR--IF ANY.
      LDA RQBUF     GET THE STREAM WORD.
      IOR BIT14     ADD THE REPLY FLAG (BIT#14).
      STA RQBUF     RESTORE THE MODIFIED WORD.
      LDA DM1       RESET #CNOD =-1, TO INDICATE
      JSB STCND      THAT <EXECW> IS INACTIVE.
* 
*  CALL <D65SV> TO INDICATE, TO THE USER, THAT THE REQUEST IS COMPLETE. 
* 
      JSB D65SV     TRANSMIT
      DEF *+5        THE REPLY
      DEF RQBUF       BACK TO 
      DEF RPLYL        THE ORIGINAL 
      DEF DABUF         REQUESTOR'S 
      DEF D0             NODE.
      NOP           IGNORE ERRORS--WE CAN DO NOTHING! 
      JMP GET       RETURN FOR THE NEXT REQUEST/COMPLETION. 
* 
      SKP 
*   PROGRAM COMPLETION, SCHEDULE W/WAIT, & QUEUE-SCHEDULEING   RC=6,9,23,24 
* 
PKILL EQU *         PROGRAM TERMINATION SHARES 'SCHED' CODE.
* 
SCHED IOR BIT15     ADD NO-ABORT BIT(#15) TO REQUEST CODE,
      STA RQBUF+4    AND SAVE FOR THE CALL TO 'EXEC'. 
      JSB PGMAD     GO TO GET THE SCHEDULEE'S STATUS. 
      DEF *+2       THE PROGRAM OF INTEREST 
      DEF RQBUF+5    IS NAMED IN THE REQUEST BUFFER.
* 
      SZA           ANY ATTEMPT TO
      CPA XEQT       REMOTELY-CONTROL <EXECW> 
      JMP ERSC5       IS UN-ACCEPTABLE! ERROR: "SC05".
* 
      STB STRAD     SAVE PROGRAM STATUS FOR 'APLCK'.
      LDB RQBUF+4   GET THE REQUEST CODE. 
      ELB,CLE,ERB   REMOVE THE NO-ABORT BIT(#15). 
      CPB D6        PROGRAM TERMINATION REQUEST?
      JMP *+2        YES. SKIP TO DETERMINE LINEAGE.
      JMP SCHD0      NO. IT'S A NORMAL SCHEDULE REQUEST.
* 
      ADA D20       POINT TO WORD #21 IN I.D. SEGMENT.
      LDA A,I       GET THE CONTENTS. 
      AND B377      ISOLATE THE FATHER'S I.D. SEG. NO.
      ADA KEYWD     COMPUTE THE ADDRESS FOR THE 
      ADA DM1        FATHER'S KEYWORD-TABLE ENTRY.
      LDA A,I       GET THE FATHER'S I.D. SEGMENT ADDRESS.
      CPA XEQT      OUR OFFSPRING?
      JMP SCHD0+1    YES, WE CAN HONOR THE REQUEST. 
      JMP ERSC5      NO. WE CANNOT PROCESS THE REQUEST! 
* 
SCHD0 JSB APLCK     CHECK FOR <APLDR> [NOP: RTE-II/III/IV]
* 
      LDA SAVA      GET THE REQUEST LENGTH. 
      ADA DM16      IF THE LENGTH [AFTER APLCK COMPENSATION]
      SSA,RSS        EXCEEDS FIFTEEN WORDS, THEN
      JMP ERSC2       IT IS AN INVALID REQUEST! 
* 
      LDA SAVA      GET THE REQUEST BUFFER SIZE, AGAIN. 
      LDB RTNDF     GET THE DEFAULT RETURN POINTER. 
      ADA DM8       SUBTRACT THE MINIMUM REQUEST SIZE.
      ADB A         COMPUTE THE ACTUAL RETURN ADDRESS,
      STB RTNAD      AND CONFIGURE THE RETURN POINTER.
      SZA,RSS       ANY ADDITIONAL PARAMETERS?
      JMP SCHD2      NO. GO CLEAR REMAINDER OF CALL BUFFER. 
* 
      SSA           WERE WE SUPPLIED WITH ENOUGH PARAMETERS?
      JMP ERSC1      NO. * ERROR: SC01 !
      CAX            YES. SAVE ADDITIONAL PARAMETER COUNT.
      LDA PR3DF     <A>= ADDRESS OF NEXT USER-PARAMETER 
      LDB RTNDF     <B>=ADDRESS OF NEXT CALL-BUFFER LOCATION. 
SCHD1 STA B,I       STORE PARAM ADDR INTO CALL BUFFER.
      INA           ADVANCE PARAMETER POINTER.
      INB           ADVANCE CALL BUFFER POINTER.
      DSX           ALL PARAMETERS PROCESSED? 
      JMP SCHD1      NO. PROCESS THE NEXT ONE.
* 
      CLA           PREPARE TO CLEAR REST OF CALL BUFFER. 
SCHD2 ADB D2        ADVANCE POINTER PAST ERROR INSTRUCTIONS.
      CPB LASTA     LAST CALL BUFFER LOCATION CLEARED?
      JMP SCHD3      YES. GO TO COMPLETE THE CALL.
      STA B,I        NO. CLEAR THE LOCATION.
      INB           ADVANCE THE CALL BUFFER POINTER, AND
      JMP SCHD2+1    GO TO CLEAR THE NEXT LOCATION. 
* 
SCHD3 LDA STRAD+1   GET THE STRING-SIZE POINTER--IF ANY.
      SZA,RSS       PASSING A STRING TO THE PROGRAM?
      JMP SCHD4      NO. BYPASS DATA-BUFFER SET-UP. 
      LDA DABFA     GET LOCAL DATA BUFFER ADDRESS,
      STA STRAD      AND ESTABLISH STRING-POINTER IN CALL.
* 
SCHD4 DLD ERRIN     LOAD THE ERROR-DETECTION INSTRUCTIONS.
      DST RTNAD,I   STORE THEM AT END OF CALLING SEQUENCE.
* 
      LDA RQBUF+2   GET THE SOURCE-NODE.
      JSB STCND     ESTABLISH CURRENT USER'S NODE IN <RES>. 
      LDB DM1       PREPARE FOR RETURN-PARAMETER CHECKING.
* 
*    THE  CONFIGURED 'EXEC' CALLING SEQUENCE IS EXECUTED BELOW: 
* 
      JSB EXEC      BUFFER FOR ASSEMBLING 'EXEC' REQUESTS.
RTNAD DEF PR3AD     RETURN POINTER (CONFIGURED).
      DEF RQBUF+4   REQUEST CODE (SUPPLIED BY CALLER) 
      DEF RQBUF+5   POINTER TO FIRST REQUEST PARAMETER. 
PR3AD NOP           CONFIGURED POINTERS (7-MAX.) TO 
      NOP            USER-SUPPLIED CALLING-PARAMETERS,
      NOP             WHICH RESIDE IN THE REQUEST BUFFER. 
      NOP           UN-USED CALLING-SEQUENCE LOCATIONS ARE
      NOP            DYNAMICALLY CHANGED TO 'NOP'.
STRAD NOP           STRING-BUFFER ADDRESS--IF ANY.
      NOP           STRING-LENGTH POINTER--IF ANY.
      NOP           [ ERROR-DETECTION INSTRUCTIONS: WILL BE 
      NOP             POSITIONED TO FOLLOW LAST POINTER ] 
ENDBF CPA DM1       REJECTING A STRING-PASSING REQUEST? 
      JMP ERDS8      YES, SKIP TO RETURN "DS08".
      SEZ            NO. WAS A SYSTEM-LEVEL ERROR DETECTED? 
      JMP DONE        YES. RETURN THE ERROR CODES TO CALLER!
* 
      CPB DM1       IF NO PARAMETERS WERE RETURNED, 
      JMP SCDON      THEN RETURN TO CALLER WITH <B>=0;
      STA STCND       ELSE, SAVE THE STATUS TEMPORARILY.
* 
      LDA B         SOURCE=RETURN-PARAMETERS IN I.D.SEGMENT.
      LDB RTPRM     DESTN.=EIGHTH WORD OF REPLY BUFFER. 
      MVW D5        MOVE THE PARAMETERS TO THE REPLY BUFFER.
* 
      LDA D12       SET THE 
      STA RPLYL      REPLY LENGTH =12 WORDS.
      LDA STCND     RECOVER THE PROGRAM STATUS. 
      CCB,CLE       INDICATE: PARAMETERS RETURNED--NO ERROR.
      JMP DONE      COMPLETE THE REQUEST PROCESSING.
* 
      SKP 
*  SET #CNOD IN <RES>: + NODE # = CURRENT <EXECW> CALLER; -1 = INACTIVE.
* 
STCND NOP 
      JSB $LIBR 
D0    NOP 
      STA #CNOD     SET <A> INTO #CNOD, IN <RES>. 
      JSB $LIBX 
      DEF STCND     RETURN. 
* 
*  SPECIAL PROCESSING FOR <APLDR> IN RTE-M ENVIRONMENT: 
* 
*   IF NOT SCHEDULING <APLDR>, RETURN; ELSE, CHECK <APLDR> STATUS.
*   IF NOT DORMANT, REJECT "DS08"; ELSE, STORE SECURITY CODE AND
*    CARTRIDGE REFERENCE NO. INTO <APLDR> I.D. SEGMENT WORDS #27,28.
*   STORE REQUEST'S SOURCE-NODE INTO #CNOD IN <RES>, AND ALSO STORE 
*    FILE-LOCATION NODE INTO #LNOD IN <RES>.
* 
APLCK NOP 
      ADA D12       POINT TO I.D. SEGMENT WORD #13 (NAME).
      RAL           FORM A BYTE ADDRESS 
      STA B          FOR THE PROGRAM'S I.D. SEGMENT "NAME". 
* 
      LDA APLBA     GET THE REFERENCE BYTE ADDRESS. 
      CBT D5        IF THIS IS AN <APLDR> SCHEDULE REQUEST, 
      JMP APSET      THEN GO TO PROCESS IT'S PARAMETERS;
      JMP APLCK,I     ELSE, NO FURTHER SPECIAL
      JMP APLCK,I      PROCESSING IS REQUIRED.
* 
APSET LDA STRAD     GET THE I.D. SEGMENT STATUS WORD. 
      AND B17       ISOLATE <APLDR'S> CURRENT STATUS. 
      SZA           IF IT IS NOT AVAILABLE, 
      JMP ERDS8      THEN, NOTHING MORE CAN BE DONE!
* 
      LDA SAVA      COMPENSATE FOR THE
      CPA D16        THREE ADDITIONAL 
      ADA DM3         REQUEST-PARAMETERS, USED TO 
      STA SAVA         SPECIFY <APLDR> DOWN-LOADING.
* 
      CLE,ERB       CONVERT FROM BYTE, TO WORD ADDRESS. 
      ADB D12       POINT TO I.D. SEGMENT WORD #27. 
      LDA RQBUF+13  GET THE SECURITY CODE.
      JSB $LIBR 
      NOP 
      STA B,I       SET SECURITY CODE INTO I.D. WORD #27. 
      CLE,INB 
      LDA RQBUF+14  GET THE CARTRIDGE REFERENCE NUMBER. 
      STA B,I       SET CRN INTO I.D. SEGMENT WORD #28. 
* 
      LDA RQBUF+15  GET LOCATION-NODE FOR THE RELOC. FILE.
      STA #LNOD     SET #LNOD IN <RES>, FOR <APLDR>.
      JSB $LIBX 
      DEF APLCK     RETURN. 
* 
APLBA DBL *+1       REFERENCE-NAME BYTE ADDRESS.
      ASC 3,APLDR 
* 
      SKP 
DM16  DEC -16 
DM8   DEC -8
DM3   DEC -3
DM1   DEC -1
D1    DEC 1 
D2    DEC 2 
D4    DEC 4 
D5    DEC 5 
D6    DEC 6 
D7    DEC 7 
D9    DEC 9 
D12   DEC 12
D16   DEC 16
B17   OCT 17
D20   DEC 20
D23   DEC 23
D24   DEC 24
D512  DEC 512 
B377  OCT 377 
BIT14 OCT 40000 
BIT15 OCT 100000
DS06  ASC 2,DS06
DS08  ASC 2,DS08
SC01  ASC 2,SC01
SC02  ASC 2,SC02
SC05  ASC 2,SC05
RPLYL NOP 
RTPRM DEF RQBUF+7 
PR3DF DEF RQBUF+8 
RTNDF DEF PR3AD 
LASTA DEF ENDBF 
* 
* * * DO NOT CHANGE ORDER OF NEXT FOUR STATEMENTS * * * 
* 
ERRIN CCE,RSS 
      CLE 
SAVA  NOP 
      NOP 
* * * * * * * * * * * * * * * * * * * * * * * * * * * * 
SAVCL NOP 
DABUF BSS 512 
RQBUF BSS 16
* 
* 
      BSS 0         [ SIZE OF <EXECW> ] 
* 
      END EXECW