ASMB,Q,C
      HED SLCIN: PRINT SLC (DVG67) INFORMATION * (C) HEWLETT-PACKARD
      NAM SLCIN,19,90 91750-16176 REV.2013 800604 MEF 
      SUP 
A     EQU 0 
B     EQU 1 
      EXT EXEC,CNUMO,CNUMD,RMPAR,$LIBR,$LIBX
      EXT #FWAM,#LU3K,D$EQT,D$XS5 
      SPC 1 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
      SPC 1 
      UNL           NEXT 5 LINES ARE FOR PRODUCTION ENGINEERING 
*  NAME:
*SOURCE: 91750-18176
* RELOC: 91750-16176
*  PGMR: DMT
      LST 
******************************* 
*                             * 
*  PROGRAM NAME: SLCIN        * 
*                             * 
*  SOURCE PART#: 91750-18176  * 
*                             * 
*  RELOC. PART#: 91750-16176  * 
*                             * 
*  PROGRAMMER  : DAVE TRIBBY  * 
*                             * 
*  DATE        : JUNE 1977    * 
*                             * 
******************************* 
      SPC 1 
* PRINT LONG TERM STATISTICS AND TRACE TABLES FROM DVG67
* 
* RUN FROM RTE WITH 
*   RU,SLCIN,<OUTLU>
* WHERE <OUTLU> IS THE LU WHERE THE INFORMATION IS TO BE PRINTED. 
* 
* THE SLC LONG TERM STATISTICS ARE PRINTED FIRST, FOLLOWED BY THE 
* EVENT TRACE TABLE.
* 
*  NOTE: MODIFIED 9-22-77 TO REMOVE CHARACTER TRACE PRINT 
      SPC 1 
      SKP 
*  PICK UP SCHEDULING PARAMETER 
SLCIN EQU * 
      JSB RMPAR     GET SCHEDULING PARAMETER. 
      DEF *+2 
      DEF OUTLU 
      LDA OUTLU 
* 
      SZA,RSS       IF OUTLU=0, 
      CLA,INA        OUTLU:=1.
      STA OUTLU 
* 
      LDA #FWAM     HAS DS/1000 
      SZA            BEEN INITIALIZED?
      JMP CHEK2      YES--IS 3000 ENABLED?
* 
      JSB PRINT     PRINT 
      DEF INTLN      ERROR
      DEC 12          MESSAGE.
      JMP FINIS     TERMINATE.
* 
CHEK2 LDA #LU3K     IF 3000 HAS 
      SZA            NOT BEEN 
      JMP CHEK3       ENABLED,
* 
      JSB PRINT        PRINT
      DEF NOTEN         ERROR 
      DEC 10             MESSAGE. 
      JMP FINIS        TERMINATE. 
* 
CHEK3 LDA D$XS5     IF 3000 LINK
      AND D2         IS VIA MODEM,
      SZA,RSS 
      JMP LTSTS 
* 
      JSB PRINT        PRINT
      DEF WRDVR         ERROR 
      DEC 9              MESSAGE. 
      JMP FINIS        TERMINATE. 
      SPC 2 
INTLN ASC 12, NEED TO INITIALIZE NODE!
NOTEN ASC 10, HP 3000 NOT ENABLED 
WRDVR ASC 9, 3000 LINK NOT HSI
      SKP 
* PRINT LONG TERM STATISTICS
* 
LTSTS JSB PRINT     PRINT 
      DEF SHEAD      HEADING. 
      DEC 13
      LDA DN11      SET UP COUNTER
      STA CNT1       FOR 11 LINES.
      LDA FSTVL     INITIALIZE
      JSB INDR
      STA FSTVL 
      ADA DN1 
      STA VPNT       VALUE POINTER. 
      LDA MSGTB     INITIALIZE
      STA MPNT       MESSAGE POINTER. 
      LDA D14       SET OUTPUT
      STA BUMP       BUMP TO 14.
* 
LOOPA LDA AW3       SET OUTPUT
      STA OPNTR      POINTER. 
      LDA BLANK     CLEAR 
      JSB FILL       BUFFER.
