ASMB,L,C
        HED COMPILER LIBRARY - GET SEGMENT ADDRESS
* 
*************************************************************** 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     * 
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE-  * 
* REPRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH- * 
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.   * 
*************************************************************** 
* 
*    SOURCE: 19060-18073
* 
* 
* 
      NAM ID.AD,7 92060-16103 780811 REV. 1901 $CLIB
        ENT ID.AD 
* 
      EXT EXEC,IDSGA,$OPSY
*  THIS COMPILER LIBRARY ROUTINE SEARCHES THE LIST OF ID SEGMENTS 
*  TO FIND THE ADDRESS OF THE SEGMENT WHOSE NAME IS GIVEN IN THE
*  ADDRESS SAVED IN THE B-REGISTER. 
* 
*       CALLING SEQUENCE:  B = ADDRESS OF SEGMENT NAME
*                          JSB ID.AD
* 
*                RETURNS:  B = 0 IF NOT FOUND 
*                          B = ADDRESS IF FOUND 
* 
* 
ID.AD NOP           ENTRY 
      STB NAME
      INB 
      STB NAM34 
      INB 
      STB NAM5
TRY   JSB IDSGA     TRANSLATE THE NAME TO AN ADDRESS
      DEF *+2 
NAME  NOP 
      STA B         PUT THE ADDRESS IN THE RIGHT REG
      SZB           IF WE GOT ONE 
      JMP ID.AD,I   RETURN WITH IT
* 
      JSB EXEC      WE FAILED SO TRY T5IDM TO RP IT 
      DEF RTN 
      DEF D23I
      DEF T5IDM 
      DEF NAME,I
NAM34 NOP 
NAM5  NOP 
RTN   CLB           FAILED SET UP ERROR RETURN (LOADS RESULT FROM A)
      LDA $OPSY     FIGURE HOW TO GET THE RETURN
      ERA,SLA       TEST THE DMS BIT
      JMP DMS       IF DMS GO DO XLOAD
* 
      LDA B,I       GET THE RETURN WORD 
      JMP TS        GO TEST IT
* 
DMS   XLA B,I       DMS INSTALLED  DO A XLOAD 
TS    CLB           SET UP B FOR REJECT 
      SZA           DID WE GET ANY WHERE? 
      JMP ID.AD,I   NO  RETURN WITH B=0 
* 
      JMP TRY       YES TRY AGAIN 
* 
A     EQU 0 
B     EQU 1 
D23I  DEF 23,I
T5IDM ASC 3,T5IDM 
      END 
                      