ASMB,R,L,C
*     NAME:   MGLU
*     SOURCE: 92064-18091 
*     RELOC:  92064-16072 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM MGLU,7  92064-16072  REV.1650  760805 
* 
*    THIS ROUTINE IS USED BY THE FMP TO SET UP A SPECIAL
*    NAME FOR THE REFERENCED LU WHICH ALLOWS AN LU TO 
*    BE TREATED AS A TYPE ZERO FILE (YOU CAN DO OPEN\CLOSE ETC.)
* 
*    THIS NAME IS LU..XX WHERE XX IS THE ASCII LU.  
*   
*       CALLING SEQUENCE: 
* 
*         JSB MGLU
*         DEF RTN 
*         DEF LU        
*         DEF RESULT BUFFER   
* 
*RTN    
* 
* 
      ENT MGLU
      EXT .ENTR,.PDCV 
      SUP 
* 
.99   DEC 99
B77   OCT 77
* 
* 
LURX  NOP 
MNAX  NOP 
MGLU  NOP 
      JSB .ENTR     FETCH PARMS 
      DEF LURX
* 
      LDA LURX,I    FETCH LU
      AND B77       ISOLATE GOOD PART 
      CPA LURX,I    THIS GUY OK?
      RSS           YEP---CONTINUE
      LDA .99       NOPE--FORCE OPEN ERROR(BAD LU)
* 
* 
      JSB .PDCV     GO CONVERT IT TO ASCII
      IOR BIT12     FORCE A BLANK TO A ZERO 
      STA MJ.2      SET RESULT INTO MAGIC NAME
      LDA MJNM      FETCH FIRST WORD
      STA MNAX,I    SET RESULT IN CALLER'S BUFFER 
      ISZ MNAX      BUMP BUFFER POINTER 
      DLD MJNM2     FETCH LAST TWO WORDS
      DST MNAX,I
      JMP MGLU,I    GET OUT 
* 
BIT12 OCT 10000 
* 
MJNM  ASC 1,LU
MJNM2 ASC 1,..
MJ.2  NOP 
      END 
      ENT IMESS 
* 
IO    NOP 
BUFAD NOP 
CCNT  NOP 
* 
* 
IMESS NOP 
      JSB .ENTR 
      DEF IO
* 
      LDA $CON,I
      AND B77       ISOLATE LU
      IOR ECHO
      STA LU
* 
* 
      JSB EXEC
      DEF MESSR 
      DEF IO,I
      DEF LU
      DEF BUFAD,I 
      DEF CCNT,I
* 
MESSR JMP IMESS,I 
* 
ECHO  OCT 400 
LU    NOP 
B77   OCT 77
      END 
* 
                                                                                                              