ASMB,R,L,C
*     NAME:   VERFY 
*     SOURCE: 92060-18041 
*     RELOC:  92060-16041
*     PGMR:   S.P.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM VERFY,3,99 92060-16041 REV.1704 761201
* VERFIY DATA TRANSFERED BY SAVE,RSTOR OR COPY
      EXT EXEC,VRFSB,COR.A,RMPAR
VERFY JSB RMPAR 
      DEF *+2       FETCH PARAMETERS PASSED BY SCHEDULING PROGRAM 
      DEF IP
      SUP 
      LDA 1717B 
      JSB COR.A     ROUTINE TO FIND FWA IN FREE MEM OF PARTITION
      STA FWA 
      ADA D2        SETTING UP PARMS TO PASS TO MAIN VERIFY ROUTINE 
      STA KBUF
      LDB IP+4      IF IP(5)=0 BUFFER SIZE USED BY SCHEDULING PROG
      SZB            IS 2048 WORDS OTHERWISE 6144 WORDS 
      JMP B6144     6144 WORD RECORDS USED
      ADA D2048     2048 WORD REC.-SET UP BUF TO READ REC FROM DISC 
      STA JBUF
      JMP GOVER 
* 
B6144 ADA D6144     6144 WORD REC.- SET UP BUF TO READ REC FROM DISC
      STA JBUF
* 
GOVER JSB VRFSB     MAIN VERIFY ROUTINE 
      DEF *+5 
      DEF FWA,I 
      DEF KBUF,I
      DEF JBUF,I
      DEF IP
      JSB EXEC      END VERIFY PROGRAM
      DEF *+2 
      DEF D6
* 
* 
A     EQU 0 
B     EQU 1 
IP    BSS 5 
FWA   BSS 1 
JBUF  BSS 1 
KBUF  BSS 1 
D2    DEC 2 
D6    DEC 6 
D20   DEC 20
D2048 DEC 2048
D6144 DEC 6144
      END VERFY 
                                                                                      