* 
LOOPB ISZ VPNT      BUMP STAT POINTER.
      LDA MPNT,I    GET # OF
      STA CNT2       CHARACTERS.
      ISZ MPNT
      LDA MPNT      MESSAGE SOURCE ADDR.
      LDB OPNTR     MESSAGE DESTINATION FIELD.
      ADB D3
      MVW CNT2      MOVE MESSAGE. 
      STA MPNT      POINT TO NEXT MESSAGE.
      LDB VPNT,I    CONVERT THE 
      JSB TO10       VALUE. 
      ISZ CNT1      LAST MESSAGE? 
      RSS 
      JMP LPRNT        YES--GO DO LAST PRINT. 
      LDA OPNTR     IF PRINTLINE
      CPA AW17       NOT FULL,
      JMP LOOPB       MOVE 2ND MESSAGE. 
* 
      JSB PRINT     PRINT 
      DEF BUFR       MESSAGES.
      DEC 30
      JMP LOOPA       NO--STAY IN LOOP. 
      SPC 1 
LPRNT JSB PRINT     PRINT 
      DEF BUFR       FINAL
D14   DEC 14          STATISTIC.
      SKP 
* DUMP EVENT TRACE TABLE
* 
* CALCULATE START/END OF EVENT TABLE
      LDA TRFWA     CALCULATE 
      JSB INDR       OFFSET 
      STA TRFWA       FOR 
      CMA,INA          TRACE
      ADA @PNTR         TABLES. 
      ADA D2
      STA OFSET 
* 
      ADA D$EQT 
      INA 
      STA EOTBL     1 WORD PAST EVENT TRACE TABLE.
* 
      JSB PRINT     PRINT 
      DEF BLANK      BLANK
D1    DEC 1           LINE. 
      JSB PRINT     PRINT HEADINGS. 
      DEF EHEAD 
      DEC 12
      JSB PRINT 
      DEF EHED2 
      DEC 28
      JSB PRINT 
      DEF BLANK 
      DEC 1 
      LDB D4        SET PRINT 
      STB BUMP       BUMP TO 4. 
* 
*      MOVE TRACE TABLES AND POINTERS 
      LDA TRFWA     SOURCE. 
      ADA DN2 
      LDB @PNTR     DESTINATION.
      JSB $LIBR     TURN OFF
      NOP            INTERRUPTS.
      MVW D202      MOVE 202 WORDS. 
      JSB $LIBX     TURN
      DEF *+1        INTERRUPTS 
      DEF *+1         BACK ON.
* 
      LDB PNTRS+1   B:=FIRST ENTRY ADDRESS. 
* 
LOOP  LDA BLANK     CLEAR 
      JSB FILL       PRINTLINE. 
      ADB OFSET     ADD OFFSET FOR LOCAL TABLES.
      STB LINK      STORE LINK ADDRESS. 
      STB ENTRY     SAVE ENTRY ADDRESS. 
      JSB NXTEV     PICK UP WORD 2. 
      LDB AW3       SET UP
      STB OPNTR      OUTPUT POINTER.
      CLB           CLEAR B-REG.
      LSL 8         B:=COMPLETION STATUS. 
      STB STATS     STORE.
      CLB 
      LSL 2         B:=REQUEST CODE.
      STB REQCD     STORE.
      CLB 
      LSL 6         B:=FUNCTION CODE. 
      STB FUNCD     STORE.
*      DECODE FUNCTION
      LDA REQCD     LOAD REQUEST CODE.
      CPA D1         IF = 1,
      JMP READ         DECODE FOR READ. 
      CPA D2         IF = 2,
      JMP WRITE        DECODE FOR WRITE.
      CPA D3         IF = 3,
      JMP CNTRL        DECODE FOR CONTROL.
*      BAD FUNCTION 
BAD   LDB REQCD     CONVERT REQUEST 
      JSB TO8        CODE AND 
      LDB REQCD       FUNCTION TO 
      JSB TO8          OCTAL. 
      JMP WRD3      GO GET WORD 3.
* 
READ  LDA FUNCD     ** PROCESS READ FUNCTION ** 
      CPA D2        CHECK FOR 
      RSS            BAD FUNCTION.
      JMP BAD 
      LDA READI     A-REG POINTS TO "READ INITIAL". 
      LDB AW8       B-REG POINTS TO DESTINATION.
      MVW D6        MOVE MESSAGE. 
      JMP WRD3      GO GET WORD 3.
