ASMB,R
      HED <<RTE BASIC - LISTER/SUB #2>>       92065-16001 
      NAM BASC2,7 92065-16001 REV.2001  791022
* 
*     DATE 8-29-79
* 
* 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
* 
* 
* 
*      SOURCE:    92065-18003 
* 
* 
* 
************************************************************* 
* 
      ENT BASC2 
      EXT EXEC,RDYPT,FNDPS,OUTCR,OUTIN,INTCK,INDCK
      EXT WRITE,ERRPT,NUMOT,GETCR,FCNS
      EXT QUOTE,DIM,MESGA,CLFIL 
      EXT IFBRK,FINDV,PRMT
      COM TEMPS(30),PNTRS(61),SPEC(10)
**************************************
*                                    *
*    SEGMENT #2: LIST THE PROGRAM    *
*                                    *
**************************************
* 
*  THIS PART OF THE INTERPRETER IS LOADED BY THE BASIC MAIN CONTROL 
*    WHENEVER THE 'LIST' OR 'SAVE'  COMMANDS ARE GIVEN. IT WILL RE- 
*    CONSTRUCT A USER PROGRAM, LINE BY LINE, CONVERTING IT FROM THE 
*    TRANSLITERATED FORM TO ASCII. IT THEN OUTPUTS THIS ASCII TO
*    THE LIST DEVICE. 
* 
*  IN ADDITION, THIS SEGMENT IS LOADED WHENEVER AN ERROR OCCURS. IT 
*    WILL PRINT OUT THE APPROPRIATE ERROR MESSAGE AND THEN RETURN 
*    EXECUTION TO THE MAIN CONTROL PROGRAM. 
      SKP 
*************************** 
*                         * 
* CONSTANTS AND VARIABLES * 
*                         * 
*************************** 
* 
FWAM  EQU PNTRS     FIRST WORD OF AVAILABLE MEMORY
LWBM  EQU PNTRS+1   LAST WORD OF AVAILABLE MEMORY 
.INBF EQU PNTRS+2   INPUT BUFFER ADDRESS
SBUFA EQU PNTRS+3   SYNTAX BUFFER ADDRESS 
SYMTA EQU PNTRS+4   START OF SYMBOL TABLE 
SYMTF EQU PNTRS+5   END OF SYMBOL TABLE 
PBUFF EQU PNTRS+6   FIRST WORD OF USER PROGRAM
PBPTR EQU PNTRS+7   LAST WORD+1 OF USER PROGRAM 
INBFA EQU PNTRS+8   INPUT BUFFER POINTER
ICCNT EQU PNTRS+9   INPUT CHARACTER COUNT 
SBPTR EQU PNTRS+10  SYNTAX BUFFER POINTER 
.LNUM EQU PNTRS+11  CURRENT LINE #
FCORE EQU PNTRS+12  START OF FREE CORE
MNNAM EQU PNTRS+13  MNEMONIC TABLE NAME:SC:LU 
BRNAM EQU PNTRS+18  BRANCH TABLE NAME:SC:LU 
FWAMM EQU PNTRS+23  POINTER TO START OF MNEMONIC TABLE
FWAMB EQU PNTRS+24  POINTER TO START OF BRANCH TABLE
.OTBF EQU PNTRS+25  POINTER TO OUTPUT BUFFER 
OCCNT EQU PNTRS+26  OUTPUT CHARACTER COUNT
OTBFA EQU PNTRS+27  POINTER INTO OUTPUT BUFFER
LUOUT EQU PNTRS+28  CURRENT OUTPUT L.U. # 
LUINP EQU PNTRS+29  CURRENT INPUT L.U. #
SIGN  EQU PNTRS+30  SIGN OF CURRENT NUMBER
BLANK EQU PNTRS+31  CURRENT TERMINATION CHAR
REC#  EQU PNTRS+32  COMMAND FILE RECORD NUMBER
FLTYP EQU PNTRS+33  TYPE 0 FILE FLAG
TTYPR EQU PNTRS+34  CONSOLE TTY L.U. #
PRINT EQU PNTRS+35  LISTING L.U. #
READR EQU PNTRS+36  AUXILLIARY INPUT L.U. # 
PUNCH EQU PNTRS+37  AUXILLIARY OUTPUT L.U. #
ERTTY EQU PNTRS+38  ERROR LIST OUTPUT L.U. #
FLFIL EQU PNTRS+39  FILE FLAG 
SAVFL EQU PNTRS+40  .SAVE COMMAND FLAG ADDRESS
PFLAG EQU PNTRS+41  SAVE,LOAD FILE FLAG 
LOLIM EQU PNTRS+42  LOW LIMITS OF PROGRAM 
HILIM EQU PNTRS+43  HIGH LIMITS OF PROGRAM
LORUN EQU PNTRS+44  LOW RUN LIMITS
HIRUN EQU PNTRS+45  HIGH RUN LIMITS 
SLSTM EQU PNTRS+46  EXECUTE SLOW STMTS
LOTRC EQU PNTRS+47  LOW TRACE LIMITS
HITRC EQU PNTRS+48  HIGH TRACE LIMITS 
BRKP1 EQU PNTRS+49  BREAK POINT #1
BRKP2 EQU PNTRS+50  BREAK POINT #2
BRKP3 EQU PNTRS+51  BREAK POINT #3
BRKP4 EQU PNTRS+52  BREAK POINT #4
SMFLG EQU PNTRS+53  SIMULATE FLAG 
TYPE  EQU PNTRS+54  PARTIAL LINE CHARACTER COUNT
DLMTR EQU PNTRS+55  CHAR EDIT DELIMITER 
MERGF EQU PNTRS+56  MERGE FLAG
      SKP 
