ASMB,L
*                                                *************
*                                                *** TIMEX ***
*                                                *************
      NAM TIMEX,7  92425-16033 REV.1841 780927
* 
*-------------------------------------------------------------
* 
* 
*     M.CHAMBREAU       17MAY76    REV. A 
* 
*     "C" COPYRIGHT HEWLETT-PACKARD COMPANY 1976. 
*     ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM 
*     MAY BE PHOTOCOPIED, REPRODUCED OR TRANSLATED
*     TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR 
*     WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY. 
* 
*-------------------------------------------------------------
* 
      ENT TIMEX 
      EXT .ENTR,EXEC
* 
*                    TIMEX(STRING)
*                    RETURNS 12-CHAR STRING CONTAINING CURRENT TIME 
*                    FORMAT:      HH:MM:SS.XXX
* 
B     EQU 1 
* 
ISTRN NOP 
TIMEX NOP 
      JSB .ENTR 
      DEF ISTRN 
* 
      LDA ISTRN     SET UP STRING ADDRESS AND LENGTH
      STA ADDR
      LDA D11 
      STA ADDR,I
      ISZ ADDR
* 
      JSB EXEC      GET CURRENT TIME (.01SEC,SEC,MIN,HR,DAYR) 
      DEF *+3 
      DEF D11 
      DEF ITIME 
* 
      LDA ITIME+3   CONVERT AND STORE HOURS 
      JSB CONV
      STA ADDR,I
      ISZ ADDR
      LDA ITIME+2   CONVERT AND STORE MINUTES 
      JSB CONV
      ALF,ALF 
      STA TEMP
      AND B377
      IOR ASCC0 
      STA ADDR,I
      ISZ ADDR
      LDA TEMP
      AND BHI 
      IOR ASC0C 
      STA ADDR,I
      ISZ ADDR
      LDA ITIME+1   CONVERT AND STORE SECONDS 
      JSB CONV
      STA ADDR,I
      ISZ ADDR
      LDA ITIME     CONVERT AND STORE .01 SECONDS 
      JSB CONV
      ALF,ALF 
      STA TEMP
      AND B377
      IOR ASC.0 
      STA ADDR,I
      ISZ ADDR
      AND BHI 
      IOR AZRO
      LDA TEMP
      STA ADDR,I
      JMP TIMEX,I 
* 
CONV  NOP           CONVERT AN INTEGER TO 2-CHARACTER ASCII 
      CLB 
      DIV D10 
      ALF,ALF 
      IOR B 
      ADA ASC00 
      JMP CONV,I
* 
ITIME BSS 5 
D10   DEC 10
D11   DEC 11
B377  OCT 377 
BHI   OCT 177400
TEMP  BSS 1 
ADDR  BSS 1 
ASC00 ASC 1,00
ASCC0 ASC 1,:0
ASC0C ASC 1,0:
ASC.0 ASC 1,.0
AZRO  OCT 60
      END 
            