* 
WRITE LDA FUNCD     ** PROCESS WRITE FUNCTION **
      SZA,RSS       CHECK 
      JMP BAD        FOR
      CPA D7          BAD 
      JMP BAD          FUNCTION.
      LDB AW8       MOVE
      LDA @WRIT      "WRITE". 
      MVW D3
      LDA FUNCD     DON'T USE 
      AND D7         FUNCTION BITS 9-11.
      ADA @WTBL     GET TABLE ADDRESS.
      LDA A,I 
      LDB A,I       STORE 
      STB CNT1       LENGTH.
      INA           A-REG POINTS TO MESSAGE.
      LDB AW11      B-REG POINTS TO DESTINATION.
      MVW CNT1      MOVE MESSAGE. 
      JMP WRD3      GO GET WORD 3.
* 
CNTRL LDA FUNCD     ** PROCESS CONTROL FUNCTION **
      CPA D5        CHECK FOR 
      JMP BAD         BAD FUNCTION
      AND D7            AND 
      LDB D11            MAP
      CPA FUNCD           40-45 
      LDB D6               TO 
      ADA DN6               5-12. 
      SSA,RSS 
      JMP BAD 
      ADA B 
      ADA @CTBL     GET TABLE ADDRESS.
      LDA A,I 
      LDB A,I       STORE 
      STB CNT1       LENGTH.
      INA           A-REG POINTS TO MESSAGE.
      LDB AW8       B-REG POINTS TO DESTINATION.
      MVW CNT1      MOVE MESSAGE. 
* 
WRD3  JSB NXTEV     PICK UP WORD 3. 
      LDB LINK,I    ALREADY 
      ADB OFSET      UP TO
      CPB ENTRY       NEXT ENTRY? 
      JMP SPCAS         YES--SPECIAL CASE!
* 
LOOP2 CLB 
      LSL 8         B:=EVENT #. 
      STB EVENT     STORE.
      CLB 
      LSL 8         B:=STATE #. 
      STB STATE     STORE.
* 
      LDA EVENT     DECODE EVENT. 
      ADA DN33      CHECK 
      SSA,RSS        FOR
      JMP BADE        BAD 
      LDA EVENT        EVENT. 
      ADA @ETBL     GET TABLE ADDRESS.
      LDA A,I 
      LDB A,I       STORE 
      STB CNT1       LENGTH.
      INA           A-REG POINTS TO MESSAGE.
      LDB AW17      B-REG POINTS TO DESTINATION.
      MVW CNT1      MOVE MESSAGE. 
* 
DESTA LDA STATE     DECODE STATE. 
      ADA DN25      CHECK 
      SSA,RSS        FOR
      JMP BADS        BAD 
      LDA STATE        STATE. 
      ADA @STBL     GET TABLE ADDRESS.
      LDA A,I 
      LDB A,I       STORE 
      STB CNT1       LENGTH.
      INA           A-REG POINTS TO MESSAGE.
      LDB AW26      B-REG POINTS TO DESTINATION.
      MVW CNT1      MOVE MESSAGE. 
* 
PRNT1 JSB PRINT     PRINT EVENT ENTRY.
      DEF BUFR
D33   DEC 33
      LDA BLANK 
      JSB FILL      FILL OUTPUT BUFFER WITH BLANKS. 
      JSB NXTEV     GET NEXT WORD.
      LDB LINK,I    PROCESSED 
      ADB OFSET      THE  LAST
      CPB ENTRY       EVENT/STATE WORD? 
      JMP PRSTA         YES--PRINT STATUS INFO. 
      LDB AW18          NO--
      STB OPNTR         SET OUTPUT POINTER
      JMP LOOP2          AND PRINT THEM.
* 
*      SPECIAL CASE--NO EVENT/STATE WORDS 
SPCAS JSB PRINT     PRINT 
      DEF BUFR       FIRST WORD 
      DEC 15          INFO ONLY.
* 
PRSTA LDA STATS     GET STATUS. 
      CLB           CONVERT 
      RRR 3          TO 
      ALF,RAL         ASCII 
      RRL 3            (OCTAL). 
      IOR "00"
      STA STASC 
      LDA D18       STATUS MESSAGE
      STA STMLN      LENGTH = 12. 
      LDA STATS     IF STATUS IS
      ADA BN22       LESS THAN 22 (OCTAL) 
      SSA,RSS 
      JMP PSTAT 
      LDA STATS        MOVE STATUS MESSAGE. 
      ADA @STAT 
      LDA A,I 
      LDB A,I 
      STB TEMP
      ADB STMLN        SET STATUS MESSAGE LEN.
      STB STMLN 
      INA 
      LDB @STMS 
      MVW TEMP