TEMPT BSS 7 
STTYP DEF DIM 
FOPBS DEF QUOTE-2 
LNBFA DEF LNBFF-1 
ERBFA DEF ERBUF 
AFCNS DEF FCNS
      SPC 1 
      SUP PRESS MULTIPLE LISTINGS 
      SPC 1 
.0    DEC 0 
.1    DEC 1 
.3    DEC 3 
.7    DEC 7 
.10   DEC 10
.15   DEC 15
.32   DEC 32
.34   DEC 34
.40   DEC 40
B23   OCT 23
.45   DEC 45
.73   DEC 73
.G50  OCT 50000 
B36   OCT 36
B37   OCT 37
B40   EQU .32 
B44   OCT 44
B60   OCT 60
B100  OCT 100 
F     OCT 106 
N     OCT 116 
B177  OCT 177 
B77   OCT 77
B200  OCT 200 
B777  OCT 777 
MSK0  OCT 377 
B1100 OCT 1100
COMWD OCT 34000 
REMOP OCT 36000 
FOROP OCT 41000 
NEXOP OCT 42000 
NSBOP OCT 56000 
ONOP  OCT 73000 
OPMSK OCT 77000 
TYPFL OCT 100017
OPDMK OCT 100777
M1    DEC -1
M2    DEC -2
M3    DEC -3
M5    DEC -5
M21   DEC -21 
MNEG  OCT 100000   MAXIMUM NEGATIVE FLOATING
      OCT 376         POINT NUMBER
FLGBT EQU MNEG
      SPC 3 
ERBUF ASC 5, IN LINE
LNBFF BSS 2 
BLNK  DEF *+1 
      ASC 2,  _                                                     : 
ALEN  DEF *+1 
      OCT 3 
      ASC 2,LEN 
FORCT NOP           'FOR'-'NEXT' SPACE COUNTER
LNCNT NOP           LINE COUNTER
CRLF  DEF *+1 
      OCT 6412
      SKP 
********************
*                  *
* LIST THE PROGRAM *
*                  *
********************
BASC2 NOP 
      CLA           INITIALIZE
      STA LNCNT       LINE COUNTER
      STA FORCT     .RESET FOR/NEXT COUNTER 
      LDA FOPBS     .SET OPERATOR PRINT ADDRESS 
      JSB INDCK     .   DIRECT
      STA FOPBS 
      LDA STTYP     .SET SYNTAX TABLE POINTER 
      JSB INDCK     .  DIRECT 
      STA STTYP 
      LDA LUOUT     IS IT ERROR 
      SSA             MESSAGE ENTRY?
      JMP PRMES     YES!
      LDB LOLIM     SET PTR 
      STB TEMPS       TO PROGRAM START
      LDB PRINT     ASSUME PRINTER
      LDA PFLAG       BUT CHECK FLAG FOR SURE 
      SSA               -1 IF PUNCH 
      LDB PUNCH           ITS A PUNCH REQUEST 
      CMA,SSA,INA,SZA PFLAG <= 0? 
      RSS           .NO SPEC LU # 
      STB LUOUT     SAVE OUTPUT DEVICE L.U. 
      SPC 1 
