ASMB,R,L,C
      HED RTE MICRODEBUG EDITOR PROGRAM-MDEP
      NAM MDEP,3,98 RTE MDEP 92061-16004 REV. A 760720
      EXT EXEC,RMPAR,MDES 
* 
*   ********************************************************* 
*   * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.           * 
*   *                                                       * 
*   * ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM MAY BE  * 
*   * PHOTOCOPIED, REPRODUCED, OR TRANSLATED TO ANOTHER     * 
*   * PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN CONSENT OF * 
*   * HEWLETT-PACKARD COMPANY.                              * 
*   ********************************************************* 
* 
*     OPERATOR SCHEDULE MDE:
* 
*     *ON,MDEP [,LU1 [,LU2 [,LU3 [,LU4 ]]]] 
* 
*           WHERE:  LU1=OPERATOR CONSOLE LU(OPTIONAL. DEFAULT=1)
*                   LU2=WCS LU NUMBER(OPTIONAL) 
*                   LU3=ADDITIONAL WCS LU(OPTIONAL) 
*                   LU4=ADDITIONAL WCS LU(OPTIONAL) 
* 
*     INTERNAL SCHEDULE MDE:
* 
*                   EXT EXEC
*                   . 
*                   . 
*             SCHED JSB EXEC     TRANSFER CONTROL TO RTE
*                   DEF RTURN    RETURN POINT 
*                   DEF RCODE    REQUEST CODE 
*                   DEF NAME     NAME OF PROGRAM
*                   DEF LU1      OPERATOR CONSOLE LU(OPTIONAL)
*                   DEF LU2      WCS LU NUMBER(OPTIONAL)
*                   DEF LU3      ADDITIONAL WCS LU(OPTIONAL)
*                   DEF LU4      ADDITIONAL WCS LU(OPTIONAL)
*             RTURN EQU * 
*                   . 
*                   . 
*             RCODE DEC 23 OR 24 23=WITH WAIT,24=WITHOUT WAIT 
*             NAME  ASC 3,MDEP   ASCII PROGRAM NAME 
*             LU1   DEC XX       OPERATOR CONSOLE LU(OPTIONAL)
*             LU2   DEC XX       WCS LU NUMBER(OPTIONAL)
*             LU3   DEC XX       ADDITIONAL WCS LU(OPTIONAL)
*             LU4   DEC XX       ADDITIONAL WCS LU(OPTIONAL)
* 
*     MDEP IS A USER PROGRAM WHICH SETS THE 
*     REGISTERS TO 0 AND PASSES PARAMETERS TO MDES. SEE 
*     MDES FOR A MORE DETAILED DESCRIPTION OF THE RTE 
*     MICRODEBUG EDITOR OPERATIONS. 
* 
      HED MDE 
      SUP 
S     EQU 1 
* 
MDEP  NOP 
      JSB RMPAR     GET PARAMETERS
      DEF *+2        AND PUT THEM 
      DEF PBUFF       IN PARAMETERS BUFFER
      LDA LU1       DEFAULT OPERATOR
      SZA,RSS        CONSOLE LOGICAL UNIT #?
      CLA,INA       YES.MAKE IT SYSTEM CONSOLE
      IOR CW        CONFIGURE WRITE 
      STA CW         REQUEST CODE 
      CLA           SET 
      CLB            REGISTERS
      OTA S           TO 0
      CAX              FOR MDES 
      CAY 
      CLE 
      CLO 
      JSB MDES      CALL MDES 
      DEF RTN       RETURN POINT
      DEF LU1       OPERATOR CONSOLE LU 
      DEF LU2       WCS LU
      DEF LU3       ADDITIONAL WCS LU 
      DEF LU4       ADDITIONAL WCS LU 
      DEF ECODE     ERROR CODE(0=SUCCESSFUL.-1=ABORTED) 
RTN   EQU * 
      LDA ECODE     SUCCESSFUL
      SSA,RSS        COMPLETION?
      JMP END       YES.GO TERMINATE
      JSB EXEC      NO.WRITE
      DEF TERM       "MDEP ABORTED" 
      DEF .2          MESSAGE 
      DEF CW
      DEF MSGXX 
      DEF .6
TERM  JSB EXEC      TERMINATE 
      DEF *+2        MDEP 
      DEF B6
END   EQU * 
      JSB EXEC      WRITE 
      DEF *+5        "$END MDEP"
      DEF .2          MESSAGE 
      DEF CW
      DEF $END
      DEF .5
      JMP TERM      GO TERMINATE PROGRAM
      SKP 
PBUFF EQU *         PROGRAM PARAMETERS FOR MDE
LU1   NOP           OPERATOR CONSOLE LU(OPTIONAL) 
LU2   NOP           1ST WCS LU(OPTIONAL)
LU3   NOP           2ND WCS LU(OPTIONAL)
LU4   NOP           3RD WCS LU(OPTIONAL)
      BSS 1         DUMMY LOCATION FOR RMPAR
.2    DEC 2 
.5    DEC 5 
.6    DEC 6 
B6    EQU .6
CW    OCT 200 
ECODE NOP 
MSGXX ASC 6,MDEP ABORTED
$END  ASC 5, $END MDEP
      END MDEP      DEFINE PRIMARY ENTRY POINT
                                                                                                          