10 PRINT "DEEP SPACE"
20 INPUT"DO YOU WISH A MANEUVER CHART";M$
30 IF LEFT$(M$,1)="N" THEN 140
40 PRINT:PRINT"  MANEUVER CHART-"
50 PRINT:PRINT TAB(16)"1. FIRE PHASERS"
60 PRINT TAB(16) "2. FIRE ANTI MATTER MISSLE"
70 PRINT TAB(16) "3. FIRE HYPERSPACE LANCE"
80 PRINT TAB(16) "4. FIRE PHOTON TORPEDO"
90 PRINT TAB(16) "5. ACTIVATE HYPERON NEUTRALIZATION FIELD"
100 PRINT TAB(16) "6. SELF-DESTRUCT"
110 PRINT TAB(16) "7. CHANGE VELOCITY"
120 PRINT TAB(16) "8. DISENGAGE"
130 PRINT TAB(16) "9. PROCEED"
140 PRINT:PRINT"YOU HAVE A CHOICE OF THREE SYSTEMS TO PATROL"
150 PRINT:PRINT TAB(16) "1. ORION"
160 PRINT TAB(16)"2. DENEB":PRINT TAB(16)"3. ARCTURUS":PRINT
170 INPUT"SELECT A SYSTEM(1-3)";S9
180 IF S9=1 THEN 910
190 IF S9=2 THEN 920
200 GOTO930
210 D0=0:D1=0:N1=0:N2=0:N3=0:N4=0
220 D=0:INPUT"WHICH SPACECRAFT WOULD YOU LIKE";S
230 IF S=1 THEN S0=10:C0=16:P0=1:GOTO 270
240 IF S=2 THEN S0=4 :C0=24:P0=2:GOTO 270
250 IF S=3 THEN S0=2 :C0=30:P0=5:GOTO 270
260 GOTO 220
270 C=C0
280 PRINT"YOU HAVE"C"UNITS OF SPACE TO FILL WITH WEAPONRY."
290 INPUT"CHOOSE WEAPON AND AMOUNT YOU WISH:";W,N
300 IF W=1 THEN C1=.12:N=100:GOTO 360
310 IF W=2 THEN C1=4:GOTO 360
320 IF W=3 THEN C1=4:GOTO 360
330 IF W=4 THEN C1=2:GOTO 360
340 IF W=5THEN C1=.2:N=100:GOTO 360
350 GOTO 280
360 IF N*C1>INT(C+.5) THEN 940
370 C=C-N*C1
380 IF W=1 THEN N1=N1+N:GOTO 430
390 IF W=2 THEN N2=N2+N:GOTO 430
400 IF W=3 THEN N3=N3+N:GOTO 430
410 IF W=4 THEN N4=N4+N:GOTO 430
420 GOTO 900
430 IF C>1 THEN 280
440 S1=S0*RND(6)
450 R=(3*RND(6)+5)*100:PRINT
460 PRINT"RANGE TO TARGET:"R:PRINT"RELATIVE VELOCITY:"S1
470 INPUT"ACTION?";M
480 ON M GOTO 800,820,840,860,880,720,560,1060,490
490 IF R<500 THEN 630
500 IF S1>0 THEN 520
510 R=R+(S1*8.3)^1.25:GOTO 530
520 R=R-(S1*8.3)^1.25
530 IF R>1500 THEN 970
540 IF R<0 THEN R=-R
550 PRINT:GOTO 460
560 INPUT"CHANGE TO BE EFFECTED";S2
570 IF S1+S2>S0 THEN 950
580 S1=S1+S2:GOTO 460
590 F0=P1*(Z/R)^1.5:D0=(2*F0+3*F0*RND(5))/5:D=D+D0
600 PRINT"SCANNERS REPORT ENEMY DAMAGE NOW";D
610 IF D>99 THEN 1040
620 GOTO 640
630 D0=0
640 K=E1+E2*RND(8):E=E3*RND(7)+5/P0*RND(4):F3=E*(K/R)^1.85
650 D2=(3*F3+3*F3*RND(3))/5.5:D1=D1+D2
660 IF (Z*D0)/(R*500)>2.2 THEN 680
670 D3=D0*2/(R*R*P0):D1=D1+D3
680 PRINT"DAMAGE CONTROL REPORTS YOUR VESSLE DAMAGE AT:";D1
690 IF D1>99 THEN 1050
700 IF D>99 THEN 1060
710 GOTO 500
720 PRINT"SELF DESTRUCT FAILSAFE ACTIVATED!!"
730 INPUT"TYPE 'RELEASE' TO RELEASE FAILSAFE";M$
740 IF M$<>"RELEASE" THEN 490
750 PRINT"SELF DESTRUCT ACCOMPLISHED":IF R>60 THEN 770
760 PRINT"ENEMY VESSEL ALSO DESTROYED":GOTO 1060
770 D4=3200/R:D=D+D4:IF D>99 THEN 760
780 PRINT"ENEMY VESSEL SURVIVES WITH"D"DAMAGE"
790 GOTO 1060
800 P1=4:IFN1=0 THEN 980
810 N1=N1-1:Z=200:GOTO 590
820 P1=20:IF N2=0 THEN 1000
830 N2=N2-1:Z=500:GOTO 590
840 P1=16:IF N3=0 THEN 1010
850 N3=N3-1:Z=550:GOTO 590
860 P1=10:IF N4=0THEN 1020
870 N4=N4-1:Z=400:GOTO 590
880 P1=6:IF N5=0 THEN 1030
890 N5=N5-1:Z=250:GOTO 590
900 N5=N5+N:GOTO 430
910 E1=150:E2=500:E3=3:E4=4:GOTO 210
920 E1=200:E2=350:E3=4:E4=3:GOTO 210
930 E1=150:E2=400:E3=5:E4=2:GOTO 210
940 PRINT"NOT ENOUGH SPACE. RESELECT":GOTO 280
950 PRINT"CHANGE BEYOND MAXIMUM POSSIBLE"
960 PRINT"INCREASING TO MAXIMUM":S1=S0:GOTO 500
970 PRINT"OUT OF SENSOR RANGE. AUTOMATIC DISENGAGE.":GOTO 1060
980 PRINT"PHASER BANKS DRAINED"
990 PRINT"SELECT ANOTHER COURSE OF ACTION":GOTO 470
1000 PRINT"ALL ANTI-MATTER MISSLES EXPENDED": GOTO 990
1010 PRINT"ALL HYPERSPACE LANCES EXPENDED":GOTO 990
1020 PRINT"ALL PHOTON TORPEDO TUBES EMPTY":GOTO 990
1030 PRINT"HYPERON NEUTRALIZATION FIELD DRAINED":GOTO 990
1040 PRINT"ENEMY VESSEL DESTROYED":GOTO 640
1050 PRINT"YOUR VESSEL HAS BEEN DESTROYED"
1060 PRINT:PRINT:INPUT "ANOTHER BATTLE";M$
1070 IF LEFT$(M$,1)="Y" THEN 170
1080 PRINT"TRY AGAIN LATTER!"
1090 END
ROYED"
1060 PRINT:PRINT:INPUT "ANOTHER BATTLE";M$
1070 IF LEFT$(M$,1)="Y" THEN 170
1080 PRINT"TRY AGAIN LATT