*  IF LINE PRINTER LIST DEVICE - MOVE FORM TO NEW PAGE
*    IF PUNCH LIST DEVICE - PUNCH LEADER ON TAPE
      SPC 1 
      LDA FLFIL     .OUTPUTTING ON FILE ? 
      INA,SZA,RSS 
      JMP LIST1     .YES - IGNOR DEVICE CONTROLS
      LDA FLFIL     .CHECK FOR FILE SAVE
      INA,SZA,RSS   .FILE THIS TIME?
      JMP LIST1     .YES
      LDA LUOUT 
      JSB FINDV     .FETCH DRIVER NUMBER
      CPA .2        .PUNCH TYPE DEVICE ?
      JMP LIS40     . YES - OUTPUT LEADER 
      CPA .10       .LINE PRINTER ? 
      JMP LIS41     .YES THROW A PAGE 
      CPA .5
      RSS           .IT IS A CRT LINE PRINTER ? 
      JMP LIST1     .NO SPECIAL PROCESSING
      CPB .4
LIS41 JSB HEAVE     .YES A LINE PRINTER 
      JMP LIST1     .CONTINUE 
* 
LIS40 LDA LUOUT     .FORM LEADER PUNCH
      IOR B1000     .  CONTROL WORD 
      STA LIS51 
      JSB EXEC      .PUNCH LEADER 
      DEF *+3 
      DEF .3
      DEF LIS51 
      SPC 1 
*  INITIALIZE FOR CONVERTING A STATEMENT
      SPC 1 
LIST1 LDB TEMPS     MORE
      CPB HILIM       PROGRAM?
      JMP LIS13     NO
* 
      CCA           INITIALIZE
      ADA .OTBF       OUTPUT
      STA OTBFA         BUFFER POINTER
      CLA           INITIALIZE
      STA OCCNT       CHAR COUNT
      SKP 
* 
      JSB OUTBL     .YES - SET BLANKS AS FIRST CHAR 
      JSB OUTBL     .  IN LINE
      ISZ LNCNT     UPDATE LINE COUNTER 
      SPC 1 
*  OUTPUT LINE NUMBER 
      SPC 1 
      LDA TEMPS,I   OUTPUT
      STA .LNUM 
      JSB OUTIN       SEQUENCE NUMBER 
      JSB OUTBL     .OUTPUT BLANK 
      LDB FORCT 
      JSB FORSP     INDENT 'FOR'-'NEXT' LOOP
      ISZ TEMPS     FETCH 
      LDA TEMPS,I     STATEMENT LENGTH
      CMA,INA       SET 
      INA             WORD
      STA LCNTR         COUNTER 
LIST3 ISZ TEMPS     MORE
      ISZ LCNTR       STATEMENT?
      JMP LIST4     YES 
* 
*     IF NO MORE STATEMENT THEN CHECK FOR AN ODD # OF BYTES.
*     MAKE EVEN FOR WORD ORIENTATED DEVICES.
* 
      LDA OCCNT 
      SLA,RSS       .CHECK THE OUTPUT BUFFER FOR ODD
      JMP LIS30     .EVEN ALREADY - DON'T CHANGE THE BUFFER 
      LDA B40       .ODD -  ADD A SPACE 
      JSB OUTCR 
      SPC 1 
*  CONVERSION COMPLETE - OUTPUT THE LINE ON LIST DEVICE 
      SPC 1 
LIS30 JSB IFBRK     IS
      DEF *+1         ATTENTION 
      SZA               FLAG SET? 
      JMP LIS13     YES, GO TO READY
