ASMB,R,L,C
*     NAME  : $MDMP 
*     SOURCE: 92064-18036 
*     RELOC:  PART OF 92064-16013 
*     PROGMR: E.J.W.
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM $MDMP,0  92064-16013  REV.1650  761020
      ENT $SABR,$MPT1,$MPT4,$MPT5,$MPT7 
      EXT $TREM,$WORK,$XEQ,$LIST,$ERMG,$ABRT,$IOCL
* 
A     EQU 0 
B     EQU 1 
* 
$SABR NOP 
      STB TEMPH     SAVE ID SEG ADDR
      ADB D16       INDEX TO TIME-LIST WORD 
      JSB $TREM     REMOVE FROM TIME-LIST 
      LDB TEMPH 
      JSB TERM      TERMINATE PROG
      JMP $SABR,I   RETURN
* 
TERM  NOP 
      JSB $LIST     MOVE PROG TO DORMANT STATE
       OCT 400
      LDB $WORK 
      ADB D20       INDEX TO FATHER WORD
      LDA B,I 
      AND B7400     KEEP ONLY RE,RM,RN FLAGS
      STA B,I 
      JMP TERM,I    RETURN
* 
* 
$MPT1 CLA           EXEC (6)  TERMINATION 
      LDA RQP2,I
      SZA           OPTION WORD = 0?
      JMP ERQ1       NO, ERROR 'RQ' 
* 
      LDB XEQT      (B) = ID SEG ADDR 
      LDA RQRTN 
      STA XSUSP,I   SET RETURN ADDR 
      CLA           IN CASE RQP3 NOT GIVEN. 
      LDA RQP3,I
      ADA M2
      SSA           OPTION < 2 ?
      JMP MPT1B      YES, TREAT AS NORMAL 
* 
      CMA,INA,SZA,RSS 
      JMP SOFT      (2) SOFT ABORT
* 
      INA,SZA,RSS 
      JMP HARD      (3) HARD ABORT
* 
MPT1B JSB TERM      DO TERMINATE STUFF
      JMP $XEQ      RETURN TO DISPATCHER
* 
SOFT  JSB $SABR     DO SOFT ABORT 
      JMP $XEQ      RETURN TO DISPATCHER
* 
HARD  LDA D15       (B) STILL HAS ID SEG ADDR 
      ADA B         INDEX TO STATUS WORD
      LDA A,I 
      AND D15       JUST KEEP STATUS PART 
      STA B 
      LDA XEQT
      CPB D2        I/O SUSPENDED?
      JMP $IOCL      YES, KILL I/O
* 
      JSB $ABRT     FINISH THE ABORT
      JMP $XEQ      RETURN TO DISPATCHER
* 
      SPC 4 
$MPT4 EQU *         DUMMY ENTRY 
$MPT5 EQU *         DUMMY ENTRY 
$MPT7 EQU *         DUMMY ENTRY 
ERQ1  LDA RQ1       NONE OF ABOVE 
      LDB BLANK 
      JSB $ERMG 
      JMP $XEQ
* 
RQ1   ASC 1,RQ
BLANK ASC 1,
D2    DEC 2 
D15   DEC 15
D16   DEC 16
D20   DEC 20
TEMPH NOP 
B7400 OCT 7400
M2    DEC -2
* 
RQRTN EQU 1677B 
RQP2  EQU 1701B 
RQP3  EQU 1702B 
XEQT  EQU 1717B 
XSUSP EQU 1730B 
* 
      ORG *         SIZE OF MODULE
* 
      END 
                                                                                            