PSTAT JSB PRINT     PRINT STATUS MESSAGE. 
      DEF STMSG 
STMLN NOP 
      JSB PRINT 
      DEF BLANK 
      DEC 1 
* 
      LDB LINK,I
      CPB PNTRS     LAST ENTRY? 
      JMP FINIS       YES!
      SSB           NEGATIVE? 
      JMP FINIS       BAD LINK! 
      CMB,INB       LESS THAN FIRST WORD? 
      ADB TRFWA 
      CMB,SSB,INB,SZB 
      JMP FINIS       BAD LINK! 
      LDB D$EQT     GREATER THAN LAST?
      CMB,INB 
      ADB LINK,I
      CMB,SSB,INB,SZB 
      JMP FINIS       BAD LINK! 
      LDB LINK,I
      JMP LOOP       NO--LOOP AGAIN.
      SPC 3 
* VARIABLES USED IN EVENT TRACE 
* 
EVENT NOP 
STATE NOP 
REQCD NOP 
FUNCD NOP 
STATS NOP 
      SPC 2 
BADE  LDA AW17      BAD EVENT-- 
      STA OPNTR       CONVERT 
      LDB EVENT        TO 
      JSB TO10          DECIMAL.
      JMP DESTA 
      SPC 2 
BADS  LDA AW26      BAD STATE-- 
      STA OPNTR       CONVERT 
      LDB STATE        TO 
      JSB TO10          DECIMAL.
      JMP PRNT1 
      SKP 
FINIS JSB EXEC      TERMINATE 
      DEF *+2 
      DEF D6
      SPC 6 
* SUBROUTINES 
      SPC 3 
* CONVERT B-REG CONTENTS TO ASCII (OCTAL) 
TO8   NOP 
      STB TEMP      STORE NUMBER. 
      STA AREG      SAVE A-REG. 
      JSB CNUMO     GO CONVERT. 
      DEF *+3 
      DEF TEMP
      DEF OPNTR,I 
      LDA AREG      RESTORE A-REG.
      LDB OPNTR     BUMP
      ADB BUMP       OUTPUT 
      STB OPNTR       POINTER.
      CLB           CLEAR B-REG.
      JMP TO8,I     RETURN. 
      SPC 5 
* CONVERT B-REG CONTENTS TO ASCII (DECIMAL) 
* 
TO10  NOP 
      STB TEMP      STORE NUMBER. 
      STA AREG      SAVE A-REG. 
      JSB CNUMD     GO CONVERT. 
      DEF *+3 
      DEF TEMP
      DEF OPNTR,I 
      LDA AREG      RESTORE A-REG.
      LDB OPNTR     BUMP
      ADB BUMP       OUTPUT 
      STB OPNTR       POINTER.
      CLB           CLEAR B-REG.
      JMP TO10,I    RETURN. 
      SPC 3 
* PRINT A MESSAGE 
* 
MSG   NOP           MESSAGE ADDRESS 
LEN   NOP           LENGTH
* 
PRINT NOP 
      LDA PRINT,I   PICK
      STA MSG        UP 
      ISZ PRINT       PARAMETERS. 
      LDA PRINT,I 
      STA LEN 
      ISZ PRINT 
* 
      JSB EXEC      CALL EXEC FOR WRITE.
      DEF *+5 
      DEF D2
      DEF OUTLU 
      DEF MSG,I 
      DEF LEN 
* 
      JMP PRINT,I   RETURN. 
      SPC 3 
* GET NEXT ENTRY IN EVENT TABLE 
* 
NXTEV NOP 
      LDA ENTRY     GET CURRENT ENTRY ADDRESS.
      INA           ADD ONE.
      CPA EOTBL     IF OUT OF TABLE,
      LDA SOTBL       RESET TO BEGINNING. 
      STA ENTRY     STORE.
      LDA A,I       A:=CONTENTS OF ENTRY. 
      JMP NXTEV,I   RETURN. 
* 
SOTBL DEF TABLE     START OF EVENT TRACE TBL
EOTBL NOP             END OF EVENT TRACE TBL
      SPC 3 
* FILL OUTPUT BUFFER WITH CHAR IN A-REG 
* 
FILL  NOP 
      LDX D33       INITIALIZE COUNTER. 