* 
* 
      LDB .OTBF     OUTPUT
      LDA OCCNT       STATEMENT 
      JSB WRITE         TO PERIPHERAL 
      JMP LIST1 
* 
      SPC 1 
*  CONVERT THE OPERATOR 
      SPC 1 
LIST4 LDA TEMPS,I 
      AND OPMSK 
      SZA,RSS       NULL OPERATOR?
      JMP LIST5     YES 
* 
CONT  STA TEMP2     SAVE OPERATOR 
      ALF,ALF       SINGLE
      ARS 
      LDB 0           CHARACTER 
      ADA M21 
      SSA,RSS           OPERATOR? 
      JMP LIS12     NO
      BLS           YES 
      INB           LOAD
      ADB FOPBS       SYMBOL'S
      LDA 1,I           ASCII WORD
      ALF,ALF       ADJUST
      AND MSK0      CHARACTER 
      CPA .34       " ? 
      JMP LIS14     YES 
      JSB OUTCR     NO
      SKP 
*  CONVERT THE OPERAND
      SPC 1 
LIST5 LDA TEMPS,I 
      AND OPDMK     SAVE
      STA TEMP3       OPERAND 
      SSA           FLAG BIT SET? 
      JMP LIST9     YES 
      SZA,RSS       NO, NULL OPERAND? 
      JMP LIST3     YES 
      AND TYPFL     ISOLATE TYPE PART 
      CPA .15       FUNCTION? 
      JMP LIST8     YES 
      SPC 1 
*  OUTPUT LETTER-DIGIT COMBINATIONS 
      SPC 1 
LIST6 LDA TEMP3 
      RRR 4 
      AND B177        OUTPUT
      ADA B100
      JSB OUTCR         LETTER
      LDA TEMP3     YES 
      AND .15       RESTORE 
      SZA,RSS       STRING? 
      JMP LIS16     YES!
      ADA M5        NO! 
      SSA           LETTER-DIGIT? 
      JMP LIST3     NO! 
      ADA B60         DIGIT 
LIS17 JSB OUTCR     OUTPUT DIGIT
      JMP LIST3 
      SPC 1 
LIS16 LDA B44       '$' 
      JMP LIS17 
      SPC 1 
LIST8 LDA F         OUTPUT
      JSB OUTCR 
      LDA N           'FN'
      JSB OUTCR 
      LDA TEMP3     OUTPUT
      RRR 4 
      AND B177        LETTER
      ADA B100
      JSB OUTCR 
      JMP LIST3 
      SPC 1 
*  OUTPUT FLOATING-POINT CONSTANTS
      SPC 1 
LIST9 XOR FLGBT 
      SZA           NUMBER? 
      JMP LIS10     NO
      ISZ TEMPS     YES 
      LDA TEMPS,I 
      ISZ TEMPS 
      LDB TEMPS,I 
      ISZ LCNTR 
      ISZ LCNTR 
      CCE           OUTPUT
      JSB NUMOT       THE NUMBER
      JMP LIST3 
      SPC 1 
*  OUTPUT FUNCTION NAMES
      SPC 1 
LIS10 AND .15 
      CPA .3        INTEGER?
      JMP LIS11     YES 
      CPA .15       NO, FUNCTION? 
      RSS           YES 
      JMP LIST6     NO, MUST BE A PARAMETER 
      LDA TEMP3     COMPUTE 
      RRR 4 
      AND B37       COMPUTE INTERNAL FUNCTION NO. 
      CPA B37       IS IT LEN FUNCTION? 
      JMP LENF      YES 
      CPA B36       FORTRAN FUNCTION? 
      JMP FRFCT     YES!
      STA TEMP2           CODE
      CMA 
      STA TEMP5     NO. OF MNEMONICS TO SKIP
      LDA AFCNS     GET ADDR. OF FUNCTION MNEM. 
      JSB INDCK     MAKE DIRECT 
      STA 1         ADDR OF MNEMONIC ENTRIES IN BREG
NXFCN ISZ TEMP5     IS THIS IT? 
      RSS           NO! 
      JMP LFCN      YES!
      LDA 1,I       GET FIRST WORD OF MNEMONIC ENTRY
      AND .7        GET CHARACTER COUNT 
      ADA .3
      ARS           INCREMENT TO NEXT ENTRY 
      ADB 0         ADD IN MNEM TBL ADDRESS 
      JMP NXFCN     CHECK NEXT ENTRY
