ASMB,L
* 
*     CHPUT (STRING, IPOSITION, IVAL) 
* 
*     PUTS AN INTEGER VALUE AT A SPECIFIED CHARACTER IN A STRING
* 
      NAM CHPUT,7 92425-16022 REV.1841 780927 
* 
*-------------------------------------------------------------
* 
* 
*     M. CHAMBREAU      17MAY76    REV. A 
* 
*     "C" COPYRIGHT HEWLETT-PACKARD COMPANY 1976. 
*     ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM 
*     MAY BE PHOTOCOPIED, REPRODUCED OR TRANSLATED
*     TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR 
*     WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY. 
* 
*-------------------------------------------------------------
* 
      ENT CHPUT 
      EXT .ENTR 
* 
B     EQU 1 
* 
STRN  NOP 
IPOS  NOP 
IVAL  NOP 
CHPUT NOP 
      JSB .ENTR 
      DEF STRN
* 
      LDB IPOS,I    COMPUTE ADDRESS IN B-REG
      STB FLAG
      INB 
      BRS 
      ADB STRN
      STB STRN
* 
      LDA STRN,I    GET WORD
      LDB FLAG
      SLB,RSS           EVEN OR ODD?
      JMP *+2       EVEN....DONT SHIFT
      ALF,ALF       ODD.....SHIFT 
      AND MASK
      IOR IVAL,I
      LDB FLAG      SHIFT BACK IF NEEDED
      SLB,RSS 
      JMP *+2 
      ALF,ALF 
      STA STRN,I
* 
      JMP CHPUT,I 
* 
MASK  OCT 177400
FLAG  BSS 1 
      END 
  