FLOOP SAX BUFR-1    STORE A-REG.
      DSX           DECREMENT X-REG AND 
      JMP FLOOP       STAY IN LOOP UNTIL 0. 
* 
      JMP FILL,I    RETURN. 
      SPC 3 
* CHASE DOWN INDIRECTS
* 
INDR  NOP 
      RSS 
N     LDA A,I 
      RAL,CLE,SLA,ERA 
      JMP N 
      JMP INDR,I
      SPC 6 
* CONSTANTS AND STORAGE 
      SPC 1 
FSTVL DEF D$XS5+1 
BLANK ASC 1,
VPNT  NOP 
MPNT  NOP 
BUMP  NOP 
LINK  NOP 
ENTRY NOP 
CNT1  NOP 
CNT2  NOP 
TEMP  NOP 
AW3   DEF BUFR+2
AW8   DEF BUFR+7
AW11  DEF BUFR+10 
AW17  DEF BUFR+16 
AW18  DEF BUFR+17 
AW26  DEF BUFR+25 
OPNTR NOP 
BUFR  ASC 20, 
      ASC 13, 
*      HEADINGS:
SHEAD ASC 13, SLC LONG TERM STATISTICS: 
EHEAD ASC 12, SLC EVENT TRACE TABLE:
EHED2 ASC 25,              FUNCTION          EVENT
      ASC 3,STATE 
OUTLU NOP           RUN-TIME
      BSS 4          PARAMETERS 
AREG  NOP 
DN33  DEC -33 
DN25  DEC -25 
DN11  DEC -11 
DN6   DEC -6
DN2   DEC -2
DN1   DEC -1
D2    DEC 2 
D3    DEC 3 
D4    DEC 4 
D5    DEC 5 
D18   DEC 18
D202  DEC 202 
BN22  OCT -22 
"00"  ASC 1,00
      SPC 3 
* LONG TERM STATS HEADINGS
* 
MSGTB DEF *+1       MESSAGE TABLE 
D7    DEC 7 
      ASC 7, READ REQUESTS
      DEC 8 
      ASC 8, WRITE REQUESTS 
D11   DEC 11
      ASC 11, MESSAGES TRANSMITTED
      DEC 10
      ASC 10, SPURIOUS INTERRUPTS 
D6    DEC 6 
      ASC 6, LINE ERRORS
      DEC 7 
      ASC 7, NAKS RECEIVED
      DEC 9 
      ASC 9, BCC/PARITY ERRORS
      DEC 7 
      ASC 7, LONG TIMEOUTS
      DEC 8 
      ASC 8, RESPONSE ERRORS
      DEC 7 
      ASC 7, RESPONSE REJ 
      DEC 9 
      ASC 9, WACK/TTD RECEIVED
      SPC 3 
* POINTERS INTO TABLES
* 
@WRIT DEF STA12+1 
@WTBL DEF WTBL-1
@CTBL DEF CTBL
@ETBL DEF ETBL
@STBL DEF STBL
@STAT DEF STATT 
      SPC 3 
* LOCAL STORAGE FOR TRACE TABLES AND POINTERS 
* 
@PNTR DEF PNTRS 
TRFWA DEF D$XS5+14  FIRST WORD OF EVENT TRACE.
OFSET NOP 
PNTRS BSS 2 
TABLE BSS 200 
      SPC 3 
* READ FUNCTION TABLE 
* 
READI DEF *+1 
      ASC 6,READ INITIAL
      SPC 2 
* WRITE FUNCTION TABLE
* 
WTBL  DEF WMSG1 
      DEF WMSG2 
      DEF WMSG3 
      DEF WMSG4 
      DEF WMSG5 
      DEF WMSG6 
WMSG1 DEC 4 
      ASC 4,INQUIRY 
WMSG2 DEC 4 
      ASC 4,CONTINUE
WMSG3 DEC 5 
      ASC 5,CONVERSTNL
WMSG4 DEC 3 
      ASC 3,RESET 
WMSG5 DEC 5 
      ASC 5,DISCONNECT
WMSG6 DEC 3 
      ASC 3,DELAY 
      SPC 2 
* CONTROL FUNCTION TABLE
* 
CTBL  DEF CMSG0 
      DEF CMSG1 
      DEF CMSG2 
      DEF CMSG3 
      DEF CMS40 
      DEF CMS41 
      DEF CMS42 
      DEF CMS43 
      DEF CMS44 
      DEF CMS45 