LFCN  JSB MCOPY     OUTPUT FUNCTION NAME
      JMP LIST3 
* LEN FUNCTION FOUND
LENF  LDB ALEN      ADDRESS OF PRINT
      JMP LFCN        BUFFER FOR LEN
FRFCT ISZ TEMPS 
      ISZ LCNTR 
      JMP MCAL1     PRINT FORTRAN FUNCT MNEM
      SPC 1 
*  OUTPUT INTEGER CONSTANTS 
      SPC 1 
LIS11 ISZ TEMPS     OUTPUT
      ISZ LCNTR 
      LDA TEMPS,I     INTEGER 
      SSA           MINUS SIGN REQUIRED?
      JMP LIS19     YES!
LIS18 JSB OUTIN 
      JMP LIST3         OPERAND 
* 
LIS19 LDA .45       OUTPUT
      JSB OUTCR       MINUS SIGN
      LDA TEMPS,I   COMPLEMENT
      CMA,INA         TO OBTAIN 
      JMP LIS18         ABSOLUTE VALUE
      SPC 1 
*  OUTPUT OPERATOR
      SPC 1 
LIS12 JSB OUTBL     .OUTPUT BLANK 
* 
      LDA TEMP2     IS THIS 
      CPA FOROP       A 'FOR' STATEMENT?
      JMP LIS21     YES, INDENT 'FOR' STATEMENT 
LIS22 LDA TEMP2 
      CPA NEXOP     IS THIS A 'NEXT' STMT?
      RSS           YES!
      JMP *+4       NO! 
      LDB FORCT     DECREMENT 
      ADB M1          FOR 
      STB FORCT         COUNT 
      CPA .G50      CALL? 
      JMP MCALL     YES. PRINT CALL STATEMENT 
      JSB MCOUT     OUTPUT
      LDA TEMP2       OPERATOR
      CPA REMOP     IS IT A REMARK STATEMENT? 
      JMP LIS15     YES 
      LDA TEMP2     COM STMT? 
      CPA COMWD 
      RSS           YES!
      JMP *+5       NO! 
      ISZ TEMPS     YES, SKIP 
      ISZ TEMPS       OVER COMMON SIZE
      ISZ LCNTR         AND DECREMENT 
      ISZ LCNTR           LENGTH COUNTER
      LDA BLANK     OUTPUT A BLANK
      JMP LIST5-1   AND LOOK FOR OPERANDS.
* 
LIS15 JSB OUTST     OUTPUT STRING 
      JMP LIST3 
      SPC 1 
LIS21 ISZ FORCT     INCREMENT COUNT 
      LDB .1          AND INDENT
      JSB FORSP         'FOR' STATEMENT 
      JMP LIS22           ONE MORE TIME 
      SPC 1 
*  IF PUNCH LIST DEVICE - PUNCH TRAILER ON TAPE 
      SPC 1 
LIS13 LDA FLFIL     .CHECK FOR FILE INPUT 
      INA,SZA,RSS 
      JMP CLOSE     .YES CLOSE IT 
      LDA LUOUT 
      JSB FINDV     .FETCH DRIVER NUMBER
      CPA .5        .2640.44.45 
      RSS           .YES
      JMP LIS49     . NO TRY SOMETING ELSE
      CPB .1        .IS IT A MINITAPE?
      JMP EOF       .YES LEFT ONE 
      CPB .2
      JMP EOF       .YES - RIGHT ONE
      CPB .4        .CRT PRINTER ?
      JMP LIS50     .YES - THROW A PAGE 
LIS49 CPA .10       .A LINE PRINTER ? 
      JMP LIS50     .YES THROW A PAGE 
      CPA .2        .IS IT THE PUNCH ?
      JMP EOF       .PUNCH LEADER 
      CPA B23       .CHECK FOR 9 TR MT
      JMP LIS48     .IF IT IS FORM A EOF WRITE REQUEST
* 
ENLST JMP RDYPT     .FINISHED - GO TO OPERATOR
* 
LIS50 JSB HEAVE 
      JMP ENLST 
