ASMB,R,L,C
*     NAME:   IMESS 
*     SOURCE: 91740-18060 
*     RELOC:  91740-16060 
*     PGMR:   MIKE SCHOENDORF 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM IMESS,8 91740-16060 REV 1740 760628 
* 
*      IMESS READS/WRITES TO THE CONSOLE FROM WHICH THE PROGRAM 
*      WAS SCHEDULED. IF NOT SCHEDULED BY OPERATOR, LU 1 IS USED. 
*          AFTER DETERMINING THE CORRECT LU (FROM $CON) THIS CALL MAPS
*      DIRECTLY INTO AN EXEC READ/WRITE CALL. 
* 
* 
*     CALLING SEQUENCE: 
*        JSB IMESS
*        DEF RETURN 
*        DEF IO           1=READ/2=WRITE
*        DEF BUFAD        BUFFER ADDRESS
*        DEF COUNT        BUFFER LENGTH 
* 
*  ON RETURN A AND B ARE AS EXEC LEFT THEM
* 
      EXT .ENTR,EXEC,$CON 
* 
      ENT IMESS 
* 
IO    NOP 
BUFAD NOP 
CCNT  NOP 
* 
* 
IMESS NOP 
      JSB .ENTR 
      DEF IO
* 
      LDA $CON,I
      AND B77       ISOLATE LU
      IOR ECHO
      STA LU
* 
* 
      JSB EXEC
      DEF MESSR 
      DEF IO,I
      DEF LU
      DEF BUFAD,I 
      DEF CCNT,I
* 
MESSR JMP IMESS,I 
* 
ECHO  OCT 400 
LU    NOP 
B77   OCT 77
      END 
* 
            