CMSG0 DEC 3 
      ASC 3,CLEAR 
CMSG1 DEC 5 
      ASC 5,INITIALIZE
CMSG2 DEC 5 
      ASC 5,LINE OPEN 
CMSG3 DEC 5 
      ASC 5,LINE CLOSE
CMS40 DEC 8 
      ASC 8,ESTABLISH LOC ID
CMS41 DEC 8 
      ASC 8,ESTBL REM ID LST
CMS42 DEC 8 
      ASC 8,CHNG ERROR PRAMS
CMS43 DEC 8 
      ASC 8,ZERO COMM STATS 
CMS44 DEC 7 
      ASC 7,SHIFT TO RECEV
CMS45 DEC 8 
      ASC 8,DISABLE NAK SEND
      SPC 2 
* EVENT TABLE 
* 
ETBL  DEF EVT00 
      DEF EVT01 
      DEF EVT02 
      DEF EVT03 
      DEF EVT04 
      DEF EVT05 
      DEF EVT06 
      DEF EVT07 
      DEF EVT08 
      DEF EVT09 
      DEF EVT10 
      DEF EVT11 
      DEF EVT12 
      DEF EVT13 
      DEF EVT14 
      DEF EVT15 
      DEF EVT16 
      DEF EVT17 
      DEF EVT18 
      DEF EVT19 
      DEF EVT20 
      DEF EVT21 
      DEF EVT22 
      DEF EVT23 
      DEF EVT24 
      DEF EVT25 
      DEF EVT26 
      DEF EVT27 
      DEF EVT28 
      DEF EVT29 
      DEF EVT30 
      DEF EVT31 
      DEF EVT32 
EVT00 DEC 7 
      ASC 7,LINE OPEN REQ 
EVT01 DEC 7 
      ASC 7,LINE CLOSE REQ
EVT02 DEC 8 
      ASC 8,READ INQUIRY REQ
EVT03 DEC 8 
      ASC 8,READ INITIAL REQ
EVT04 DEC 8 
      ASC 8,READ CONTINUE RQ
EVT05 DEC 8 
      ASC 8,READ REPEAT REQ 
EVT06 DEC 8 
      ASC 8,READ/REV INT REQ
EVT07 DEC 5 
      ASC 5,DELAY READ
EVT08 DEC 8 
      ASC 8,WRITE INQURY REQ
EVT09 DEC 8 
      ASC 8,WRITE CNTNUE REQ
EVT10 DEC 7 
      ASC 7,WRITE CONV REQ
EVT11 DEC 8 
      ASC 8,WRT RESET(EOT)RQ
EVT12 DEC 8 
      ASC 8,WRITE DISCON REQ
EVT13 DEC 8 
      ASC 8,DELAY WRITE REQ 
EVT14 DEC 7 
      ASC 7,ACK0 RECEIVED 
EVT15 DEC 7 
      ASC 7,ACK1 RECEIVED 
EVT16 DEC 7 
      ASC 7,WACK RECEIVED 
EVT17 DEC 7 
      ASC 7,RVI RECV/SENT 
EVT18 DEC 6 
      ASC 6,ENQ RECEIVED
EVT19 DEC 6 
      ASC 6,NAK RECEIVED
EVT20 DEC 6 
      ASC 6,EOT RECEIVED
EVT21 DEC 8 
      ASC 8,DLE EOT RECEIVED
EVT22 DEC 6 
      ASC 6,TTD RECEIVED
EVT23 DEC 7 
      ASC 7,TEXT RECEIVED 
EVT24 DEC 8 
      ASC 8,BCC PRTY/FMT ERR
EVT25 DEC 6 
      ASC 6,TEXT OVERRUN
EVT26 DEC 8 
      ASC 8,GARBAGE RECEIVED
EVT27 DEC 8 
      ASC 8,BAD ID SEQUENCE 
EVT28 DEC 7 
      ASC 7,SHORT TIMEOUT 
EVT29 DEC 6 
      ASC 6,LONG TIMEOUT
EVT30 DEC 2 
      ASC 2,LOW 
EVT31 DEC 2 
      ASC 2,HIGH
EVT32 DEC 2 
      ASC 2,MID 
      SPC 2 