* 
LIS48 LDA B100      .FETCH 9 TR MT FUNCTION BITS
      RSS           .AND JMP OVER CT AND PT FUNCTION BITS 
EOF   LDA B1000 
      IOR LUOUT     .FORM EOF REQUEST 
      STA LIS51 
      JSB EXEC      .PUNCH LEADER -OR-
      DEF *+3       .  WRITE 2644/45 EOF
      DEF .3
      DEF LIS51 
      JMP ENLST 
* 
CLOSE JSB CLFIL     .CLOSE OUTPUT FILE
      JMP ENLST 
* 
B1000 OCT 1000
.5    DEC 5 
.2    DEC 2 
.4    DEC 4 
LIS51 NOP 
******************************* 
*                             * 
*  INDENT 'FOR'-'NEXT' LOOPS  * 
*                             * 
******************************* 
* 
FORSP NOP 
      SZB,RSS       NEED ANY SPACES?
      JMP FORSP,I   NO! 
      SSB           TOO MANY 'NEXT'S' ? 
      JMP FORSP,I   YES!
      CMB,INB       SET 
      STB TEMP3       COUNTER 
      LDA M1        . SAVE OR PUNCH 
      CPA SAVFL 
      JMP FORSP,I   .YES - A SAVE 
      CPA PFLAG 
      JMP FORSP,I   YES, DON'T INDENT 
FORS0 LDA B40       OUTPUT
      JSB OUTCR       SPACE 
      LDA B40       OUTPUT ANOTHER
      JSB OUTCR       SPACE 
      ISZ TEMP3     DONE? 
      JMP FORS0     NO! 
      JMP FORSP,I   YES!
* 
      SKP 
*  OUTPUT QUOTE STRING
      SPC 1 
LIS14 LDB TEMPS,I   OUTPUT QUOTE STRING 
      BLF,BLF       TEST BIT 8
      SLB           SUPPRESS QUOTES?
      JMP LIS13     YES!
      JSB OUTCR     OUTPUT "
      JSB OUTST     OUTPUT QUOTE STRING 
      LDA .34       OUTPUT "
      JMP LIS17 
* 
********************* 
*                   * 
*  OUTPUT FORMFEED  * 
*                   * 
********************* 
* 
HEAVE NOP 
      AND B177      MAKE SURE V-BIT IS 0
      IOR B1100     FORM TAB COMMAND
      STA LENTH 
      JSB EXEC      DO IT TO IT 
      DEF *+4 
      DEF .3
      DEF LENTH 
      DEF M3
      JMP HEAVE,I 
* 
* 
**************************************
*                                    *
*  OUTPUT BLANKS IF LISTING          *
*                                    *
**************************************
* 
OUTBL NOP 
      LDA SAVFL     .TEST FOR PUNCH OR SAVE 
      CPA M1
      JMP OUTBL,I   .YES - NO BLANKS
      LDA .32       .NO - INSERT BLANKS 
      JSB OUTCR 
      JMP OUTBL,I 
      SKP 
******************* 
*                 * 
* OUTPUT A STRING * 
*                 * 
******************* 
OUTST NOP 
      LDA TEMPS,I 
      AND B177      GET STRING COUNT
      CMA,INA,SZA,RSS  NULL STRING? 
      JMP OUTST,I   YES!
      STA TEMP6     NO, SAVE NEG OF COUNT 
OUTS1 ISZ TEMPS     MOVE TO NEXT PAIR OF CHARS
      ISZ LCNTR     BUMP COUNTER
      LDA TEMPS,I   GET THEM
      ALF,ALF       POSITION TO OUTPUT LEFT CHARACTER 
      JSB OUTS2     OUTPUT CHAR 
      LDA TEMPS,I   GET CHAR PAIR AGAIN 
      JSB OUTS2     OUTPUT RIGHT HAND CHAR
      JMP OUTS1 
      SPC 1 
OUTS2 NOP 
      AND B177
      JSB OUTCR     ISOLATE AND OUTPUT CHAR 
      ISZ TEMP6     WAS IT LAST CHAR
      JMP OUTS2,I   NO! 
      JMP OUTST,I   YES!
