ASMB,Q,C
*     NAME: .XCB
*     SOURCE: 92071-18330 
*     RELOC: 92071-16330
*     PGMR:   DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .XCB,6  92071-1X330 REV.2041  800417
      ENT .XCB
      EXT .A.,.B.,.ZPRV,.XLD
* 
A     EQU 0 
B     EQU 1 
TEMP  NOP 
* 
.XCB  NOP 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      DST .A.       SAVE A,B
      LDA .XCB,I    GET THE UNRESOLVED ADDRESS
      ISZ .XCB      ADJUST RETURN 
* 
* THE ADDRESS IS IN A, BUT INDIRECTS MUST 
* STILL BE RESOLVED.
* 
BACK  SSA 
      JMP RESLV     INDIRECT BIT WAS SET
* 
      JSB .XLD      GET DATA IN A 
      DEF A,I 
      CPA .B.       COMPARE DATA
      JMP SAME      THE COMPARISON IS TRUE
      ISZ .XCB      THEY ARE DIFFERENT, SO CAUSE A SKIP 
SAME  DLD .A.       RESTORE REGISTERS 
EXIT  JMP .XCB,I    RETURN
      DEF .XCB
* 
RESLV ELA,CLE,ERA   CLEAR INDIRECT BIT (NO CHANGE TO E) 
      STA TEMP      SAVE IN CASE DEF A OR B,I 
      LDA .A.       RESTORE A IN CASE DEF A,I 
      LDA TEMP,I    GET NEXT LEVEL ADDRESS
      JMP BACK
* 
      END 
                                      