ASMB,R,L,C
*     NAME:   CLD.R 
*     SOURCE: 92064-18066 
*     RELOC:  92064-16061 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM CLD.R,7  92064-16061  REV.1650  761018
* 
      HED CALL ROUTINE FOR D.RC 761018
      ENT CLD.R,.P1,.P2,.P3,.P4,.P5 
      EXT EXEC,$D.RC,$OPSY,$CON 
* 
* 
*     THIS ROUTINE PROVIDES A CENTRAL 
*     CALLING POINT FOR THE SCHEDULING
*     OF D.R. 
* 
* 
*              RTE-M1 MAY  NOT HAVE THE SCHEDULING
*              ABILITY FOUND IN M2 & M3. THEREFORE
*              THIS ROUTINE WILL DO A DIRECT ENTRY
*              IN THE M1 ENVIRONMENT IF THE DIRECTORY 
*              MANAGER ($D.RC1) WAS RELOCATED INTO
*              THE RESIDENT LIBRARY.
* 
* 
* 
* 
.P1   NOP 
.P2   NOP 
.P3   NOP 
.P4   NOP 
.P5   NOP 
TMPA  NOP 
TMPA2 NOP 
* 
CLD.R NOP           ENTRY POINT 
      DST TMPA      SAVE THE A AND B REGS 
      LDA $D.RC     FETCH THE SUBROUTINE FLAG 
      SSA,RSS       WAS M1 VERSION LOADED?(DUMMY ENT =-1) 
      JMP M1         YES--GO DO DIRECT ENTRY IF M1
* 
      LDA TMPA      RESTORE A 
      JSB EXEC      NOW SCHED 
      DEF BACK         D.R WITH 
      DEF SCED            WAIT AND QUEUE
      DEF D.RC      PASSING 
      DEF .P1              THE FIVE TEMPS IN THE CALL.
      DEF .P2        FOUR MORE PARMS MAY BE PASSED BY 
      DEF .P3        USING WDS 27&28 OF CALLERS ID SEG
      DEF .P4        ALONG WITH THE A AND B REGS. D.R CAN THEN
      DEF .P5        DETERMINE HIS FATHERS ID ADDRESS AND PROCEDE 
*                    TO FETCH ANY EXTRA PARMS AS REQUIRED 
* 
BACK  JMP ERR8      SCHEDULE ERROR
* EXIT TO CALLING PROG. 
*    RETURN PARMS MAY BE FETCHED BY RMPAR 
* 
* 
      JMP CLD.R,I 
* 
* 
M1    LDA $OPSY     FETCH OP SYS TYPE 
      CPA N7        ALLOW RE-ENTRANT CALL ONLY IN M1
      RSS           OK---SKIP 
      JMP ERR26     NO!!!! GIVE ERROR AND ABORT 
* 
      JSB $D.RC     DIRECT ENTRY TO D.R IN  LIBRARY 
      DEF M1BK
      DEF .P1 
* 
M1BK  JMP CLD.R,I   EXIT, SEE ABOVE FOR INFO ON RETURN PARMS
* 
* 
N7    DEC -7
* 
SCED  OCT 100027
D.RC  ASC 3,D.RCR 
* 
* 
ERR8  LDA E8        SCHEDULE ERROR
      RSS 
ERR26 LDA E26              ATTEMPT TO USE M1 SUB IN 2/3 SYS 
      STA CPE       SET THE ERROR CODE
* 
      LDA $CON,I    FETCH LU FOR MESSAGE
      AND B77       ISOLATE LU
      STA LU        SAVE IT FOR CALL
* 
      JSB EXEC
      DEF P1TN
      DEF .2
      DEF LU
      DEF EBUF
      DEF .5
* 
P1TN  LDB XEQT      FETCH IDSEG ADDRESS 
      ADB .12       ADVANCE TO NAME 
      LDA B,I       MOVE
      STA PN1       FIRST WORD
      INB 
      DLD B,I       FETCH NEXT TWO
      STA PN2       SET WORD 2
      SWP           GET LAST WORD TO A
      AND HBYTE     ISOLATE HIGH BYTE 
      IOR B40       INCLUDE BLANK 
      STA PN3       SET INTO BUF
* 
      JSB EXEC
      DEF P2TN
      DEF .2
      DEF LU
      DEF ABUF
      DEF .8
* 
P2TN  JSB EXEC
      DEF *+2 
      DEF .6
* 
* 
.2    OCT 2 
.5    OCT 5 
.6    OCT 6 
.12   DEC 12
B40   OCT 40
B77   OCT 77
HBYTE OCT 177400
LU    NOP 
E8    ASC 1,08
E26   ASC 1,26
EBUF ASC 4,  FMGR 0 
CPE   BSS 1 
ABUF  ASC 1,
PN1   NOP 
PN2   NOP 
PN3   NOP 
      ASC 4, ABORTED
.8    DEC 8 
* 
* 
XEQT  EQU 1717B 
B     EQU 1 
* 
* 
END   EQU * 
      END 
                                                                            