* 
**********************************
*                                *
* OUTPUT A MULTICHARACTER SYMBOL *
*                                *
**********************************
MCOUT NOP 
      LDB STTYP     ADDRESS OF STATEMENT OPERATORS
MCOU1 LDA 1,I       LOAD INFORMATION WORD 
      AND OPMSK     COMPARE WITH
      CPA TEMP2       OPERATOR CODE 
      JMP MCOU2     EQUAL 
      LDA 1,I       UNEQUAL,
      AND .7          COMPUTE 
      ADA .3            ENTRY 
      ARS                 LENGTH
      ADB 0         COMPUTE ADDRESS OF NEXT ENTRY 
      JMP MCOU1 
MCOU2 JSB MCOPY     GO OUTPUT SYMBOL
      JMP MCOUT,I 
* 
MCOPY NOP 
      LDA 1,I       COMPUTE 
      AND .7          ENTRY 
      CMA,INA           LENGTH
      STA DIGCT           AND SAVE IT 
      CLE,INB       SET FOR FIRST CHARACTER 
      STB TEMP3     SAVE SYMBOL ADDRESS 
MCOU3 LDA TEMP3,I   LOAD WORD 
      SEZ,RSS       FIRST CHARACTER?
      ALF,ALF       YES, POSITION IT
      AND B177      EXTRACT CHARACTER 
      JSB OUTCR     OUTPUT IT 
      SEZ,CME       SET FOR NEXT CHARACTER
      ISZ TEMP3     MOVE TO NEXT WORD OF SYMBOL 
      ISZ DIGCT     MORE CHARACTERS?
      JMP MCOU3     YES 
      JMP MCOPY,I 
******************************* 
*                             * 
*   LIST A CALL STATEMENT     * 
*                             * 
******************************* 
* 
MCALL JSB MCOUT     OUTPUT 'CALL" 
      JSB OUTBL     .OUTPUT SPACE 
MCAL1 LDA TEMPS 
      STA TEMP7     CLEAR FORT FCT FLAG 
      LDA 0,I       GET OPERATOR WORD 
      AND B777      GET MNEMONIC TBL OFFSET 
      CMA           USE OFFSET TO FIND MNEMONIC 
      STA TEMP5     NO. OF MNEMONICS TO SKIP
      LDB FWAMM     GET ADDR. OF SUB. MNEMONICS 
      INB 
NXSUB ISZ TEMP5     IS THIS IT? 
      RSS           NO! 
      JMP LCALL     YES!
      LDA 1,I       GET FIRST WORD OF MNEMONIC ENTRY
      AND .7        GET CHARACTER COUNT 
      ADA .3
      ARS           INCREMENT TO NEXT ENTRY 
      ADB 0         ADD IN MNEM TBL ADDRESS 
      JMP NXSUB     CHECK NEXT ENTRY
LCALL JSB MCOPY     LIST THE CALL MNEMONIC
      LDA TEMP4     GET LAST CHAR (SEE OUTCR) 
      CPA .40       LAST CHAR "("?
      JMP MCAL2     YES, SUPPRESS SPACE 
      JSB OUTBL     .OUTPUT A BLANK 
MCAL2 ISZ TEMPS     POINT AT FIRST PARAM
      ISZ LCNTR     UPDATE INTERMEDIATE CODE COUNTER
      JMP LIST5 
      SKP 
* 
* 
*  MOVE WORDS ROUTINE 
* 
*    CALLING SEQ IS:    A=SOURCE ADDRESS
*                       B=DESTINATION ADDRESS 
* 
*     (P)           JSB MVW 
*     (P+1)         COUNT OF WORDS
*     (P+2)         NOP 
*     (P+3)         RETURN HERE 
* 
MVW   NOP 
      STA TEMP4     SAVE SOURCE ADDRS 
      LDA MVW,I     GET COUNT 
      CMA,INA         AND USE 
      ISZ MVW           AS COUNTER
      STA MVW,I           FOR MOVE
