ASMB,R,L,C
      HED COMPILER LIBRARY END ROUTINE
      NAM END.C,7 92060-16103 780726 REV. 1901 $CLIB
* 
* 
*************************************************************** 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     * 
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE-  * 
* REPRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH- * 
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.   * 
*************************************************************** 
* 
* 
* 
*   SOURCE PART NUMBER :       92060-18064
* 
* 
*  END ROUTINE
* 
*  THIS ROUTINE WILL SEARCH THE LINKED LIST OF FCB'S AND CLOSE ALL
*  FILES. IT WILL PASS A FIVE WORD LIST OF ERRORS BACK TO THE CALLING 
*  PROGRAM AND TERMINATE EXECUTION. 
* 
* 
* 
* 
* 
* 
*  CALLING SEQUENCE:
* 
*         JSB END.C 
*         DEF COMLST
*         ERROR RETURN
*   NOTE: THIS ROUTINE RETURNS TO THE SCHEDULING PRGRAM ON SUCCESSFUL 
*         COMPLETION. 
* 
*  ON RETURN A < 0  INDICATES ERROR 
* 
* 
* 
*  ENTRY POINT: 
* 
      ENT END.C 
* 
*  EXTERNALS: 
* 
      EXT EXEC      SYSTEM EXEC 
      EXT PRTN      PARAMETER RETURNER
      EXT CLO.C     CLOSE ROUTINE 
      EXT C.HLK     HEAD OF FCB LIST
* 
* 
* 
* 
*  DETERMINE TYPE OF OPERATION
* 
*   THE FCB CONTAINS THE OPERATION TYPE AS FOLLOWS: 
* 
*      TYPE  =  0   IS READ SOURCE FILE(OR LU)
*            =  1   IS WRITE BINARY FILE(OR LU) 
*            =  2   IS WRITE SCRATCH FILE 
*            =  3   IS WRITE LIST  FILE(OR LU)
* 
* 
* 
A     EQU 0 
B     EQU 1 
* 
END.C NOP 
      LDA C.HLK     GET ADDRESS OF
END1  STA FCB         OF FCB
      SZA,RSS       END?
      JMP EXIT      YES!
      JSB CLO.C     CLOSE FCB 
FCB   NOP 
      JMP ERROR     ERROR!
      LDA FCB,I     GET NEXT FCB ADDRESS
      JMP END1        AND CLOSE IT
* 
ERROR ISZ END.C     STEP TO RETURN
      JMP END.C,I   ERROR RETURN
* 
EXIT  LDA END.C,I   GET THE DEF TO THE PRAMS
      STA PADD      AND PUT IN THE PRAM CALL
      JSB PRTN      RETURN
      DEF *+2         PARAMETER STRING
PADD  DEF END.C,I 
      JSB EXEC      TERMINATE 
      DEF *+2 
      DEF .6
* 
.6    DEC 6 
      END 
                                                                              