ASMB,R,L,C
*     NAME:   RN..  
*     SOURCE: 92064-18050 
*     RELOC:  92064-16017 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM RN..,7  92064-16017  REV.1650  760709 
* 
      EXT CLD.R,.P1,.P2,.P3,.P4,NAM..,.ENTR 
      EXT PMOVE,.DRCT,N.OPL 
      ENT RN..
* 
      SUP 
* 
* 
CNT   NOP 
LST   NOP 
ER    NOP 
* 
RN..  NOP 
      JSB .ENTR 
      DEF CNT 
* 
*  ENOUGH PARMS?
* 
      LDB .50       PRESET
      STB ER,I         NOT ENOUGH PARMS ERROR 
      LDA CNT,I     FETCH NUMBER OF PARMS 
      CPA .2        MUST HAVE AT LEAST 2
      RSS           YEP IT'S OK 
      JMP RN..,I    NOPE--GET OUT 
* 
      LDA LST       ADVANCE 
      ADA .5           TO NEW-NAME
      STA TEMP      SAVE IT'S ADDRESS 
      JSB NAM..     NEW-NAME VALID NAME 
      DEF RTN2
      DEF TEMP,I
* 
RTN2  STA ER,I      SET ERROR CODE
      SZA           CONTINUE IF OK
      JMP RN..,I    ELSE EXIT 
* 
*  SAVE WD27 OF IDSEG FOR PARM PASSING TO D.R 
* 
      LDA XEQT      IDSEG ADDRESS 
      ADA .26       ADVANCE TO WD 27
      STA CNT       SAVE ADDRESS
      LDA A,I       FETCH OLD VALUE 
      STA W27       SAVE IT FOR EXIT
      LDA TEMP      FETCH ADDRESS OF NEW-NAME 
      ADA .2        ADVANCE TO THIRD WORD 
      LDB CNT       FETCH ADDR OF IDSEG WD27
      JSB PMOVE     GO PRIV AND MOVE WD3 (NUNAME) DOWN
      OCT 1 
* 
* 
*   SET UP REST OF PARAMETERS FOR D.R CALL
* 
      LDA .2        SET FUNCTION CODE 
      STA .P1              FOR NAME CHANGE
* 
      JSB .DRCT     FETCH 
      DEF N.OPL        SUBPARM
      INA                 ADDRESS 
      LDA A,I       FETCH 
      STA .P2           LU OF THIS NAME 
      ISZ LST       ADVANCE PAST FLAG WD(OLD NAME)
      LDA LST,I     FETCH FIRST WORD
      STA .P3       SAVE FOR D.R
      ISZ LST       ADVANCE TO 2ND WORD 
      DLD LST,I     FETCH LAST TWO WORDS
      DST .P4       SAVE THEM ALSO
      DLD TEMP,I    SET A/B=WDS 1&2 OF NUNAME 
      JSB CLD.R     GO SCHED D.R,PASSING 8 PARMS
* 
* 
      LDA B,I       FETCH ERROR RETURN
      STA ER,I      SET ERROR CODE
      JMP RN..,I    EXIT
* 
* 
N2    OCT -2
.2    OCT 2 
.5    OCT 5 
.26   DEC 26
.50   DEC 50
TEMP  NOP 
W27   NOP 
* 
* 
A     EQU 0 
B     EQU 1 
XEQT  EQU 1717B 
PLEN  EQU * 
      END 
                                                                                    