MVW1  LDA TEMP4,I   GET WORD
      STA 1,I       PUT AWAY
      ISZ TEMP4     INCREMENT SOURCE ADDR 
      INB           INCREMENT DESTINATION ADDR
      ISZ MVW,I     INCREMENT COUNTER, DONE?
      JMP MVW1      NO, NOT YET 
      ISZ MVW       YES 
      JMP MVW,I 
*********************** 
*                     * 
* PRINT ERROR MESSAGE * 
*                     * 
*********************** 
* 
* 
PRMES LDA ERTTY     RESET OUTPUT
      STA LUOUT       L.U. # TO ERROR DEVICE
* 
      LDA FLFIL     .OUTPUTTING ON FILES ?
      INA,SZA,RSS 
      JSB CLFIL     .YES - CLOSE FILE SO THAT ERROR PRINTS
      LDA TEMP3     .FETCH ERROR #
* 
      CMA,INA      MAKE NEGATIVE AND
      STA LCNTR     SAVE FOR COUNTER
      LDB MESGA   SET TABLE PNTR TO START 
PRMS1 LDA 1,I     GET LENGTH OF MESSAGE 
      INB          MOVE PNTR TO MESSAGE 
      ISZ LCNTR   INDEX ERROR CNTR, IS IT = 0?
      RSS          NO, MOVE PNTR TO NEXT MESSG
      JMP PRMS2     YES - GO PRINT MESSAGE
      SLA         IF CHAR COUNT ODD,
      INA          MAKE EVEN
      ARS           CONVERT TO WORDS
      ADB 0          MOVE PNTR TO NEXT MESSG
      JMP PRMS1   GO INDEX ERROR COUNTER
* 
* DISK FILE ERRORS ARE NEGATIVE AND COME HERE 
* 
* 
* 
PRMS2 JSB WRITE   PRINT FIRST PART OF MESSAGE 
      LDA .10     INITIALIZE
      STA OCCNT       OUTPUT
      LDA LNBFA         BUFFER
      STA OTBFA 
      LDA .LNUM     OUTPUT
      SZA,RSS       COMMAND ERROR?
      JMP ERRP2     YES, DON'T PRINT OUT LINE#
      JSB OUTIN     NO! 
      LDA OCCNT       LINE
      LDB ERBFA 
      JSB WRITE         NUMBER
* 
      LDA TEMP8     IS CHAR 
      SSA,RSS         COUNT 
      CMA,INA           WITHIN
      ADA .73             A REASONABLE
      SSA                   RANGE?
      JMP ERRP1     NO, GO TO MAIN! 
      LDA .INBF     YES, MOVE 
      LDB .OTBF       BAD STMT
      JSB MVW           FROM INPUT
      DEC 36              BUFFER TO 
      NOP                   OUTPUT BUFFER 
      LDA TEMP8     MAKE
      CMA             STATEMENT 
      STA OCCNT         LENGTH POSITIVE 
      LDA PFLAG     KEYBOARD
      SZA,RSS         INPUT?
      JMP ERRP1     YES, EXIT 
      LDA .OTBF,I   ARE FIRST TWO 
      CPA BLNK,I      CHARACTERS BLNKS? 
      JMP PRMS3     YES, DON'T INSERT BLANKS
      LDA .3        OUTPUT
      LDB BLNK        TWO 
      JSB WRITE         BLANKS
PRMS3 LDA OCCNT     REPRINT 
      LDB .OTBF       THE 
      JSB WRITE         STATEMENT 
* 
ERRP1 JMP PRMT      YES, RETURN TO IT THEN
* 
ERRP2 LDA M2        PRINT 
      LDB CRLF        CARRIAGE RETURN/LINE FEED 
      JSB WRITE 
      JMP ERRP1 
* 
TEMP2 EQU TEMPS+3 
TEMP3 EQU TEMPS+4 
TEMP4 EQU TEMPS+5 
TEMP5 EQU TEMPS+6 
TEMP6 EQU TEMPS+7 
TEMP7 EQU TEMPS+8 
TEMP8 EQU TEMPS+9 
LENTH EQU TEMPT+1 
TBUFA EQU TEMPT+2 
TCNTR EQU TEMPT+3 
LCNTR EQU TEMPT+4 
DIGCT EQU TEMPT+5 
FERR  EQU TEMPT+6 
      END