* STATE TABLE 
* 
STBL  DEF STA00 
      DEF STA01 
      DEF STA02 
      DEF STA03 
      DEF STA04 
      DEF STA05 
      DEF STA06 
      DEF STA07 
      DEF STA08 
      DEF STA09 
      DEF STA10 
      DEF STA11 
      DEF STA12 
      DEF STA13 
      DEF STA14 
      DEF STA15 
      DEF STA16 
      DEF STA17 
      DEF STA18 
      DEF STA19 
      DEF STA20 
      DEF STA21 
      DEF STA22 
      DEF STA23 
      DEF STA24 
STA00 DEC 4 
      ASC 4,UNOPENED
STA01 DEC 4 
      ASC 4,CONTROL 
STA02 DEC 4 
      ASC 4,READ ENQ
STA03 DEC 7 
      ASC 7,READ ENQ ERROR
STA04 DEC 7 
      ASC 7,CHECK READ REQ
STA05 DEC 2 
      ASC 2,READ
STA06 DEC 5 
      ASC 5,READ TEXT 
STA07 DEC 4 
      ASC 4,READ RVI
STA08 DEC 8 
      ASC 8,RESTRICTED READ 
STA09 DEC 5 
      ASC 5,WRITE ENQ 
STA10 DEC 8 
      ASC 8,WRITE ENQ ERROR 
STA11 DEC 8 
      ASC 8,ENQ-ENQ CONTENTN
STA12 DEC 3 
      ASC 3,WRITE 
STA13 DEC 5 
      ASC 5,WRITE TEXT
STA14 DEC 8 
      ASC 8,WRITE RESPNS ENQ
STA15 DEC 7 
      ASC 7,CHECK RESPONSE
STA16 DEC 8 
      ASC 8,BAD ACK RECEIVED
STA17 DEC 6 
      ASC 6,WRITE RETRY 
STA18 DEC 8 
      ASC 8,ENQ RCV IN WRITE
STA19 DEC 8 
      ASC 8,ENQ RCRD IN WRIT
STA20 DEC 8 
      ASC 8,WRITE CONVERSTNL
STA21 DEC 5 
      ASC 5,WRITE EOT 
STA22 DEC 8 
      ASC 8,READ EOT RSPONSE
STA23 EQU WMSG5 
STA24 DEC 5 
      ASC 5,WRITE TTD 
      SPC 3 
STATT DEF ST00
      DEF ST01
      DEF ST02
      DEF ST03
      DEF ST04
      DEF ST05
      DEF ST06
      DEF ST07
      DEF ST10
      DEF ST11
      DEF ST12
      DEF ST13
      DEF ST14
      DEF ST15
      DEF ST16
      DEF ST17
      DEF ST20
      DEF ST21
ST00  DEC 9 
      ASC 9,NORMAL COMPLETION 
ST01  DEC 8 
      ASC 8,INVALID REQUEST 
ST02  DEC 16
      ASC 16,REQST INCOMPATIBLE W/ LINE STATE 
ST03  DEC 1 
      ASC 1,  [BAD ID SEQUENCE] 
ST04  DEC 11
      ASC 11,LOCAL HARDWARE FAILURE 
ST05  DEC 6 
      ASC 6,EOT RECEIVED
ST06  DEC 15
      ASC 15,DISCONNECT (DLE EOT) RECEIVED
ST07  DEC 6 
      ASC 6,LONG TIMEOUT
ST10  DEC 11
      ASC 11,EOT SENT, ENQ RECEIVED 
ST11  DEC 6 
      ASC 6,DATA OVERRUN
ST12  DEC 9 
      ASC 9,MAX NAKS RECEIVED 
ST13  DEC 7 
      ASC 7,MAX ENQS SENT 
ST14  DEC 6 
      ASC 6,RVI RECEIVED
ST15  DEC 11
      ASC 11,ENQ SENT, ENQ RECEIVED 
ST16  DEC 11
      ASC 11,ENQ SENT, NAK RECEIVED 
ST17  DEC 9 
      ASC 9,MAX ENQS RECEIVED 
ST20  DEC 1 
      ASC 1,  [TTD SENT, NAK RECEIVED]
ST21  DEC 10
      ASC 10,IMPOSSIBLE SITUATION 
* 
STMSG ASC 16,              COMPLETION STATUS
STASC ASC 18,XX:
@STMS DEF STASC+2 
      SPC 1 
      BSS 0         SIZE OF SLCIN.
      SPC 1 
      END SLCIN