ASMB,Q,C
*     NAME: .XCA
*     SOURCE: 92071-18329 
*     RELOC:  92071-16329 
*     PGMR:   DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .XCA,6  92071-1X329 REV.2041  800417
      ENT .XCA
      EXT .A.,.B.,.ZPRV,.XLD
* 
A     EQU 0 
B     EQU 1 
TEMP  NOP 
* 
.XCA  NOP 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      DST .A.       SAVE A,B
      LDB .XCA,I    GET THE UNRESOLVED ADDRESS
      ISZ .XCA      ADJUST RETURN 
* 
* THE ADDRESS IS IN B, BUT INDIRECTS MUST 
* STILL BE RESOLVED.
* 
BACK  SSB 
      JMP RESLV     INDIRECT BIT WAS SET
* 
      JSB .XLD      GET DATA IN A 
      DEF B,I 
      CPA .A.       COMPARE DATA
      JMP SAME      THE COMPARISON IS TRUE
      ISZ .XCA      THEY ARE DIFFERENT, SO CAUSE A SKIP 
SAME  DLD .A.       RESTORE REGISTERS 
EXIT  JMP .XCA,I    RETURN
      DEF .XCA
* 
RESLV ELB,CLE,ERB   CLEAR INDIRECT BIT (NO CHANGE TO E) 
      STB TEMP      SAVE IN CASE DEF A OR B,I 
      LDB .B.       RESTORE B IN CASE DEF B,I 
      LDB TEMP,I    GET NEXT LEVEL ADDRESS
      JMP BACK
* 
      END 
                                    